home *** CD-ROM | disk | FTP | other *** search
/ Antennas / Antennas_CD-ROM_Walnut_Creek_September_1996.iso / w4mb / vol1 / basic / log_per.asc < prev    next >
Text File  |  1996-06-30  |  4KB  |  117 lines
  1. 100 CLS : PRINT "  ************************************"
  2. 110 PRINT "  *       LOG-PERIODIC ANTENNAS      *"
  3. 120 PRINT "  *    REFERENCE-SCHOLZ AND SMITH    *"
  4. 130 PRINT "  *     HAM RADIO, DECEMBER 1979     *"
  5. 140 PRINT "  *      PROGRAM COPYRIGHT 1985      *"
  6. 150 PRINT "  *       R.P. HAVILAND, W4MB        *"
  7. 160 PRINT "  ************************************"
  8. 165 REM PROGRAM 21
  9. 170 DEF FNO (X) = INT(10 * X + .5) / 10
  10. 180 DEF FNP (X) = INT(1000 * X + .5) / 1000
  11. 190 DIM S(40), L(40)
  12. 200 INPUT "ENTER LOWER FREQUENCY TO COVER, MHZ"; FL
  13. 210 INPUT "ENTER UPPER FREQUENCY TO COVER, MHZ"; FH
  14. 220 PRINT : PRINT "THE RANGE OF DESIGN GAIN IS 5-10 DB"
  15. 230 INPUT "ENTER TRIAL VALUE OF GAIN"; GA
  16. 240 IF GA < 5 OR GA > 10 THEN 220
  17. 300 TF = -1.32201 + .70127 * GA - .07409 * GA * GA + 2.68938E-03 * GA * GA * GA
  18. 310 SF = .2273 * TF - .0413: SO = SF
  19. 320 BF = FH / FL
  20. 330 BA = 1.1 + (30.8 * (1 - TF) * SF)
  21. 340 BS = BA * BF
  22. 350 LL = 984 / FL
  23. 360 LW = (1 - 1 / BS) * (4 * SF / (1 - TF)) / 4
  24. 370 LA = LW * LL
  25. 380 NE = 1 + LOG(BS) / LOG(1 / TF)
  26. 390 NR = INT(NE + 1)
  27. 400 LA = LA * NR / NE
  28. 480 PRINT : PRINT "THE TAPER FACTOR IS"; FNP(TF)
  29. 490 PRINT "THE SPACING FACTOR IS"; FNP(SF)
  30. 500 PRINT "THE NUMBER OF ELEMENTS IS "; NR
  31. 510 PRINT "THE REQUIRED BOOM LENGTH IS"; FNP(LA); "FEET": PRINT
  32. 520 PRINT "PRESS   A=ACCEPT VALUES"
  33. 530 PRINT "        S=SHORTER BOOM, STEP SPACING"
  34. 540 PRINT "        I=SHORTER BOOM, INTERPOLATE"
  35. 550 Q$ = INKEY$: IF Q$ = "" THEN 550
  36. 560 IF Q$ = "A" THEN 620
  37. 570 IF Q$ = "I" THEN INPUT "NEW SPACING FACTOR"; SF: GOTO 320
  38. 580 IF Q$ <> "S" THEN 550
  39. 590 SF = SF - .01: IF SO < SF * 2 THEN 320
  40. 600 PRINT " POOR DESIGN VALUES-USE LESS TRIAL GAIN AND RERUN": GOTO 1520
  41. 610 GOTO 520
  42. 620 PRINT " ENTER 1 IF ELEMENTS ARE END SUPPORTED, OTHERWISE 0"
  43. 630 INPUT ES
  44. 640 L(1) = 984 / FL / 2
  45. 650 IF ES = 1 THEN L(1) = L(1) * .95
  46. 660 S(1) = SF * LL
  47. 670 CA = 4 * SF / (1 - TF)
  48. 680 FOR N = 2 TO NR
  49. 690 L(N) = TF * L(N - 1)
  50. 700 S(N) = TF * S(N - 1)
  51. 710 NEXT N
  52. 720 PRINT "ELEMENT", "LENGTH,FT. "; " SPACING,FT."
  53. 730 FOR N = 1 TO NR
  54. 740 PRINT N, FNP(L(N)),
  55. 750 IF N = NR THEN 770
  56. 760 PRINT FNP(S(N))
  57. 770 NEXT N
  58. 780 IF P$ = "Y" THEN RETURN
  59. 800 DG = (.148 - .0417 * GA) * (SO - SF) / .01
  60. 810 GG = GA + DG
  61. 820 PRINT : PRINT " THE ESTIMATED GAIN IS "; FNO(GG); " DB"
  62. 830 PRINT
  63. 900 PRINT " PRESS   C=CONTINUE DESIGN"
  64. 910 PRINT "         R=REVISE DESIGN"
  65. 920 PRINT "         N=NEW DESIGN"
  66. 930 Q$ = INKEY$: IF Q$ = "" THEN 930
  67. 940 IF Q$ = "R" THEN 480
  68. 950 IF Q$ = "N" THEN 200
  69. 960 IF Q$ <> "C" THEN 930
  70. 1000 MF = SF / SQR(TF)
  71. 1010 INPUT " ENTER AVERAGE ELEMENT DIAMETER,INCHES"; DE
  72. 1020 ZA = 120 * (LOG(L(NR / 2) * 12 / DE) - 2.25)
  73. 1030 RO = 200
  74. 1040 PRINT " ENTER DRIVE IMPEDANCE, TYPICAL VALUE = 200 OHMS"
  75. 1050 INPUT RO
  76. 1060 ZR = ZA / RO
  77. 1070 ZT = 8 * MF * ZR
  78. 1080 ZO = RO * (1 / ZT + SQR(1 / ZT / ZT + 1))
  79. 1090 PRINT "THE ARRAY FEED IMPEDANCE IS "; INT(ZO); " OHMS"
  80. 1200 PRINT : PRINT "FOR CROSSED WIRE FEED"
  81. 1210 INPUT " ENTER WIRE DIAMETER,INCHES"; DW
  82. 1220 DS = DW / 2 * EXP(ZO / 120)
  83. 1230 PRINT "WIRE SEPARATION IS "; FNP(DS); "INCHES"
  84. 1300 PRINT : PRINT "FOR PARALLEL BOOM FEED"
  85. 1310 INPUT " ENTER BOOM WIDTH, INCHES"; BW
  86. 1320 BS = BW * ZO / 377
  87. 1330 PRINT "BOOM SEPARATION IS "; FNP(BS); "INCHES"
  88. 1500 REM
  89. 1520 PRINT : PRINT " PRESS   R=REVISE DESIGN"
  90. 1530 PRINT "         N=NEW DESIGN"
  91. 1540 PRINT "         Q=QUIT"
  92. 1550 Q$ = INKEY$: IF Q$ = "" THEN 1550
  93. 1560 IF Q$ = "R" THEN 480
  94. 1570 IF Q$ = "N" THEN 200
  95. 1580 STOP
  96. 2000 REM PRINT SUB
  97. 2010 PRINT "     LOG-PERIODIC ARRAY"
  98. 2020 PRINT : PRINT "FREQUENCY RANGE"; FL; "-"; FH; " MHZ"
  99. 2030 PRINT "ESTIMATED GAIN "; FNO(GG); " DB"
  100. 2040 PRINT "BOOM LENGTH "; FNO(LA); "FEET"
  101. 2050 PRINT "NUMBER OF ELEMENTS-"; NR: PRINT
  102. 2060 PRINT "FEED POINT IMPEDANCE "; RO; " OHMS"
  103. 2070 PRINT "CONNECTION IMPEDANCE"; FNO(ZO); "OHMS"
  104. 2075 PRINT : PRINT "  CROSSED WIRE FEED"
  105. 2080 PRINT "WIRE SIZE"; DW; "INCHES"
  106. 2090 PRINT "WIRE SPACING"; FNO(DS); "INCHES"
  107. 2095 PRINT : PRINT "  PARALLEL BOOM FEED"
  108. 2100 PRINT "BOOM WIDTH"; BW; "INCHES"
  109. 2110 PRINT "BOOM SPACING"; FNO(BS); "INCHES"
  110. 2120 PRINT
  111. 2130 GOSUB 720
  112. 2140 PRINT "    ***** END OF DESIGN *****"
  113. 2150 PRINT : PRINT "PRESS ANY KEY TO CONTINUE."
  114. 2160 Q$ = INKEY$: IF Q$ = "" THEN 2160
  115. 2170 GOTO 1520
  116.  
  117.