home *** CD-ROM | disk | FTP | other *** search
/ Antennas / Antennas_CD-ROM_Walnut_Creek_September_1996.iso / w4mb / vol2 / basic / frod.asc < prev    next >
Text File  |  1996-06-30  |  10KB  |  230 lines
  1. 2 ON ERROR GOTO 60000
  2. 3 CLS
  3. 10 PRINT "   ***************************************************************"
  4. 20 PRINT "   *                FERRITE CORE LOOP ANTENNAS                   *"
  5. 30 PRINT "   *   PRZEDPELSKI, LOOP ANTENNA DESIGN, RF DESIGN, N/D, 1982    *"
  6. 40 PRINT "   *     JOHNSON AND JASIK, ANTENNA ENGG. HANDBOOK, 2ND ED       *"
  7. 50 PRINT "   *                   KRAUS, ANTENNAS, 2ND ED.                  *"
  8. 60 PRINT "   *               PROGRAM BY  R.P. HAVILAND, W4MB               *"
  9. 70 PRINT "   *                       COPYRGHT 1990                         *"
  10. 80 PRINT "   *          MINILAB BOOKS, DAYTONA BEACH, FL 32121-1086        *"
  11. 90 PRINT "   ****************************************************************"
  12. 100 DEF FNP(X)=INT(100*X+.5)/100
  13. 110 PI=3.141592
  14. 200 DIM LD(12,10)
  15. 210 FOR M=0 TO 12
  16. 220 FOR N=0 TO 10                    
  17. 230 READ LD(M,N)
  18. 240 NEXT N
  19. 250 NEXT M
  20. 400 PRINT "  THE ACCURACY OF THIS PROGRAM DEPENDS PRIMARILY ON THE ACCURACY"
  21. 410 PRINT "   OF THE VALUES FOR EFFECTIVE PERMABILITY OF THE LOOP CORE"
  22. 420 PRINT "    WHETHER IRON POWDER OR FERRITE. RECOMMENDED PROCEEDURE IS TO"
  23. 430 PRINT "     WIND A TEST COIL, MEASURE L AND Q, THEN DETERMINE "
  24. 440 PRINT "      EFFECTIVE PERMABILITY BY USING THE ROUTINES PROVIDED."
  25. 450 PRINT "  THE LOOP WINDING IS ASSUMED TO BE CENTERED ON THE ROD"
  26. 460 PRINT "   PARALLEL TUNING IS ASSUMED:SEE FIRST REFERENCE FOR SERIES."
  27. 470 PRINT "    FOR MOST DESIGNS, OUTPUT S/N IS THE SAME AS RECEIVED S/N"
  28. 480 PRINT 
  29. 500 INPUT " PAPER COPY OF DESIGN DATA Y/N";P$
  30. 510 IF P$="Y" THEN LPRINT " DESIGN DATA FOR FERRITE ROD ANTENNA"
  31. 520 LPRINT
  32. 600 INPUT " ENTER DESIGN LOWEST TUNING FREQUENCY, MHZ";MINF
  33. 605 IF P$="Y" THEN LPRINT " DESIGN LOWEST TUNING FREQUENCY, MHZ";MINF
  34. 610 PRINT " PARALLEL TUNING GIVES BETTER PASSBAND CHARACTERISTICS,"
  35. 620 PRINT "   SERIES TUNING GIVES SLIGTHTLY GREATER SIGNAL OUTPUT"
  36. 630 INPUT " ENTER MAXIMUM TUNING CAPACITY, PICOFARADS";MAXC
  37. 635 IF P$="Y" THEN LPRINT " MAXIMUM TUNING CAPACITY, PICOFARADS";MAXC
  38. 640 MAXC=MAXC*.000001
  39. 650 INPUT "  ENTER MINIMUM TUNING CAPACITY, PF";MINC 
  40. 655 IF P$="Y" THEN LPRINT "   MINIMUM TUNING CAPACITY, PF";MINC
  41. 660 MINC=MINC*.000001
  42. 670 INPUT "   ENTER ESTIMATED STRAY CIRCUIT CAPACITY, PF";STRC
  43. 675 IF P$="Y" THEN LPRINT "    ESTIMATED STRAY CIRCUIT CAPACITY, PF";STRC
  44. 680 STRC=STRC*.000001
  45. 690 MAXLAM=299.8/MINF
  46. 700 INPUT " ENTER DIAMETER OF FERRITE ROD, INCHES";DR
  47. 705 IF P$="Y" THEN LPRINT " DIAMETER OF FERRITE ROD, INCHES";DR
  48. 710 INPUT "  ENTER LENGTH OF FERRITE ROD, INCHES";LR
  49. 715 IF P$="Y" THEN LPRINT "  LENGTH OF FERRITE ROD, INCHES";LR
  50. 720 LOD=LR/DR
  51. 730 IF LOD<2 OR LOD>80 THEN PRINT "OUT OF RANGE":GOTO 700
  52. 800 PRINT "ENTER M= MATERIAL PERMABILITY KNOWN"
  53. 810 PRINT "      E= EFFECTIVE PERMABILITY KNOWN"
  54. 820 PRINT "      L= TEST COIL INDUCTANCE KNOWN"
  55. 830 PRINT "      D= DESIGN AND MEASURED RESONANT FREQUENCY KNOWN"
  56. 840 PRINT "      F= TEST COIL RESONANT FREQUENCY KNOWN"
  57. 850 INPUT M$
  58. 900 IF M$="M" THEN GOSUB 4000:GOTO 1000
  59. 910 IF M$="E" THEN GOSUB 5000:GOTO 1000
  60. 920 IF M$="L" THEN GOSUB 6000:GOTO 1000
  61. 930 IF M$="D" THEN GOSUB 7000:GOTO 1000
  62. 940 IF M$="F" THEN GOSUB 8000:GOTO 1000
  63. 950 GOTO 720
  64. 1000 PRINT 
  65. 1010 CT=MAXC+STRC 
  66. 1020 XC=1/(2*PI*MINF*CT):XL=XC
  67. 1030 IND=XL/(2*PI*MINF)                                    
  68. 1040 PRINT " REQUIRED COIL INDUCTANCE=";FNP(IND);"UH"
  69. 1045 IF P$="Y" THEN LPRINT " REQUIRED COIL INDUCTANCE=";FNP(IND);"UH"
  70. 1050 PRINT "  COIL LENGTH IS TYPICALLY";FNP(LR/4);"INCHES"
  71. 1060 INPUT "   ENTER DESIGN LENGTH OF COIL, INCHES";LCOIL
  72. 1065 IF P$="Y" THEN LPRINT "   DESIGN LENGTH OF COIL, INCHES";LCOIL
  73. 1100 FA=1-.17*LCOIL/LR                                    
  74. 1110 NCOIL=SQR(IND*(18*DR+40*LR)/(MUEFF*FA*DR*DR))
  75. 1120 PRINT " REQUIRED COIL TURNS=";INT(NCOIL)
  76. 1125 IF P$="Y" THEN LPRINT " REQUIRED COIL TURNS=";INT(NCOIL)
  77. 1230 WDIA= LCOIL/NCOIL
  78. 1240 AWG=40*(LOG(.41/WDIA)/LOG(92))+2
  79. 1250 PRINT "  FOR SINGLE LAYER COIL,"
  80. 1260 PRINT "   MAXIMUM WIRE SIZE IS #";INT(AWG);" AWG ENAMELED WIRE"
  81. 1270 INPUT " ENTER DESIGN WIRE SIZE, AWG";AWG
  82. 1275 IF P$="Y" THEN LPRINT "     DESIGN WIRE SIZE, AWG";AWG
  83. 1280 WDIA=.41/92^((AWG+2)/40)
  84. 1400 INPUT " ENTER COIL Q, 0=USE CALCULATED VALUE";CQ
  85. 1410 IF CQ<>0 THEN 1450
  86. 1420 RCOIL=PI*NCOIL*SQR(4*MINF/5.7*1E-08)
  87. 1430 RRAD=197*MUEFF*MUEFF*NCOIL*NCOIL*(MINF*LR*PI/11803)^4
  88. 1440 RLOSS=PI^4/2*MINF*1000000!*MUEFF*MUIMAG/MUREAL*NCOIL*NCOIL*DR*DR/LR/39.37*.0000001
  89. 1450 CQ=XL/(RCOIL+RRAD+RLOSS)
  90. 1454 PRINT " UNLOADED Q=";INT(CQ)
  91. 1455 IF P$="Y" THEN LPRINT " UNLOADED Q=";INT(CQ)
  92. 1460 PRINT "  MAX TUNING FREQUENCY=";MINF*SQR((MAXC+STRC)/(MINC+STRC))
  93. 1465 IF P$="Y" THEN LPRINT "  MAX TUNING FREQUENCY=";MINF*SQR((MAXC+STRC)/(MINC+STRC))
  94. 1470 PRINT 
  95. 1600 INPUT "  ENTER LOAD RESISTANCE OF ANTENNA,OHMS";RO
  96. 1605 IF P$="Y" THEN LPRINT "  LOAD RESISTANCE OF ANTENNA,OHMS";RO
  97. 1610 EIND=1.355E-05*MUEFF*NCOIL*PI*DR*DR/4*MINF*FA     
  98. 1620 PRINT " COIL INDUCED VOLTAGE=";
  99. 1630 PRINT USING "##.##^^^^";EIND;
  100. 1635 IF P$="Y" THEN LPRINT " COIL INDUCED VOLTAGE=";
  101. 1636 IF P$="Y" THEN LPRINT USING "##.##^^^^";EIND;
  102. 1640 PRINT "VOLTS FOR 1 VOLT/METER FIELD"
  103. 1650 ELOAD=RO*CQ/(XL*CQ+RO)
  104. 1655 IF P$="Y" THEN LPRINT "VOLTS FOR 1 VOLT/METER FIELD"
  105. 1656 IF P$="Y" THEN LELOAD=RO*CQ/(XL*CQ+RO)
  106. 1660 PRINT "  VOLTAGE ACROSS LOAD=";
  107. 1670 PRINT USING "##.##^^^^"; ELOAD;
  108. 1675 IF P$="Y" THEN LPRINT "  VOLTAGE ACROSS LOAD=";
  109. 1676 IF P$="Y" THEN LPRINT USING "##.##^^^^"; ELOAD;
  110. 1680 PRINT " VOLTS FOR 1 VOLT/METER FIELD"
  111. 1700 BW=MINF/CQ*1000000!
  112. 1710 PRINT USING "   BANDWIDTH= ##.#^^^^";BW;:PRINT " HZ"
  113. 1715 IF P$="Y" THEN LPRINT " VOLTS FOR 1 VOLT/METER FIELD"
  114. 1716 IF P$="Y" THEN LPRINT USING "   BANDWIDTH= ##.#^^^^";BW;:PRINT " HZ"
  115. 1740 PRINT                                           
  116. 1800 PRINT "   ENTER F= FREQUENCY SCAN"
  117. 1810 PRINT "         N= NEW DESIGN CONDITIONS"
  118. 1820 PRINT "         R= REVISE DESIGN"
  119. 1830 PRINT "         Q= QUIT"
  120. 1840 INPUT T$
  121. 1850 IF T$="F" THEN 2000
  122. 1860 IF T$="N"THEN 600
  123. 1870 IF T$="R"THEN 700
  124. 1880 IF T$="Q" THEN STOP
  125. 1890 GOTO 1800
  126. 2000 CLS
  127. 2010 CRANG=MAXC-MINC
  128. 2020 CDEL=CRANG/10
  129. 2030 PRINT "STEP","FREQ, MHZ","E-OUT, V/V","BW, HZ"
  130. 2035 IF P$="Y" THEN LPRINT "STEP","FREQ, MHZ","E-OUT, V/V","BW, HZ"
  131. 2100 FOR N=0 TO 10
  132. 2110 CTUN=MAXC+STRC-N*CDEL
  133. 2120 TUNF=MINF*SQR((STRC+MAXC)/CTUN)
  134. 2130 XC=1/(2*PI*TUNF*CTUN):XL=XC
  135. 2140 RCOIL=PI*NCOIL*SQR(4*TUNF/5.7*1E-08)
  136. 2150 RRAD=197*MUEFF*MUEFF*NCOIL*NCOIL*(TUNF*LR*PI/11803)^4
  137. 2160 RLOSS=PI^4/2*TUNF*1000000!*MUEFF*MUIMAG/MUREAL*NCOIL*NCOIL*DR*DR/LR/39.37*.0000001
  138. 2170 CQ=XL/(RCOIL+RRAD+RLOSS)
  139. 2180 ELOAD=RO*CQ/(XL*CQ+RO)
  140. 2190 BW=MINF/CQ*1000000!
  141. 2500 PRINT N,FNP(TUNF),
  142. 2510 PRINT USING "##.##^^^^"; ELOAD,
  143. 2520 PRINT ,FNP(BW)
  144. 2525 IF P$="Y" THEN LPRINT N,FNP(TUNF),
  145. 2526 IF P$="Y" THEN LPRINT USING "##.##^^^^"; ELOAD,
  146. 2527 IF P$="Y" THEN LPRINT ,FNP(BW)
  147. 2530 NEXT N
  148. 2540 PRINT 
  149. 2550 GOTO 1800
  150. 4000 CLS      'LINEAR INTERPOLATE, ROD PERMABILITY KNOWN
  151. 4010 INPUT "ENTER ROD PERMABILITY";PERM
  152. 4020 IF PERM>1000 THEN 4500
  153. 4030 IF PERM=1 THEN MUEFF=1:GOTO 4800
  154. 4040 UIND=0    'DO TABLE LOOKUP
  155. 4050 LDIND=0
  156. 4060 IF LD(UIND,0)<PERM THEN UIND=UIND+1:GOTO 4050     
  157. 4070 IF LD(0,LDIND)<LOD THEN LDIND=LDIND+1:GOTO 4060
  158. 4100 D1=LD(UIND,LDIND)-LD(UIND-1,LDIND)     'PAIR INTERPOLATE
  159. 4110 D2=LD(UIND,LDIND-1)-LD(UIND-1,LDIND-1)
  160. 4120 UDIF=LD(UIND,0)-LD(UIND-1,0)
  161. 4130 LDDIF=LD(0,LDIND)-LD(0,LDIND-1)
  162. 4135 INUDIF=LD(UIND,0)-PERM
  163. 4140 INLDDIF=LD(0,LDIND)-LOD
  164. 4150 VAL1=LD(UIND,LDIND)-D1*INUDIF/UDIF      
  165. 4160 VAL2=LD(UIND,LDIND-1)-D2*INUDIF/UDIF     
  166. 4170 D3=VAL1-VAL2    'FINAL INTERPOLATE
  167. 4180 MUEFF=VAL1-D3*INLDDIF/LDDIF
  168. 4190 GOTO 4600
  169. 4500 MUEFF=2.934*LOD^1.394  'LIMIT CASE
  170. 4600 INPUT "  ENTER REAL PART OF EFFECTIVE PERMABILITY, 0=UNKNOWN";MUREAL
  171. 4610 IF MUREAL=0 THEN MUREAL=PERM:MUIMAG=.01*PERM:GOTO 4800
  172. 4620 INPUT "   ENTER IMAGINARY PART OF EFFECTIVE PERMABILITY";MUIMAG
  173. 4800 PRINT "ROD PERMABILITY=";PERM
  174. 4810 PRINT "EFFECTIVE PERMABILITY=";FNP(MUEFF)
  175. 4999 RETURN
  176. 5000 CLS    'EFFECTIVE PERMABILITY KNOWN
  177. 5010 PRINT " USE MEASURED OR DATA-SHEET VALUE"
  178. 5020 INPUT "  ENTER EFFECTIVE PERMABILITY";MUEFF
  179. 5030 INPUT "   ENTER REAL PART OF EFFECTIVE PERMABILITY, 0=UNKNOWN";MUREAL
  180. 5040 IF MUREAL=0 THEN MUREAL=MUEFF:MUIMAG=.01*MUEFF:GOTO 5060
  181. 5050 INPUT "    ENTER IMAGINARY PART OF EFFECTIVE PERMABILITY";MUIMAG
  182. 5060 RETURN
  183. 6000 CLS    'TEST WINDING MEASURED INDUCTANCE KNOWN
  184. 6010 INPUT " ENTER MEASURED INDUCTANCE OF TEST COIL, UH";LMES
  185. 6020 INPUT "  ENTER NUMBER OF TURNS OF TEST COIL";NTEST
  186. 6030 INPUT "   ENTER LENGTH OF TEST COIL, INCHES";LTEST
  187. 6040 FA=1-.17*LTEST/LR
  188. 6050 MUEFF=LMES*4*LTEST/FA*(9*DR+10*LTEST)/DR/DR/NTEST/NTEST
  189. 6060 PRINT " EFFECTIVE PERMABILITY=";FNP(MUEFF)
  190. 6070 MUREAL=MUEFF:MUIMAG=.01*MUEFF  'RATIO ONLY USED
  191. 6080 RETURN
  192. 7000 CLS    'TEST RESONANT FREQUENCY KNOWN
  193. 7010 INPUT " ENTER DESIGN FREQUENCY, MHZ";FDES
  194. 7020 INPUT "  ENTER MEASURED FREQUENCY, MHZ";FMES
  195. 7030 INPUT "   ENTER EFFECTIVE PERMABILITY AS DESIGNED";MUEDES
  196. 7040 MUEFF=MUEDES*FMES/FDES
  197. 7050 PRINT " MEASURED EFFECTIVE PERMABILITY=";FNP(MUEFF)
  198. 7060 MUREAL=MUEFF:MUIMAG=.01*MUEFF  'RATIO ONLY USED
  199. 7070 RETURN
  200. 8000 CLS
  201. 8010 INPUT " ENTER NUMBER OF TURNS OF TEST COIL";NTEST
  202. 8020 INPUT "  ENTER LENGTH OF TEST COIL, INCHES";LTEST
  203. 8030 INPUT "   ENTER PARALLEL CAPACIANCE RESONATING TEST COIL, PF";CRES
  204. 8040 INPUT "    ENTER RESONANT FREQUENCY, MHZ";FRES
  205. 8100 FA=1-.17*LTEST/LR
  206. 8110 XC=1/2/PI/FRES/CRES
  207. 8120 XL=XC
  208. 8130 L=XL/2/PI/FRES
  209. 8140 MUEFF=LTEST/FA*(9*DR+10*LTEST)/DR/DR/NTEST/NTEST
  210. 8150 PRINT " THE TEST COIL INDUCTANCE=";FNP(L);"UH"
  211. 8160 PRINT "  THE EFFECTIVE PERMABILITY=";FNP(MUEFF)
  212. 8999 RETURN
  213. 59999 STOP
  214. 60000 PRINT "ERROR";ERR;"AT LINE";ERL
  215. 60010 STOP
  216. 62000 DATA 0,2,4,6,8,10,15,20,40,60,80
  217. 62010 DATA 5,3.6,4.2,4.7,4.8,4.9,4.95,4.97,4.99,5,5
  218. 62020 DATA 10,4.9,7,8.1,8.95,9.05,9.6,9.9,1,10,10
  219. 62030 DATA 20,5.7,10,14,16,17,18,18.8,19.5,20,20
  220. 62040 DATA 30,6.3,11.5,16,19.5,22,26,28,19.5,30,30
  221. 62050 DATA 50,6.5,15,20.1,27,31,38,42,48,49.5,49.9
  222. 62060 DATA 70,6.6,17,23,30,37,42,54,63,68,69.5
  223. 62070 DATA 100,6.7,17.2,25,34,42,55,71,90,96,98
  224. 62080 DATA 200,6.8,17.4,28,39,51,70,102,160,180,190
  225. 62090 DATA 300,6.9,17.6,28.5,42,53,90,120,210,260,280
  226. 62100 DATA 500,7,17.7,29,44,55,95,160,295,370,420
  227. 62110 DATA 700,7.1,17.8,29.8,46,58,96,180,340,500,560
  228. 62120 DATA 1000,7.2,18,30,47,60,97,190,395,590,700
  229. 62130 END
  230.