home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Antennas
/
Antennas_CD-ROM_Walnut_Creek_September_1996.iso
/
w4mb
/
vol2
/
basic
/
eltp.asc
< prev
next >
Wrap
Text File
|
1996-06-30
|
3KB
|
75 lines
3 CLS
10 PRINT " ***************************************************************"
20 PRINT " * ANTENNA ELEMENT TAPER CORRECTION *"
30 PRINT " * R.P. HAVILAND, W4MB *"
40 PRINT " * PROGRAM COPYRGHT 1990 *"
50 PRINT " * MINILAB BOOKS, DAYTONA BEACH, FL 32121-1086 *"
70 PRINT " ***************************************************************"
80 DEF FNP(X)=INT(100*X+.5)/100
90 PI=3.141593:DTORAD=180/PI
100 PRINT
110 PRINT " TO CORRECT DIPOLE ANTENNA ELEMENT LENGTH FOR TAPERING DIAMETERS,"
120 PRINT " FIRST CALCULATE RFERENCE ELEMENT LENGTH AND DIAMETER BY NBS YAGI OR
130 PRINT " ANOTHER PROGRAM, OR USE KNOWN DESIGN DATA AS REFERENCE."
140 PRINT " THEN USE A SAG PROGRAM TO DEVELOP ACCEPTABLE NUMBER OF SECTIONS"
150 PRINT " AND SECTION LENGTHS FOR EXPECTED WIND/ICE LOADS"
160 PRINT " THIS PROGRAM ASSUMES THAT ONLY OUTERMOST SECTION LENGTH IS CHANGED"
170 PRINT " IF CHANGE IS LARGE, CHECK USING SAG PROGRAM"
180 PRINT " AND REVISE IF NECESSARY"
190 PRINT
200 INPUT " ENTER DESIGN FREQUENCY, MHZ";FREQ:IF FREQ=<0 THEN 200
210 LAM=299.8/FREQ
220 PRINT
230 PRINT " ***** ALL DIMENSIONS ARE IN INCHES *****"
240 PRINT
300 INPUT " ENTER LENGTH, CENTER TO END OF REFERENCE ELEMENT";HREF
310 PRINT
320 PRINT " ENTER EITHER CALCULATED CYLINDRICAL ELEMENT DIAMETER, OR"
330 PRINT " DIAMETER OF REFERENCE TAPERED ELEMENT AT MID-POINT, CENTER TO END"
340 INPUT " ENTER REFERENCE DIAMETER";DC
350 NREF=4.373-LOG(FREQ*DC)/LOG(10)
360 PRINT
400 INPUT " ENTER NUMBER OF SECTIONS IN NEW TAPERED ELEMENT";SECT
410 DIM SLEN(SECT), ACLEN(SECT),SDIA(SECT)
420 FOR N=1 TO SECT
430 PRINT:PRINT"APPROXIMATE ADDED LENGTH REQUIRED=";FNP(HREF-ACLEN(N-1))
440 PRINT " ENTER LENGTH OF SECTION";N;", A COMMA, THEN ITS DIAMETER"
450 INPUT SLEN(N),SDIA(N)
460 ACLEN(N)=ACLEN(N-1)+SLEN(N)
470 NEXT N
480 THLAST=0
490 HNEW=0
500 FOR N=1 TO SECT
510 NSECT=4.373-LOG(FREQ*SDIA(N))/LOG(10)
520 MRAT=(NSECT-.7869)/(NREF-.7869)
530 THNEW=90*ACLEN(N)/HREF
540 FACT=28.648*(SIN(2*THNEW/DTORAD)-SIN(2*THLAST/DTORAD))/(THNEW-THLAST)
550 SEQ=SLEN(N)/2*(MRAT+1/MRAT+FACT*(MRAT-1/MRAT))
560 HNEW=HNEW +SEQ
570 THLAST=THNEW
580 NEXT N
600 LCORR=HREF-HNEW
610 IF ABS(LCORR)<.01 THEN 1000
620 SLEN(SECT)=SLEN(SECT)+LCORR
630 ACLEN(SECT)=ACLEN(SECT)+LCORR
640 GOTO 480
1000 PRINT
1010 PRINT " WITH LENGTHS ADJUSTED FOR TAPER"
1020 PRINT " SECTION DIMENSIONS ARE"
1030 PRINT
1040 PRINT " SECTION SECTION LENGTH FROM CENTER"
1050 PRINT " NUMBER LENGTH TO SECTION END"
1060 FOR N=1 TO SECT
1070 PRINT N,FNP(SLEN(N)),FNP(ACLEN(N))
1080 NEXT N
1200 PRINT
1210 PRINT " OVERALL ELEMENT LENGTH, END TO END"
1220 PRINT ,FNP(2*ACLEN(SECT))
1230 PRINT
1240 PRINT " SECTION LENGTHS DO NOT INCLUDE INSERT INTO PREVIOUS SECTION"
1300 INPUT " ENTER R= RERUN, OTHER= QUIT";T$
1310 IF T$<>"R" THEN 1400
1320 ERASE SLEN,ACLEN,SDIA
1330 GOTO 200
1400 END