home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Antennas
/
Antennas_CD-ROM_Walnut_Creek_September_1996.iso
/
w4mb
/
vol1
/
basic
/
shortver.asc
< prev
next >
Wrap
Text File
|
1996-06-30
|
2KB
|
49 lines
100 CLS : PRINT " ***********************************"
110 PRINT " * SHORT VERTICAL ANTENNAS *"
120 PRINT " *REFERENCE-JASIK, ANTENNA HANDBOOK*"
130 PRINT " * PAGE 3-2 *"
140 PRINT " * PROGRAM COPYRIGHT 1985 *"
150 PRINT " * R.P. HAVILAND, W4MB *"
160 PRINT " ***********************************"
170 REM PROGRAM 7
180 DEF FNP (X) = INT(10 * X + .5) / 10
190 PI = 3.14159
200 PRINT : PRINT : INPUT "ENTER RESONANT FREQUENCY, MHZ"; FR
210 LA = 984 / FR
220 PRINT "MAXIMUM HEIGHT ALLOWED FOR THIS ROUTINE IS "; INT(LA / 4); " FEET"
230 INPUT "ENTER HEIGHT OF ANTENNA, FEET"; LV
240 IF LV > LA / 4 THEN 220
250 INPUT "ENTER RADIUS OF ANTENNA, INCHES"; RA
300 KL = 2 * PI * LV / LA
310 RR = 1 / 2 * .05334 - 2.0464 * KL + 29.1772 * KL ^ 2 - 13.4166 * KL ^ 3 + 9.2298 * KL ^ 4
320 XT = -.05581 + 10.1427 * KL + 12.4064 * KL ^ 2 - 11.6651 * KL ^ 3 + 6.7621 * KL ^ 4
330 XR = -60 * (LOG(24 * LV / RA) - 1) / TAN(KL) + XT
400 PRINT : PRINT "FOR A VERTICAL "; LV; " FEET HIGH"
410 PRINT " AT A FREQUENCY OF "; FR; " MHZ"
420 PRINT : PRINT "THE BASE RESISTANCE IS "; FNP(RR); " OHMS"
430 PRINT " THE BASE REACTANCE IS "; FNP(XR); " OHMS"
440 PRINT : PRINT "PRESS A KEY TO CONTINUE"
450 Q$ = INKEY$: IF Q$ = "" GOTO 450
500 IF XR > O THEN 700
510 CL = ABS(XR) / 2 / PI / FR
520 CR = ABS(XR / 200)
530 EF = 100 * RR / (RR + CR + 4)
600 PRINT : PRINT "THE REQUIRED SERIES LOADING COIL IS"
610 PRINT " "; FNP(CL); " MICROHENRIES"
620 PRINT : PRINT "FOR A COIL Q OF 200"
630 PRINT " AND A GROUND RESISTANCE OF 4 OHMS"
640 PRINT : PRINT "THE RADIATION EFFIENCY IS "; INT(EF); " PERCENT"
650 GOTO 900
700 CC = 2 * PI * FR * XR
710 EF = 100 * RR / (RR + 4)
800 PRINT : PRINT "FOR ZERO REACTANCE,"
810 PRINT " THE REQUIRED SERIES CAPACITOR IS"
820 PRINT " "; FNP(CC); " PICOFARADS"
830 PRINT : PRINT "FOR A GROUND RESISTANCE OF 4 OHMS"
840 PRINT " THE RADIATION EFFIENCY IS "; INT(EF); " PERCENT"
900 PRINT : PRINT "PRESS R TO RERUN, ANY OTHER KEY TO STOP"
910 Q$ = INKEY$: IF Q$ = "" GOTO 910
920 IF Q$ = "R" OR Q$ = "r" THEN RUN
930 END