home *** CD-ROM | disk | FTP | other *** search
/ Antennas / Antennas_CD-ROM_Walnut_Creek_September_1996.iso / w4mb / vol2 / basic / gamm.asc < prev    next >
Text File  |  1996-06-30  |  4KB  |  107 lines
  1. 2 ON ERROR GOTO 60000
  2. 3 CLS
  3. 10 PRINT "   ****************************************************************"
  4. 20 PRINT "   *                        GAMMA MATCH                           *"
  5. 30 PRINT "   *     REFERENCE- H. F. TOLLES, W7IBT,  HAM RADIO, MAY 1973     *
  6. 40 PRINT "   *                PROGRAM BY  R.P. HAVILAND, W4MB               *"
  7. 50 PRINT "   *                       COPYRGHT 1990                          *"
  8. 60 PRINT "   *          MINILAB BOOKS, DAYTONA BEACH, FL 32121-1086         *"
  9. 70 PRINT "   ****************************************************************"
  10. 80 DEF FNP(X)=INT(100*X+.5)/100
  11. 90 DEF FNACSH(X)=LOG(X+SQR(X*X-1))
  12. 100 PI=3.141592
  13. 200 PRINT " THIS PROGRAM CALCULATES GAMMA MATCH PARAMETERS FOR RADIATING"
  14. 210 PRINT "  ELEMENTS NEAR RESONANCE. DRIVE POINT RESISTANCE AND REACTANCE"
  15. 220 PRINT "    MUST BE KNOWN BY MEASUREMENT OR CALCULATION."
  16. 230 PRINT "     MULTIPLE GAMMA UNITS MAY BE FED FROM A SINGLE FEED POINT,"
  17. 240 PRINT "      FOR MATCH TO MULTIPLY-RESONANT (TRAP) ANTENNAS."
  18. 250 PRINT " FOR T-MATCH BALANCED LINE DESIGN PARAMATERS,
  19. 260 PRINT "  ENTER ONE-HALF OF THE FEED LINE CHARACTERISTIC IMPEDANCE,"
  20. 270 PRINT "   AND PLACE A GAMMA ROD AND CAPACITOR OF CALCULATED SIZE"
  21. 280 PRINT "    ON EACH SIDE OF THE RADIATOR CENTER" 
  22. 1000 PRINT 
  23. 1010 INPUT " ENTER OPERATING FREQUENCY, MHZ";FO
  24. 1020 LAM=984/FO
  25. 1030 INPUT " ENTER RADIATOR TYPE, H= HALF WAVE, Q=QUARTER WAVE";AT$
  26. 1200 PRINT 
  27. 1210 INPUT " ENTER RADIATOR DIAMETER AT DRIVE POINT, INCHES";DE
  28. 1220 INPUT "  ENTER GAMMA SECTION DIAMETER, INCHES";DG
  29. 1230 INPUT "   ENTER RADIATOR-GAMMA ELEMENT C-C SPACING, INCHES";S
  30. 1400 PRINT 
  31. 1410 INPUT " ENTER DRIVE POINT RESISTANCE, OHMS";RA
  32. 1420 INPUT "  ENTER DRIVE POINT REACTANCE, OHMS";XA
  33. 1430 INPUT "   ENTER FEED LINE CHARACTERISTIC IMPEDANCE, OHMS";ZO
  34. 1440 IF AT$<>"H" THEN 1500
  35. 1450 RA=RA/2
  36. 1460 XA=XA/2
  37. 1500 NUMF=(4*S*S-DE*DE+DG*DG)/(4*S*DG)
  38. 1510 DENF=(4*S*S+DE*DE-DG*DG)/(4*S*DE)
  39. 1520 HZ=(1+FNACSH(NUMF)/FNACSH(DENF))^2 'EQ 3
  40. 1530 IF HZ=<ZO/RA THEN PRINT " IMPOSSIBLE MATCHING DIMENSIONS": GOTO 1200
  41. 1600 ZG=60*FNACSH((4*S*S-DE*DE-DG*DG)/(2*DE*DG))
  42. 1610 T=HZ/ZG 
  43. 1620 A=(ZO*XA)/(HZ*RA-ZO)
  44. 1630 B=(ZO*(RA*RA+XA*XA))/(HZ*RA-ZO)
  45. 1640 QF=A+SQR(A*A+B)
  46. 1650 XS=ZO*XA+SQR((ZO*XA)^2+ZO*(HZ*RA-ZO)*(RA*RA+XA*XA))
  47. 1660 XS=XS*HZ/(HZ*RA-ZO)  'EQ 6
  48. 1700 LGAM=ATN(QF*T) 'RAD
  49. 1710 E=ZO/RA*(RA*RA+XA*XA)/QF
  50. 1720 F=ZO/RA*XA
  51. 1730 CG=1000000!/(2*PI*(E+F)*FO)
  52. 1740 IF AT$="Q" THEN RA=2*RA:XA=2*XA
  53. 2000 PRINT 
  54. 2010 PRINT " LENGTH, CENTER OF ANTENNA TO END OF GAMMA ROD"
  55. 2020 PRINT "                             =";FNP(LGAM*360/2/PI);"DEGREES"
  56. 2030 PRINT "                             =";FNP(LGAM*LAM*6/PI*.956);"INCHES"
  57. 2040 PRINT " GAMMA CAPACITY=";FNP(CG);"PF"
  58. 2050 PRINT
  59. 3000 INPUT " ENTER F=VARY FREQUENCY , R=RERUN, P=PRINTER COPY, Q=QUIT";T$
  60. 3010 IF T$="F" THEN GOSUB 5000
  61. 3020 IF T$="R" THEN 1010
  62. 3030 IF T$="P" THEN GOSUB 4000
  63. 3040 IF T$="Q" THEN STOP
  64. 3050 PRINT 
  65. 3060 GOTO 3000
  66. 4000 LPRINT "               GAMMA MATCH"
  67. 4010 LPRINT "  OPERATING FREQUENCY=";FO;"MHZ"
  68. 4020 LPRINT "   ANTENNA RESISTANCE=";RA;"OHMS"
  69. 4030 LPRINT "            REACTANCE=";XA;"OHMS
  70. 4040 LPRINT "       LINE IMPEDANCE=";ZO;"OHMS
  71. 4050 LPRINT 
  72. 4060 LPRINT " RADIATOR DIAMETER=";DE;"INCHES
  73. 4070 LPRINT " GAMMA SECTION DIAMETER=";DG;"INCHES"
  74. 4080 LPRINT "                 LENGTH=";FNP(LGAM*LAM*6/PI*.956);"INCHES
  75. 4090 LPRINT "GAMMA CAPACITOR=";FNP(CG);"PF"
  76. 4100 LPRINT
  77. 4110 RETURN
  78. 5000 PRINT 
  79. 5010 PRINT " USE THIS ROUTINE TO DETERMINE USEFUL MATCHING RANGE"
  80. 5020 INPUT "  ENTER FREQUENCY, MHZ";F1
  81. 5040 INPUT "   ENTER ANTENNA RESISTANCE AT THIS FREQUENCY, OHMS";RA1
  82. 5050 INPUT "    ENTER ANTENNA REACTANCE AT THIS FREQUENCY, OHMS";XA1
  83. 5060 RA1=RA1/2
  84. 5070 XA1=XA1/2
  85. 5080 XC=-1000000!/2/PI/CG
  86. 5100 KLG1=LGAM*F1/FO   'RADIANS
  87. 5110 XS1=ZG*TAN(KLG1)
  88. 5120 M1=XS1*HZ*SQR(RA1*RA1+XA1*XA1)
  89. 5130 M1=M1/(SQR((HZ*RA1)^2+(XS1+HZ*XA1)^2))
  90. 5140 PRINT 
  91. 5150 ANG1=ATN(NUM1/XS1/RA1+XA1/RA1)
  92. 5160 RL=M1*COS(ANG1)
  93. 5170 XL=M1*SIN(ANG1)-1000000!/(2*PI*F1*CG)
  94. 5180 QA=SQR((RL+ZO)^2+XL*XL)
  95. 5190 QB=SQR((RL-ZO)^2+XL*XL)
  96. 5200 SWR=(QA+QB)/(QA-QB) 
  97. 5300 PRINT 
  98. 5310 PRINT " FEED RESISTANCE=";FNP(RL)
  99. 5320 PRINT "       REACTANCE=";FNP(XL)
  100. 5330 PRINT "             SWR=";FNP(SWR)
  101. 5350 INPUT " ENTER ANOTHER FREQUENCY, 0=END";F1
  102. 5360 IF F1=0 THEN RETURN
  103. 5370 GOTO 5040
  104. 59999 END
  105. 60000 PRINT " ERROR";ERR;" AT LINE";ERL
  106. 60010 STOP
  107.