home *** CD-ROM | disk | FTP | other *** search
/ Antennas / Antennas_CD-ROM_Walnut_Creek_September_1996.iso / w4mb / vol2 / basic / eltp.asc < prev    next >
Text File  |  1996-06-30  |  3KB  |  75 lines
  1. 3 CLS
  2. 10 PRINT "   ***************************************************************"
  3. 20 PRINT "   *           ANTENNA ELEMENT TAPER CORRECTION                  *"
  4. 30 PRINT "   *                R.P. HAVILAND, W4MB                          *"
  5. 40 PRINT "   *               PROGRAM COPYRGHT 1990                         *"
  6. 50 PRINT "   *       MINILAB BOOKS, DAYTONA BEACH, FL 32121-1086           *"
  7. 70 PRINT "   ***************************************************************"
  8. 80 DEF FNP(X)=INT(100*X+.5)/100
  9. 90 PI=3.141593:DTORAD=180/PI
  10. 100 PRINT 
  11. 110 PRINT " TO CORRECT DIPOLE ANTENNA ELEMENT LENGTH FOR TAPERING DIAMETERS,"
  12. 120 PRINT "  FIRST CALCULATE RFERENCE ELEMENT LENGTH AND DIAMETER BY NBS YAGI OR
  13. 130 PRINT "   ANOTHER PROGRAM, OR USE KNOWN DESIGN DATA AS REFERENCE."
  14. 140 PRINT " THEN USE A SAG PROGRAM TO DEVELOP ACCEPTABLE NUMBER OF SECTIONS"
  15. 150 PRINT "  AND SECTION LENGTHS FOR EXPECTED WIND/ICE LOADS"
  16. 160 PRINT " THIS PROGRAM ASSUMES THAT ONLY OUTERMOST SECTION LENGTH IS CHANGED"
  17. 170 PRINT "  IF CHANGE IS LARGE, CHECK USING SAG PROGRAM" 
  18. 180 PRINT "   AND REVISE IF NECESSARY"
  19. 190 PRINT 
  20. 200 INPUT " ENTER DESIGN FREQUENCY, MHZ";FREQ:IF FREQ=<0 THEN 200
  21. 210 LAM=299.8/FREQ
  22. 220 PRINT
  23. 230 PRINT "     *****    ALL DIMENSIONS ARE IN INCHES    *****"
  24. 240 PRINT  
  25. 300 INPUT " ENTER LENGTH, CENTER TO END OF REFERENCE ELEMENT";HREF
  26. 310 PRINT 
  27. 320 PRINT " ENTER EITHER CALCULATED CYLINDRICAL ELEMENT DIAMETER, OR"
  28. 330 PRINT "  DIAMETER OF REFERENCE TAPERED ELEMENT AT MID-POINT, CENTER TO END"
  29. 340 INPUT "   ENTER REFERENCE DIAMETER";DC
  30. 350 NREF=4.373-LOG(FREQ*DC)/LOG(10)
  31. 360 PRINT 
  32. 400 INPUT " ENTER NUMBER OF SECTIONS IN NEW TAPERED ELEMENT";SECT
  33. 410 DIM SLEN(SECT), ACLEN(SECT),SDIA(SECT)
  34. 420 FOR N=1 TO SECT
  35. 430 PRINT:PRINT"APPROXIMATE ADDED LENGTH REQUIRED=";FNP(HREF-ACLEN(N-1))
  36. 440 PRINT " ENTER LENGTH OF SECTION";N;", A COMMA, THEN ITS DIAMETER"
  37. 450 INPUT SLEN(N),SDIA(N)
  38. 460 ACLEN(N)=ACLEN(N-1)+SLEN(N)
  39. 470 NEXT N
  40. 480 THLAST=0
  41. 490 HNEW=0
  42. 500 FOR N=1 TO SECT
  43. 510 NSECT=4.373-LOG(FREQ*SDIA(N))/LOG(10)
  44. 520 MRAT=(NSECT-.7869)/(NREF-.7869)
  45. 530 THNEW=90*ACLEN(N)/HREF 
  46. 540 FACT=28.648*(SIN(2*THNEW/DTORAD)-SIN(2*THLAST/DTORAD))/(THNEW-THLAST)
  47. 550 SEQ=SLEN(N)/2*(MRAT+1/MRAT+FACT*(MRAT-1/MRAT))
  48. 560 HNEW=HNEW +SEQ
  49. 570 THLAST=THNEW
  50. 580 NEXT N
  51. 600 LCORR=HREF-HNEW 
  52. 610 IF ABS(LCORR)<.01 THEN 1000
  53. 620 SLEN(SECT)=SLEN(SECT)+LCORR
  54. 630 ACLEN(SECT)=ACLEN(SECT)+LCORR
  55. 640 GOTO 480
  56. 1000 PRINT 
  57. 1010 PRINT " WITH LENGTHS ADJUSTED FOR TAPER"
  58. 1020 PRINT "   SECTION DIMENSIONS ARE"
  59. 1030 PRINT 
  60. 1040 PRINT " SECTION    SECTION    LENGTH FROM CENTER"
  61. 1050 PRINT "  NUMBER     LENGTH      TO SECTION END"
  62. 1060 FOR N=1 TO SECT
  63. 1070 PRINT N,FNP(SLEN(N)),FNP(ACLEN(N))
  64. 1080 NEXT N
  65. 1200 PRINT 
  66. 1210 PRINT " OVERALL ELEMENT LENGTH, END TO END"
  67. 1220 PRINT ,FNP(2*ACLEN(SECT))
  68. 1230 PRINT
  69. 1240 PRINT " SECTION LENGTHS DO NOT INCLUDE INSERT INTO PREVIOUS SECTION"
  70. 1300 INPUT "  ENTER R= RERUN, OTHER= QUIT";T$
  71. 1310 IF T$<>"R" THEN 1400
  72. 1320 ERASE SLEN,ACLEN,SDIA
  73. 1330 GOTO 200
  74. 1400 END
  75.