home *** CD-ROM | disk | FTP | other *** search
/ Antennas / Antennas_CD-ROM_Walnut_Creek_September_1996.iso / w4mb / vol2 / basic / bbrl.asc < prev    next >
Text File  |  1996-06-30  |  5KB  |  122 lines
  1. 2 ON ERROR GOTO 60000 
  2. 5 CLS
  3. 10 PRINT"****************************************************************"
  4. 20 PRINT"*             BROAD-BAND RESISTANCE LOADED DIPOLES             *"
  5. 30 PRINT"*                   REFERENCE-SCHELKUNOFF,                     *"
  6. 40 PRINT"*              ELECTROMAGNETIC WAVES, PAGE 452FF               *"
  7. 50 PRINT"*               PROGRAM BY  R.P. HAVILAND, W4MB                *"
  8. 60 PRINT"*                      COPYRIGHT 1990                          *"
  9. 70 PRINT"*         MINILAB BOOKS, DAYTONA BEACH, FL 32119-1068          *"
  10. 80 PRINT"****************************************************************"
  11. 90 PI=3.14159
  12. 100 DEF FNP(X)=(INT(X*10+.5))/10
  13. 110 PRINT " TO SECURE BROADBAND OPERATION OF A DIPOLE "
  14. 120 PRINT "  SHUNT ITS FEED POINT WITH A RESISTANCE,"
  15. 130 PRINT "   A TYPICAL 100 OHMS BEING THE INITIAL VALUE USED HERE"
  16. 140 PRINT " THIS REDUCES SWR,BUT INTRODUCES A MATCH LOSS"
  17. 150 PRINT "  THE LOSS ON RECEPTION MAY BE UNNOTICABLE, SINCE
  18. 160 PRINT "   ANTENNA NOISE AND SIGNAL ARE REDUCED BY THE SAME RATIO."
  19. 170 PRINT " THIS PROGRAM CALCULATES THE RESULTING SWR AND LOSS" 
  20. 180 PRINT "  DUE TO MATCHING RESISTOR, COMPARED TO A TRUE MATCH."
  21. 200 PRINT 
  22. 210 INPUT "ENTER P FOR PAPER COPY OF DATA, OTHER =SCREEN ONLY";P$ 
  23. 220 PRINT 
  24. 300 INPUT"ENTER ANTENNA WIRE SIZE, AWG";WS
  25. 310 DA=.46/(92^((WS+3)/39))
  26. 320 INPUT "ENTER CENTER TO END LENGTH OF ANTENNA, FEET";LE
  27. 330 INPUT "ENTER FEEDLINE IMPEDANCE, ZO, OHMS ";ZO
  28. 340 RL=100 'INITIAL VALUE OF LOAD
  29. 350 RS=0   'INITIAL VALUE OF SERIES
  30. 360 PRINT 
  31. 1000 IF P$<>"P" THEN 1100
  32. 1010 LPRINT "OPERATION OF A DIPOLE RESISTANCE LOADED FOR BROADBANDING"
  33. 1020 LPRINT " DIPOLE LENGTH, CENTER TO END";LE;"FEET"
  34. 1030 LPRINT "  CONDUCTOR SIZE #";WS;"AWG"
  35. 1040 LPRINT "   FEEDLINE IMPEDANCE";ZO;"OHMS"
  36. 1050 LPRINT "LOAD RESISTANCE";RL;"OHMS":LPRINT:LPRINT
  37. 1060 LPRINT "FREQ.  ANTENNA-ONLY           COMBINATION";
  38. 1070 LPRINT "                COMBINATION"
  39. 1080 LPRINT "MHZ   R         X            R            X";
  40. 1090 LPRINT "            SWR          DB LOSS"
  41. 1100 PRINT "FREQ.   ANTENNA-ONLY           COMBINATION";
  42. 1110 PRINT "                COMBINATION"
  43. 1120 PRINT  "MHZ   R        X              R           X";
  44. 1130 PRINT "              SWR         DB LOSS"
  45. 1200 FOR FO=2 TO 30 STEP 2
  46. 1210 GOSUB 5300  'FOR ANTENNA ONLY
  47. 1220 GOSUB 6000  'FOR COMBINATION
  48. 1230 GOSUB 5000  'FOR PRINTOUT
  49. 1240 NEXT FO
  50. 1250 PRINT  
  51. 1500 INPUT "ENTER L=NEW LOAD RESISTOR, F=A FREQUENCY, R=RERUN, S=STOP";T$
  52. 1510 IF T$="S" THEN STOP
  53. 1520 IF T$="L" THEN INPUT "LOAD RESISTANCE";RL:GOTO 1000
  54. 1530 IF T$="R" THEN 200
  55. 1540 IF T$<>"F" THEN 1500
  56. 1550 INPUT "FREQUENCY";FO
  57. 1560 GOSUB 5300  'FOR ANTENNA ONLY
  58. 1570 GOSUB 6000  'FOR COMBINATION
  59. 1580 GOSUB 5000  'FOR PRINTOUT
  60. 1590 GOTO 1500
  61. 5000 IF FO<10 THEN PRINT " ";
  62. 5010 PRINT FNP(FO);"   ";INT(RI);"     ";INT(XI);"       ";INT(RC);"        ";INT(XC);"         ";FNP(SWR);"         ";FNP(LOSS)
  63. 5020 IF P$<>"P" THEN 5050
  64. 5030 IF FO<10 THEN PRINT " ";                      
  65. 5040 LPRINT INT(FO);"    ";INT(RI);"     ";INT(XI);"        ";INT(RC);"        ";INT(XC);"        ";FNP(SWR);"        ";FNP(LOSS)
  66. 5050 RETURN
  67. 5299 REM DO ANTENNA R,X AFTER SCHELKUNOFF                  
  68. 5300 LA=984/FO
  69. 5310 LP=2*PI*LE/LA
  70. 5320 KA=120*(LOG(48*LE/DA)-1)        
  71. 5330 LQ=LP*2
  72. 5340 LR=LP*4
  73. 5350 IF LQ>5 THEN C2=SIN(LQ)/LQ:S2=PI/2-COS(LQ)/LQ:GOTO 5380
  74. 5360 C2=.577+LOG(LQ)-LQ^2/4+LQ^4/96-LQ^6/4320+LQ^8/322560!-LR^10/36288000#
  75. 5370 S2=LQ-LQ^3/18+LQ^5/600-LQ^7/35280!+LQ^9/3265920!
  76. 5380 IF LR>5 THEN C4=SIN(LR)/LR:S4=PI/2-COS(LR)/LR:GOTO 5410
  77. 5390 C4=.577+LOG(LR)-LR^2/4+LR^4/96-LR^6/4320+LR^8/322560!-LR^10/36288000#
  78. 5400 S4=LR-LR^3/18+LR^5/600-LR^7/35280!+LR^9/3265920!
  79. 5410 ML=60*(LOG(LQ)-C2+.577-1+COS(LQ))
  80. 5420 NL=60*(S2-SIN(LQ))
  81. 5430 RA=60*(.577+LOG(LQ)-C2)+30*(.577+LOG(LP)-2*C2+C4)*COS(LQ)
  82. 5440 RA=RA+30*(S4-2*S2)*SIN(LQ)
  83. 5450 XA=60*S2+30*(C4-LOG(LP)-.577)*SIN(LQ)-30*S4*COS(LQ)
  84. 5460 DE=RA*RA*(COS(LP))^2+((KA+ML)*SIN(LP)+(XA+NL)*COS(LP))^2
  85. 5470 RI=KA*RA*(KA+NL*SIN(LQ)-ML*COS(LQ))
  86. 5480 RI=RI/DE
  87. 5490 XI=(RA*RA+XA*XA+ML*ML-NL*NL-KA*KA)*SIN(LQ)/2
  88. 5500 XI=XI+(ML*NL-KA*XA)*COS(LQ)+ML*XA-KA*NL
  89. 5510 XI=XI*KA/DE
  90. 5520 ZA=SQR(RI*RI+XI*XI)
  91. 5530 RETURN
  92. 5999 REM DO ANT AND RESISTOR IN PARALLEL
  93. 6000 MAG1=SQR(RI*RI+XI*XI)
  94. 6010 ANG1=ATN(XI/RI)
  95. 6020 MAG2=RL
  96. 6030 ANG2=0
  97. 6040 MAG=MAG1*MAG2  'PRODUCT
  98. 6050 ANG=ANG1+ANG2
  99. 6200 MAG1=MAG
  100. 6210 ANG1=ANG
  101. 6220 RES=RI+RL       'SUM
  102. 6230 REA=XI
  103. 6240 MAG2=SQR(RES*RES+REA*REA)
  104. 6250 ANG2=ATN(REA/RES)
  105. 6260 MAG=MAG1/MAG2  'PARALLEL IMPEDANCE
  106. 6270 ANG=ANG1-ANG2
  107. 6280 ZI=MAG
  108. 6290 RC=MAG*COS(ANG) 
  109. 6300 XC=MAG*SIN(ANG)
  110. 6400 RES=RC+ZO    'DO SWR
  111. 6410 REA=XC
  112. 6420 MAG1=SQR(RES*RES+REA*REA)  'SUM
  113. 6430 RES=RC-ZO    
  114. 6440 REA=XC
  115. 6450 MAG2=SQR(RES*RES+REA*REA)   'DIFF
  116. 6800 SWR=ABS((MAG1+MAG2)/(MAG1-MAG2))
  117. 6810 LOSS=ABS(10/2.3*LOG(RI*RL/(RI*RL+ZA*ZA)))    
  118. 6820 RETURN
  119. 6830 END
  120. 60000 PRINT "ERROR";ERR;"AT LINE";ERL
  121. 60010 STOP
  122.