home *** CD-ROM | disk | FTP | other *** search
/ Antennas / Antennas_CD-ROM_Walnut_Creek_September_1996.iso / w4mb / vol2 / basic / elsg.asc < prev    next >
Text File  |  1996-06-30  |  5KB  |  125 lines
  1. 2 ON ERROR GOTO 60000
  2. 3 CLS
  3. 10 PRINT "   ***************************************************************"
  4. 20 PRINT "   *          ANTENNA ELEMENT DIAMETER CORRECTION                *"
  5. 30 PRINT "   *                R.P. HAVILAND, W4MB                          *"
  6. 40 PRINT "   *               PROGRAM COPYRGHT 1991                         *"
  7. 50 PRINT "   *       MINILAB BOOKS, DAYTONA BEACH, FL 32121-1086           *"
  8. 60 PRINT "   ***************************************************************"
  9. 70 DEF FNP (X) = INT(100 * X + .5) / 100
  10. 80 MTOF = 39.37 / 12: MTIN = 39.37
  11. 90 PI = 3.141593: DTORAD = 180 / PI
  12. 100 PRINT
  13. 200 PRINT " THIS PROGRAM FIRST CALCULATES ANTENNA ELEMENT DIMENSIONS FOR"
  14. 210 PRINT "  PROPORTIONAL SCALING TO A NEW FREQUENCY."
  15. 220 PRINT " IT THEN CALCULATES THE REVISED ELEMENT LENGTH"
  16. 230 PRINT "  AS CONDUCTOR SIZE IS CHANGED. IT IS USEABLE FOR ELEMENTS"
  17. 240 PRINT "   WITHIN 0.8-1.2 TIMES RESONANCE, MAINTAINING THE SAME"
  18. 250 PRINT "    REACTANCE WITH SIZE CHANGE, AND THEREFORE THE SAME PERFORMANCE."
  19. 260 PRINT " LENGTH IS OVERALL LENGTH OF A DIPOLE ELEMENT, OR"
  20. 270 PRINT "  CIRCUMFERENCE/PERIMETER OF LOOP ELEMENTS."
  21. 280 PRINT
  22. 290 PRINT
  23. 300 INPUT " ENTER ORIGINAL FREQUENCY, MHZ"; FORG
  24. 310 INPUT "  ENTER NEW FREQUENCY,MHX, 0=NO FREQUENCY CHANGE"; FREQ
  25. 320 IF FREQ < 0 OR FORG <= 0 THEN 300
  26. 330 IF FREQ = 0 THEN FREQ = FORG
  27. 400 PRINT " ENTER ANTENNA ELEMENT TYPE, 1= DIPOLE"
  28. 410 PRINT "                             2= ONE WAVELENGTH OCTAGON LOOP"
  29. 420 PRINT "                             3= ONE WAVELENGTH SQUARE LOOP"
  30. 430 PRINT "                             4= ONE WAVELENGTH 60 DEG. DELTA LOOP"
  31. 440 PRINT "           USE OCTAGON FOR CIRCULAR LOOP"
  32. 450 INPUT ETYPE
  33. 460 IF ETYPE < 1 OR ETYPE > 4 THEN 400
  34. 600 PRINT
  35. 610 INPUT " ENTER ORIGINAL ELEMENT DIAMETER, INCHES"; ODIA
  36. 620 INPUT "   ENTER ORIGINAL ELEMENT LENGTH, INCHES"; OLEN
  37. 700 SCDIA = ODIA * FORG / FREQ
  38. 710 SCLEN = OLEN * FORG / FREQ
  39. 720 PRINT " AT FREQUENCY="; FREQ; "MHZ"
  40. 730 PRINT "    SCALED DIAMETER="; FNP(SCDIA); "INCHES"
  41. 740 PRINT "    SCALED LENGTH  ="; FNP(SCLEN); "INCHES"
  42. 800 LAMBDA = 299.7 / FREQ
  43. 810 LAMIN = LAMBDA * MTIN
  44. 820 XRES = 0
  45. 830 NEWDIA = SCDIA
  46. 840 CLEN = SCLEN
  47. 850 DIA = SCDIA
  48. 900 GOSUB 12000 'K FACTORS FOR ANTENNA TYPE
  49. 910 GOSUB 6000 'FOR REFERENCE LENGTH
  50. 920 GOSUB 9000 'FOR REACTANCE
  51. 930 REACT = XREF
  52. 1000 PRINT
  53. 1010 PRINT " RESONANT LENGTH, SCALED DIAMETER ELEMENT="; FNP(LRES); "WAVELEMGTHS"
  54. 1020 PRINT "  REACTANCE OF SCALED ELEMENT="; FNP(REACT); "OHMS"
  55. 1200 PRINT
  56. 1210 INPUT "  ENTER REVISED ELEMENT DIAMETER, INCHES"; NEWDIA
  57. 1500 PRINT
  58. 1510 CLEN = SCLEN
  59. 1520 DIA = NEWDIA
  60. 1530 GOSUB 12000  'SET KVALUES,SIZE RATIO
  61. 1540 GOSUB 6000   'FOR RESONANT LENGTH
  62. 1550 GOSUB 8000 ' FOR REVISED LENGTH
  63. 3000 LADJMETER = LADJ * LAMBDA
  64. 3010 LADJFT = LADJMETER * MTOF
  65. 3020 LADJIN = LADJMETER * MTIN
  66. 3200 PRINT
  67. 3210 PRINT " REVISED ELEMENT CHARACTERSTICS ARE"
  68. 3220 PRINT "  REACTANCE="; FNP(XREF); "OHMS"
  69. 3230 PRINT "   DIAMETER="; NEWDIA; "INCHES"
  70. 3240 PRINT "    ELEMENT LENGTH, WAVELENGTHS="; FNP(LADJ)
  71. 3250 PRINT "                         METERS="; FNP(LADJMETER)
  72. 3260 PRINT "                           FEET="; FNP(LADJFT)
  73. 3270 PRINT "                         INCHES="; FNP(LADJIN)
  74. 3600 PRINT
  75. 3610 PRINT " ENTER   D= A DIFFERENT NEW DIAMETER"
  76. 3620 PRINT " ENTER   L= ANOTHER ELEMENT TYPE"
  77. 3630 PRINT "         R= RERUN"
  78. 3640 PRINT "     OTHER= QUIT"
  79. 3650 INPUT T$
  80. 3660 IF T$ = "R" THEN 300
  81. 3670 IF T$ = "L" THEN 400
  82. 3680 IF T$ = "D" THEN 1200
  83. 3690 STOP
  84. 5999 'LENGTH KNOWN
  85. 6000 LRES = K0 + K1 * TF + K2 * TF * TF
  86. 6010 LREF = SCLEN / LAMIN
  87. 6020 RETURN
  88. 7999 ' CALCULATE LENGTH
  89. 8000 LADJ = (XREF - XTUR) * (LRES - LTUR) / (XRES - XTUR) + LTUR'WAVELENGTHS
  90. 8030 RETURN
  91. 8999 'CALCULATE REACTANCE
  92. 9000 XREF = (XRES - XTUR) * (LREF - LTUR) / (LRES - LTUR) + XTUR
  93. 9010 RETURN
  94. 12000 REM SET TYPE CONSTANTS
  95. 12110 IF ETYPE <> 1 THEN 12200
  96. 12120 XTUR = 24: LTUR = .4975'DIPOLE
  97. 12130 K0 = .427614: K1 = 9.933301E-03: K2 = -3.93074E-04
  98. 12140 TF = LOG(LAMIN / DIA)
  99. 12150 IF TF < 4.6 OR TF > 13.8 THEN GOSUB 13000
  100. 12160 GOTO 12600
  101. 12200 IF ETYPE <> 2 THEN 12300
  102. 12210 XTUR = -95: LTUR = 1!'CIRCULAR
  103. 12220 K0 = 1.49293: K1 = -.11153: K2 = .0067004
  104. 12230 TF = LOG(CLEN / DIA)
  105. 12240 IF TF < 4.3 OR TF > 9.3 THEN GOSUB 13000
  106. 12250 GOTO 12600
  107. 12300 IF ETYPE <> 3 THEN 12400
  108. 12310 XTUR = -105: LTUR = 1.064'SQUARE
  109. 12320 K0 = 1.4485: K1 = -.0647924: K2 = .0030161
  110. 12330 TF = LOG(CLEN / DIA)
  111. 12340 IF TF < 5.7 OR TF > 11.5 THEN GOSUB 13000
  112. 12350 GOTO 12600
  113. 12400 IF ETYPE <> 4 THEN 12600
  114. 12410 XTUR = -100: LTUR = 1.05'TRIANGLE
  115. 12420 K0 = 1.30343: K1 = -2.152258E-02: K2 = 0
  116. 12430 TF = LOG(CLEN / DIA)
  117. 12440 IF T < 7.2 OR TF > 9.3 THEN GOSUB 13000
  118. 12600 RETURN
  119. 13000 PRINT " ERROR CAUTION-LENGTH/DIAMETER RATIO IS BEYOND TABLES"
  120. 13010 PRINT "   EXPECT ERRORS. TRY DIAMETER NEARER TO REFERENCE SIZE"
  121. 13020 RETURN
  122. 60000 PRINT " ERROR"; ERR; "AT LINE"; ERL
  123. 60010 STOP
  124.  
  125.