home *** CD-ROM | disk | FTP | other *** search
/ Antennas / Antennas_CD-ROM_Walnut_Creek_September_1996.iso / w4mb / vol1 / basic / smloop.asc < prev    next >
Text File  |  1996-06-30  |  3KB  |  65 lines
  1. 100 CLS : PRINT "   ***********************************"
  2. 110 PRINT "   *       SMALL LOOP ANTENNAS       *"
  3. 120 PRINT "   *  REFERENCE-IEEE TRANS. ANTENNAS *"
  4. 130 PRINT "   *AND PROPAGATION. NOV, 1984,P 1248*"
  5. 140 PRINT "   *      PROGRAM COPYRIGHT 1985     *"
  6. 150 PRINT "   *       R.P. HAVILAND, W4MB       *"
  7. 160 PRINT "   ***********************************"
  8. 170 REM PROGRAM 12
  9. 180 DEF FNP (X) = INT(X * 100 + .5) / 100
  10. 190 PI = 3.14159
  11. 200 DIM C(6, 4)
  12. 210 FOR M = 1 TO 6
  13. 220 FOR N = 1 TO 4
  14. 230 READ C(M, N)
  15. 240 NEXT N
  16. 250 NEXT M
  17. 260 DATA 1.793,3.928,1.722,3.67
  18. 270 DATA 1.126,3.950,1.073,3.271
  19. 280 DATA 1.140,3.958,1.065,3.452
  20. 290 DATA 0.694,3.998,0.755,2.632
  21. 300 DATA 0.688,3.995,0.667,3.280
  22. 310 DATA 1.588,4.293,1.385,3.525
  23. 400 PRINT "THIS ANALYSIS VALID UP TO  PERIMETER OF  LOOP= 0.7 WAVELENGTH"
  24. 410 PRINT : PRINT "ENTER SHAPE NUMBER OF LOOP"
  25. 420 PRINT "  1=CIRCULAR"
  26. 430 PRINT "  2=SQUARE, CENTER DRIVE"
  27. 440 PRINT "  3=SQUARE, CORNER DRIVE"
  28. 450 PRINT "  4=TRIANGLE, BASE DRIVE"
  29. 460 PRINT "  5=TRIANGLE, TOP, DRIVE"
  30. 470 PRINT "  6=HEXAGON"
  31. 480 INPUT TY
  32. 490 IF TY < 1 OR TY > 6 THEN 410
  33. 500 INPUT "ENTER LOOP PERIMETER, FEET"; CI
  34. 510 IF TY = 1 THEN AL = CI * CI / 12.5664
  35. 520 IF TY = 2 OR TY = 3 THEN AL = CI * CI / 16
  36. 530 IF TY = 4 OR TY = 5 THEN AL = CI * CI / 20.7846
  37. 540 IF TY = 6 THEN AL = CI * CI / 13.8564
  38. 550 INPUT "ENTER ELEMENT DIAMETER, INCHES"; DA
  39. 560 WR = DA / 24
  40. 570 INPUT "ENTER FREQUENCY, MHZ"; FO
  41. 580 LA = 984 / FO
  42. 590 IF CI / LA > .8 THEN PRINT " ** TOO HIGH-BEYOND RANGE OF TABLES ***": GOTO 570
  43. 600 ZO = 276 * LOG(2 * AL / CI / WR)
  44. 610 XR = ZO * TAN(PI * CI / LA)
  45. 620 A = 1: B = 2
  46. 630 IF LA > .2 THEN A = 3: B = 4
  47. 640 IF CI / LA > .5 THEN RR = 0: GOTO 660
  48. 650 RR = C(TY, A) * (TAN(PI * CI / LA)) ^ C(TY, B)
  49. 660 OM = 2 * LOG(2 * CI / WR)
  50. 670 CA = 1000000! / 2 / PI / FO / XR
  51. 700 PRINT : PRINT "THE THICKNESS FACTOR OMEGA IS"; FNP(OM)
  52. 710 PRINT "THE PERIMETER IS "; INT(100 * CI / LA) / 100; " WAVELENGTHS"
  53. 720 IF CI / LA > .5 THEN PRINT "RESISTANCE OUT OF CALCULAION RANGE": GOTO 740
  54. 730 PRINT : PRINT "THE FEED RESISTANCE IS "; FNP(RR); " OHMS"
  55. 740 PRINT "THE FEED REACTANCE IS "; INT(XR)
  56. 750 IF XR < 0 THEN 900
  57. 760 PRINT "THE CAPACTANCE TO RESONATE IS "; FNP(CA); "PICOFARADS"
  58. 800 PRINT : PRINT "PRESS R TO RERUN, ANY OTHER KEY FOR MENU"
  59. 810 Q$ = INKEY$: IF Q$ = "" GOTO 810
  60. 820 IF Q$ = "R" OR Q$ = "r" THEN RUN
  61. 830 STOP
  62. 900 PRINT "ADD "; INT(ABS(XR / 2 / PI / FO) * 10) / 10; " MICROHENRIES TO RESONATE"
  63. 910 GOTO 800
  64.  
  65.