home *** CD-ROM | disk | FTP | other *** search
/ Antennas / Antennas_CD-ROM_Walnut_Creek_September_1996.iso / w4mb / vol2 / basic / bevr.asc < prev    next >
Text File  |  1996-06-30  |  6KB  |  150 lines
  1. 2 ON ERROR GOTO 60000
  2. 3 CLS
  3. 10 PRINT "   ***************************************************************"
  4. 20 PRINT "   *                       BEVERAGE ANTENNA                      *"
  5. 30 PRINT "   *  REFERENCE -LITVA AND ROOK, CRC REPORT 1282, OTTAWA, 1976   *"
  6. 40 PRINT "   *              H.H. BEVERAGE, QST, DECEMBER, 1981             *"
  7. 50 PRINT "   *            BEVERAGE AND DEMAW, QST,JANUARY, 1982            *"
  8. 60 PRINT "   *                PROGRAM BY  R.P. HAVILAND, W4MB              *"
  9. 70 PRINT "   *                       COPYRGHT 1990                         *"
  10. 80 PRINT "   *          MINILAB BOOKS, DAYTONA BEACH, FL 32121-1086        *"
  11. 90 PRINT "   ***************************************************************"
  12. 200 DEF FNP (X) = INT(100 * X + .5) / 100
  13. 210 PI = 3.141592
  14. 220 DTORAD = 2 * PI / 360
  15. 230 DIM VPAT(36)
  16. 400 PRINT " THE BEVERAGE ANTENNA IS A LOW ELEVATION TRAVELING WAVE ANTENNA"
  17. 410 PRINT "   USEFUL FROM VLF TO THE TOP HF BANDS. IT'S APPEARANCE IS:"
  18. 420 PRINT
  19. 430 PRINT "             WWWWWWWWWWWWWWWWWWWWWWWWWWWWWWWWW       W=WIRE"
  20. 440 PRINT "             W                               W       R=RESISTOR"
  21. 450 PRINT "             S                               R       S=SIGNAL UNIT"
  22. 460 PRINT "             W                               W       G=GROUND"
  23. 470 PRINT "         GGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGG"
  24. 480 PRINT
  25. 490 PRINT " THIS ANALYSIS USES MANY APPROXIMATIONS TO DEVELOP A PERFORMANCE ESTIMATE."
  26. 500 PRINT
  27. 1000 INPUT "ENTER DESIGN FREQUENCY, MHZ"; FREQ
  28. 1010 LAMDA = 299.8 / FREQ'METERS
  29. 1020 PRINT "TYPICAL GROUND CONDUCTIVITIES, MHOS/METER ARE"
  30. 1030 PRINT "    DRY SAND-      1E-4      DRY POOR SOIL- 3E-4"
  31. 1040 PRINT "    AVERAGE DRY-   3E-3   = DEFAULT VALUE"
  32. 1050 PRINT "    AVERAGE WET  - 1E-2       GOOD WET    - 3E-2"
  33. 1060 GCON = .001
  34. 1070 INPUT "ENTER NEW CONDUCTIVITY, RETURN ONLY = DEFAULT VALUE"; T$
  35. 1080 IF T$ <> "" THEN GCON = VAL(T$)
  36. 1100 INPUT "ENTER WIRE HEIGHT ABOVE GROUND, FEET "; HFT
  37. 1110 HMTR = HFT * .3048
  38. 1120 HLAM = HMTR / LAMDA
  39. 1130 INPUT "ENTER WIRE SIZE, AWG ", AWG
  40. 1140 WDIA = .01168 / (92 ^ ((AWG + 3) / 39))'METERS
  41. 1150 PRINT
  42. 1200 PRINT "TYPICAL SIGNAL ARRIVAL ANGLES ARE:"
  43. 1210 PRINT "   F-LAYER EXTREME DISTANCE- 3  DEGREES"
  44. 1220 PRINT "                    TYPICAL- 10 DEGREES"
  45. 1230 PRINT "   E-LAYER          TYPICAL- 30 DEGREES"
  46. 1240 INPUT "ENTER EXPECTED SIGNAL ARRIVAL ANGLE, DEGREES"; ARR
  47. 1250 ARRAD = ARR / 57.3
  48. 1400 GOSUB 5000 'VELOCITY
  49. 1410 PRINT "VELOCITY RATIO V/C="; FNP(VRATIO)
  50. 1420 LOPT = LAMDA / 2 / (1 / VRATIO - COS(ARRAD))
  51. 1430 LOPTFT = LOPT * 3.28
  52. 1440 PRINT "LENGTH FOR BEST SIGNAL AT THIS FREQUENCY="; INT(LOPTFT); "FT"
  53. 1450 PRINT "                                        ="; INT(LOPT); "METERS"
  54. 1460 INPUT "ENTER DESIGN WIRE LENGTH,FEET"; LFT
  55. 1470 LMT = LFT / 3.28
  56. 1480 LLAM = LMT / LAMDA
  57. 1500 ZW = 138 / 2.3 * LOG(4 * HMTR / WDIA)
  58. 1510 PRINT " FAR END TERMINATING RESISTANCE="; INT(ZW); "OHMS"
  59. 1520 PRINT "    ADJUST FOR BEST FRONT/BACK PERFORMANCE"
  60. 1530 PRINT
  61. 1540 PRINT " THE FOLLOWING PATTERN DATA IS FOR IDEAL GROUND ONLY,"
  62. 1550 PRINT "   AND IS FOR COMPARISONS ONLY. THE ACTUAL PATTERN IS COMPLEX."
  63. 1560 PRINT "     SEE REFERENCES."
  64. 1600 GOSUB 6000  'VPATTERN
  65. 1610 PRINT " APPROXIMATE NO-LOSS VERTICAL PLANE PATTERN IN DIRECTION OF WIRE"
  66. 1620 PRINT " DEGREES", "DB", , "DEGREES", "DB"
  67. 1630 FOR N = O TO 36 STEP 2
  68. 1640 PRINT N * 5, FNP(VPAT(N)), ,
  69. 1650 IF N = 36 THEN 1670
  70. 1660 PRINT N * 5 + 5, FNP(VPAT(N + 1))
  71. 1670 NEXT N
  72. 1680 PRINT "RELATIVE GAIN FACTOR="; 20 / 2.3 * LOG(MV)
  73. 1800 INPUT "PRESS RETURN TO CONTINUE"; T$
  74. 2000 PRINT
  75. 2010 PRINT "   ENTER L= NEW LENGTH"
  76. 2020 PRINT "         P= PRINT COPY"
  77. 2030 PRINT "         R= RERUN"
  78. 2040 PRINT "         S= SAVE PATTERN TO DISK"
  79. 2050 PRINT "         Q= QUIT"
  80. 2100 INPUT T$
  81. 2110 IF T$ = "L" THEN GOTO 1400
  82. 2120 IF T$ = "P" THEN GOSUB 7000
  83. 2130 IF T$ = "R" THEN GOTO 1000
  84. 2140 IF T$ = "S" THEN GOSUB 8000
  85. 2150 IF T$ = "Q" THEN STOP
  86. 2160 GOTO 2000
  87. 4999 END
  88. 5000 F = FREQ'VELOCITY RATIO
  89. 5010 A = .7775612 + .006834584# * F - .000098978478# * F * F
  90. 5020 B = .2027129 - .003819636# * F + .0001808748# * F * F - .000004744822# * F * F * F
  91. 5030 C = (-9.518469 + .2643712 * F - .01718888# * F * F + .0004295341# * F * F * F) * .01
  92. 5040 D = .01635602# - .002369755# * F + .0001968106# * F * F - .000004362774# * F * F * F
  93. 5100 VRATIO2 = A + B * HMTR + C * HMTR * HMTR + D * HMTR * HMTR * HMTR
  94. 5110 VRATIO1 = VRATIO2 * (.9414568 + 3.051976 * GCON): VRATIO = VRATIO1
  95. 5120 IF VRATIO > .995 THEN VRATIO = .995
  96. 5999 RETURN
  97. 6000 FOR N = 0 TO 36
  98. 6010 VANG = 5 * N * DTORAD
  99. 6020 VPAT(N) = SIN(VANG) / (1 - COS(VANG + .001)) * SIN(PI * LLAM * (1 - COS(VANG))) * 2 * SIN(2 * PI * HLAM * SIN(VANG))
  100. 6030 VPAT(N) = ABS(VPAT(N))
  101. 6040 NEXT N
  102. 6100 MV = 0
  103. 6110 FOR N = 0 TO 36
  104. 6120 IF MV < VPAT(N) THEN MV = VPAT(N)
  105. 6130 NEXT N
  106. 6200 FOR N = 0 TO 36
  107. 6210 VPAT(N) = VPAT(N) / MV
  108. 6220 IF VPAT(N) = 0 THEN VPAT(N) = -100: GOTO 6250
  109. 6230 VPAT(N) = 20 / 2.3 * LOG(VPAT(N))
  110. 6240 IF VPAT(N) < -20 THEN VPAT(N) = -20
  111. 6250 NEXT N
  112. 6999 RETURN
  113. 7000 LPRINT "           BEVERAGE ANTENNA"
  114. 7010 LPRINT "  DESIGN FREQUENCY=              "; FREQ; "MHZ"
  115. 7020 LPRINT "  DESIGN EARTH CONDUCTIVITY=     "; GCON; "MHOS/METER"
  116. 7030 LPRINT "  ANTENNA HEIGHT=                "; HFY; "FT"
  117. 7040 LPRINT "  WIRE SIZE=                     "; AWG; "AWG"
  118. 7050 LPRINT "  ANTENNA VELOCITY RATIO         "; VRATIO; ""
  119. 7060 LPRINT "  DESIGN SIGNAL ARRIVAL ANGLE=   "; ARR; "DEGREES"
  120. 7070 LPRINT "  WIRE LENGTH FOR BEST SIGNAL=   "; LOPTFT; "FT"
  121. 7080 LPRINT "  DESIGN WIRE LENGTH=            "; LFT; "FT"
  122. 7090 LPRINT "  DESIGN TERMINATING RESISTANCE  "; ZW; "OHMS"
  123. 7100 LPRINT : LPRINT
  124. 7200 LPRINT , "     VERTICAL PATTERN"
  125. 7210 LPRINT , "  ANGLE", "RELATIVE SIGNAL"
  126. 7220 LPRINT , "FROM WIRE", "    DB"
  127. 7230 FOR N = 0 TO 36
  128. 7240 LPRINT , 10 * N, VPAT(N)
  129. 7250 NEXT N
  130. 7260 LPRINT
  131. 7270 LPRINT "  RELATIVE GAIN FACTOR="; 20 / 2.3 * LOG(MV)
  132. 7280 LPRINT : LPRINT
  133. 7999 RETURN
  134. 8000 CLS
  135. 8010 INPUT "ENTER FILENAME OF ANTENNA"; NA$
  136. 8020 INPUT "ENTER FILEPATH FOR DISK, INCLUDE ANY : AND : "; FP$
  137. 8030 OPEN FP$ + NA$ + DA$ + ".PAT" FOR OUTPUT AS #1
  138. 8100 PRINT #1, 36, 0, "D"
  139. 8110 FOR N = 0 TO 36
  140. 8130 PRINT #1, N, 10 * N, 0, 0, VPAT(N)
  141. 8150 NEXT N
  142. 8200 CLOSE 1
  143. 8300 PRINT "  PATTERN SAVED IN MININEC .PAT FORMAT"
  144. 8310 PRINT "   USE MNPOLT OR PLOTPRNT FOR PLOTTING OF DATA"
  145. 8320 PRINT
  146. 8999 RETURN
  147. 60000 PRINT "ERROR"; ERR; "AT LINE"; ERL
  148. 60010 STOP
  149.  
  150.