home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Antennas
/
Antennas_CD-ROM_Walnut_Creek_September_1996.iso
/
w4mb
/
vol1
/
basic
/
lwire.asc
< prev
next >
Wrap
Text File
|
1996-06-30
|
2KB
|
48 lines
100 CLS : PRINT " ***********************************"
110 PRINT " * LONG WIRE ANTENNAS *"
120 PRINT " * REFERENCE-ARRL ANTENNA HANDBOOK *"
130 PRINT " * FIG. 7-1 AND FIG. 7-20 *"
140 PRINT " * PROGRAM COPYRIGHT 1985 *"
150 PRINT " * R.P. HAVILAND, W4MB *"
160 PRINT " ***********************************"
165 REM PROGRAM 25
170 PRINT : PRINT "CALCULATED VALUES ARE FOR THIN (WIRE) ANTENNAS 1-10 WAVELENGTHS LONG"
180 PRINT : PRINT
190 PI = 3.14159
200 INPUT "ENTER MAXIMUM LENGTH OF ANTENNA"; LM
210 PRINT " ENTER 1 FOR CURRENT, 2 FOR VOLTAGE, 3 FOR VARIABLE IMPEDANCE FEED"
220 INPUT TF: IF TF > 3 THEN 200
230 INPUT "ENTER FREQUENCY"; FO: IF FO = 0 THEN 230
240 LA = 984 / FO
250 NH = 2 * LM / LA
260 IF TF = 1 THEN 500
270 IF TF = 2 THEN 400
300 GOTO 600
400 IF NH - INT(NH) > .5 THEN NH = INT(NH) + .5 - .05
410 NH = INT(NH) - .05
420 GOTO 600
500 IF NH - INT(NH) > .75 THEN NH = INT(NH) + .75 - .05
510 IF NH - INT(NH) > .25 THEN NH = INT(NH) + .25 - .05
520 NH = INT(NH) - .25 - .05
600 LE = (NH + .05) / 2
610 LW = LE * LA
620 RR = 17.32 + 30 * LOG(4 * PI * LE)
630 TH = 74.91669 - 28.734 * LE + 5.9693 * LE * LE - .57838 * LE ^ 3 + .02113 * LE ^ 4
640 GA = -.4273 + .7953 * LE + .0444 * LE * LE - .0069487 * LE ^ 3 + 2.4036E-04 * LE ^ 4
700 PRINT : PRINT "THE WIRE LENGTH SHOULD BE "; INT(10 * NH / 2 * LA + .5) / 10; " FEET"
710 PRINT "THE ANTENNA IS "; INT(100 * LE) / 100; " WAVELENGTHS LONG"
720 PRINT "THE RADIATION RESISTANCE IS"; INT(RR + .5); " OHMS"
730 PRINT "AT A CURRENT LOOP"
740 IF LE > 12 THEN PRINT "WIRE TOO LONG TO CALCULATE-SEE REFERENCE": GOTO 780
750 PRINT "THE MAIN LOBE IS "; INT(TH + .5); " DEGREES"
760 PRINT "FROM THE WIRE AXIS"
770 PRINT "THE GAIN IS "; INT(10 * GA + .05) / 10; " DB"
780 PRINT : IF TF <> 1 THEN PRINT "USE TUNED ZEPP FEEDERS": GOTO 810
790 PRINT "FEED AT"; INT(100 * LA / 4 + .5) / 100; "FEET"
800 PRINT "FROM END AWAY FROM PREFERRED DIRECTION"
810 PRINT : PRINT "PRESS R TO RERUN, ANY OTHER KEY TO STOP"
820 Q$ = INKEY$: IF Q$ = "" GOTO 820
830 IF Q$ = "R" OR Q$ = "r" THEN RUN
840 END