home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Antennas
/
Antennas_CD-ROM_Walnut_Creek_September_1996.iso
/
w4mb
/
vol2
/
basic
/
elsg.asc
< prev
next >
Wrap
Text File
|
1996-06-30
|
5KB
|
125 lines
2 ON ERROR GOTO 60000
3 CLS
10 PRINT " ***************************************************************"
20 PRINT " * ANTENNA ELEMENT DIAMETER CORRECTION *"
30 PRINT " * R.P. HAVILAND, W4MB *"
40 PRINT " * PROGRAM COPYRGHT 1991 *"
50 PRINT " * MINILAB BOOKS, DAYTONA BEACH, FL 32121-1086 *"
60 PRINT " ***************************************************************"
70 DEF FNP (X) = INT(100 * X + .5) / 100
80 MTOF = 39.37 / 12: MTIN = 39.37
90 PI = 3.141593: DTORAD = 180 / PI
100 PRINT
200 PRINT " THIS PROGRAM FIRST CALCULATES ANTENNA ELEMENT DIMENSIONS FOR"
210 PRINT " PROPORTIONAL SCALING TO A NEW FREQUENCY."
220 PRINT " IT THEN CALCULATES THE REVISED ELEMENT LENGTH"
230 PRINT " AS CONDUCTOR SIZE IS CHANGED. IT IS USEABLE FOR ELEMENTS"
240 PRINT " WITHIN 0.8-1.2 TIMES RESONANCE, MAINTAINING THE SAME"
250 PRINT " REACTANCE WITH SIZE CHANGE, AND THEREFORE THE SAME PERFORMANCE."
260 PRINT " LENGTH IS OVERALL LENGTH OF A DIPOLE ELEMENT, OR"
270 PRINT " CIRCUMFERENCE/PERIMETER OF LOOP ELEMENTS."
280 PRINT
290 PRINT
300 INPUT " ENTER ORIGINAL FREQUENCY, MHZ"; FORG
310 INPUT " ENTER NEW FREQUENCY,MHX, 0=NO FREQUENCY CHANGE"; FREQ
320 IF FREQ < 0 OR FORG <= 0 THEN 300
330 IF FREQ = 0 THEN FREQ = FORG
400 PRINT " ENTER ANTENNA ELEMENT TYPE, 1= DIPOLE"
410 PRINT " 2= ONE WAVELENGTH OCTAGON LOOP"
420 PRINT " 3= ONE WAVELENGTH SQUARE LOOP"
430 PRINT " 4= ONE WAVELENGTH 60 DEG. DELTA LOOP"
440 PRINT " USE OCTAGON FOR CIRCULAR LOOP"
450 INPUT ETYPE
460 IF ETYPE < 1 OR ETYPE > 4 THEN 400
600 PRINT
610 INPUT " ENTER ORIGINAL ELEMENT DIAMETER, INCHES"; ODIA
620 INPUT " ENTER ORIGINAL ELEMENT LENGTH, INCHES"; OLEN
700 SCDIA = ODIA * FORG / FREQ
710 SCLEN = OLEN * FORG / FREQ
720 PRINT " AT FREQUENCY="; FREQ; "MHZ"
730 PRINT " SCALED DIAMETER="; FNP(SCDIA); "INCHES"
740 PRINT " SCALED LENGTH ="; FNP(SCLEN); "INCHES"
800 LAMBDA = 299.7 / FREQ
810 LAMIN = LAMBDA * MTIN
820 XRES = 0
830 NEWDIA = SCDIA
840 CLEN = SCLEN
850 DIA = SCDIA
900 GOSUB 12000 'K FACTORS FOR ANTENNA TYPE
910 GOSUB 6000 'FOR REFERENCE LENGTH
920 GOSUB 9000 'FOR REACTANCE
930 REACT = XREF
1000 PRINT
1010 PRINT " RESONANT LENGTH, SCALED DIAMETER ELEMENT="; FNP(LRES); "WAVELEMGTHS"
1020 PRINT " REACTANCE OF SCALED ELEMENT="; FNP(REACT); "OHMS"
1200 PRINT
1210 INPUT " ENTER REVISED ELEMENT DIAMETER, INCHES"; NEWDIA
1500 PRINT
1510 CLEN = SCLEN
1520 DIA = NEWDIA
1530 GOSUB 12000 'SET KVALUES,SIZE RATIO
1540 GOSUB 6000 'FOR RESONANT LENGTH
1550 GOSUB 8000 ' FOR REVISED LENGTH
3000 LADJMETER = LADJ * LAMBDA
3010 LADJFT = LADJMETER * MTOF
3020 LADJIN = LADJMETER * MTIN
3200 PRINT
3210 PRINT " REVISED ELEMENT CHARACTERSTICS ARE"
3220 PRINT " REACTANCE="; FNP(XREF); "OHMS"
3230 PRINT " DIAMETER="; NEWDIA; "INCHES"
3240 PRINT " ELEMENT LENGTH, WAVELENGTHS="; FNP(LADJ)
3250 PRINT " METERS="; FNP(LADJMETER)
3260 PRINT " FEET="; FNP(LADJFT)
3270 PRINT " INCHES="; FNP(LADJIN)
3600 PRINT
3610 PRINT " ENTER D= A DIFFERENT NEW DIAMETER"
3620 PRINT " ENTER L= ANOTHER ELEMENT TYPE"
3630 PRINT " R= RERUN"
3640 PRINT " OTHER= QUIT"
3650 INPUT T$
3660 IF T$ = "R" THEN 300
3670 IF T$ = "L" THEN 400
3680 IF T$ = "D" THEN 1200
3690 STOP
5999 'LENGTH KNOWN
6000 LRES = K0 + K1 * TF + K2 * TF * TF
6010 LREF = SCLEN / LAMIN
6020 RETURN
7999 ' CALCULATE LENGTH
8000 LADJ = (XREF - XTUR) * (LRES - LTUR) / (XRES - XTUR) + LTUR'WAVELENGTHS
8030 RETURN
8999 'CALCULATE REACTANCE
9000 XREF = (XRES - XTUR) * (LREF - LTUR) / (LRES - LTUR) + XTUR
9010 RETURN
12000 REM SET TYPE CONSTANTS
12110 IF ETYPE <> 1 THEN 12200
12120 XTUR = 24: LTUR = .4975'DIPOLE
12130 K0 = .427614: K1 = 9.933301E-03: K2 = -3.93074E-04
12140 TF = LOG(LAMIN / DIA)
12150 IF TF < 4.6 OR TF > 13.8 THEN GOSUB 13000
12160 GOTO 12600
12200 IF ETYPE <> 2 THEN 12300
12210 XTUR = -95: LTUR = 1!'CIRCULAR
12220 K0 = 1.49293: K1 = -.11153: K2 = .0067004
12230 TF = LOG(CLEN / DIA)
12240 IF TF < 4.3 OR TF > 9.3 THEN GOSUB 13000
12250 GOTO 12600
12300 IF ETYPE <> 3 THEN 12400
12310 XTUR = -105: LTUR = 1.064'SQUARE
12320 K0 = 1.4485: K1 = -.0647924: K2 = .0030161
12330 TF = LOG(CLEN / DIA)
12340 IF TF < 5.7 OR TF > 11.5 THEN GOSUB 13000
12350 GOTO 12600
12400 IF ETYPE <> 4 THEN 12600
12410 XTUR = -100: LTUR = 1.05'TRIANGLE
12420 K0 = 1.30343: K1 = -2.152258E-02: K2 = 0
12430 TF = LOG(CLEN / DIA)
12440 IF T < 7.2 OR TF > 9.3 THEN GOSUB 13000
12600 RETURN
13000 PRINT " ERROR CAUTION-LENGTH/DIAMETER RATIO IS BEYOND TABLES"
13010 PRINT " EXPECT ERRORS. TRY DIAMETER NEARER TO REFERENCE SIZE"
13020 RETURN
60000 PRINT " ERROR"; ERR; "AT LINE"; ERL
60010 STOP