home *** CD-ROM | disk | FTP | other *** search
/ Antennas / Antennas_CD-ROM_Walnut_Creek_September_1996.iso / w4mb / vol1 / basic / shortver.asc < prev    next >
Text File  |  1996-06-30  |  2KB  |  49 lines
  1. 100 CLS : PRINT "   ***********************************"
  2. 110 PRINT "   *     SHORT VERTICAL ANTENNAS     *"
  3. 120 PRINT "   *REFERENCE-JASIK, ANTENNA HANDBOOK*"
  4. 130 PRINT "   *            PAGE 3-2             *"
  5. 140 PRINT "   *     PROGRAM COPYRIGHT 1985      *"
  6. 150 PRINT "   *       R.P. HAVILAND, W4MB       *"
  7. 160 PRINT "   ***********************************"
  8. 170 REM PROGRAM 7
  9. 180 DEF FNP (X) = INT(10 * X + .5) / 10
  10. 190 PI = 3.14159
  11. 200 PRINT : PRINT : INPUT "ENTER RESONANT FREQUENCY, MHZ"; FR
  12. 210 LA = 984 / FR
  13. 220 PRINT "MAXIMUM HEIGHT ALLOWED FOR THIS ROUTINE IS "; INT(LA / 4); " FEET"
  14. 230 INPUT "ENTER HEIGHT OF ANTENNA, FEET"; LV
  15. 240 IF LV > LA / 4 THEN 220
  16. 250 INPUT "ENTER RADIUS OF ANTENNA, INCHES"; RA
  17. 300 KL = 2 * PI * LV / LA
  18. 310 RR = 1 / 2 * .05334 - 2.0464 * KL + 29.1772 * KL ^ 2 - 13.4166 * KL ^ 3 + 9.2298 * KL ^ 4
  19. 320 XT = -.05581 + 10.1427 * KL + 12.4064 * KL ^ 2 - 11.6651 * KL ^ 3 + 6.7621 * KL ^ 4
  20. 330 XR = -60 * (LOG(24 * LV / RA) - 1) / TAN(KL) + XT
  21. 400 PRINT : PRINT "FOR A VERTICAL "; LV; " FEET HIGH"
  22. 410 PRINT " AT A FREQUENCY OF "; FR; " MHZ"
  23. 420 PRINT : PRINT "THE BASE RESISTANCE IS "; FNP(RR); " OHMS"
  24. 430 PRINT " THE BASE REACTANCE IS "; FNP(XR); " OHMS"
  25. 440 PRINT : PRINT "PRESS A KEY TO CONTINUE"
  26. 450 Q$ = INKEY$: IF Q$ = "" GOTO 450
  27. 500 IF XR > O THEN 700
  28. 510 CL = ABS(XR) / 2 / PI / FR
  29. 520 CR = ABS(XR / 200)
  30. 530 EF = 100 * RR / (RR + CR + 4)
  31. 600 PRINT : PRINT "THE REQUIRED SERIES LOADING COIL IS"
  32. 610 PRINT "  "; FNP(CL); " MICROHENRIES"
  33. 620 PRINT : PRINT "FOR A COIL Q OF 200"
  34. 630 PRINT " AND A GROUND RESISTANCE OF 4 OHMS"
  35. 640 PRINT : PRINT "THE RADIATION EFFIENCY IS "; INT(EF); " PERCENT"
  36. 650 GOTO 900
  37. 700 CC = 2 * PI * FR * XR
  38. 710 EF = 100 * RR / (RR + 4)
  39. 800 PRINT : PRINT "FOR ZERO REACTANCE,"
  40. 810 PRINT " THE REQUIRED SERIES CAPACITOR IS"
  41. 820 PRINT "  "; FNP(CC); "  PICOFARADS"
  42. 830 PRINT : PRINT "FOR A GROUND RESISTANCE OF 4 OHMS"
  43. 840 PRINT " THE RADIATION EFFIENCY IS "; INT(EF); " PERCENT"
  44. 900 PRINT : PRINT "PRESS R TO RERUN, ANY OTHER KEY TO STOP"
  45. 910 Q$ = INKEY$: IF Q$ = "" GOTO 910
  46. 920 IF Q$ = "R" OR Q$ = "r" THEN RUN
  47. 930 END
  48.  
  49.