home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ftp.barnyard.co.uk
/
2015.02.ftp.barnyard.co.uk.tar
/
ftp.barnyard.co.uk
/
cpm
/
walnut-creek-CDROM
/
SIMTEL
/
CPMUG
/
CPMUG003.ARK
/
ANIMAL.BAS
< prev
next >
Wrap
BASIC Source File
|
1984-04-29
|
2KB
|
93 lines
NAME$="ANIMAL.GME"
PRINT"***** ANIMALS ******"
PRINT "YOU THINK OF AN ANIMAL AND"
PRINT"THIS PROGRAM TRIES TO GUESS IT"
PRINT"THE COMPUTER ASKS A SERIES OF QUESTIONS AND YOU REPLY YES OR NO"
PRINT "IF IT DOES NOT GET YOUR ANIMAL THEN IT ASKS YOU"
PRINT "FOR A QUESTION THAT IT COULD HAVE ASKED"
PRINT "IT LEARNS NEW QUESTIONS IN THIS WAY"
PRINT "THE MORE IT PLAYS THE MORE ANIMALS IT GETS TO KNOW"
10 PRINT
PRINT
PRINT "ARE YOU THINKING OF AN ANIMAL";
INPUT R$
R$=LEFT$(R$,1)
IF R$ NE "Y" THEN STOP
FILE NAME$(80)
IF END #1 THEN 600
READ #1,1;N
L=0
FOR I=2 TO N
J=I
IF END #1 THEN 600
READ #1,I;Q$,A$,B$
PRINT Q$;
INPUT R$
R$=LEFT$(R$,1)
IF R$=A$ THEN 800
NEXT I
L=1
200 READ #1,N;Q$,A$,B$,P$
210 PRINT "IS IT A "+P$;
INPUT R$
R$=LEFT$(R$,1)
IF R$="Y" THEN 700
B$=P$
300 GOSUB 2000
REM ****INSERT AT END OF FILE ****
400 IF J<>N THEN 500
IF L=0 THEN 500
READ #1,N;Q$,A$,B$,P$
PRINT #1,N;Q$,A$,B$
PRINT #1,N+1;D$,E$,C$,P$
PRINT #1,1;N+1
GO TO 710
REM ****CREATE NEW FILE *****
500 IF J<>N THEN 510
READ #1,N;Q$,A$,B$,P$
PRINT #1,N;Q$,A$,"@"+B$,P$
GO TO 520
510 READ #1,J;Q$,A$,B$
PRINT #1,J;Q$,A$,"@"+B$
520 F$=LEFT$(B$,5)+".GME"
530 CLOSE (1)
FILE F$(80)
PRINT #1,1;2
PRINT #1,2;D$,E$,C$,B$
GO TO 710
REM **** HERE ON ERROR *****
600 PRINT "FILE READ ERROR RECORD";J
CLOSE (1)
STOP
700 PRINT
PRINT
PRINT
PRINT "!!!! I GOT THAT ONE !!!!!"
PRINT
PRINT
PRINT
710 NAME$="ANIMAL.GME"
CLOSE (1)
GO TO 10
800 IF LEFT$(B$,1)="@" THEN 900
PRINT "IS IT A "+B$;
INPUT R$
R$=LEFT$(R$,1)
IF R$="Y" THEN 700
GO TO 300
900 B$=RIGHT$(B$,LEN(B$)-1)
NAME$=LEFT$(B$,5)+".GME"
CLOSE (1)
GO TO 200
2000 INPUT"WHAT ANIMAL WERE YOU THINKING OF";C$
PRINT "GIVE ME A QUESTION THAT I COULD HAVE ASKED TO TELL A "+C$+" FROM A "+B$
INPUT D$
PRINT "FOR A "+C$+" WHAT IS THE ANSWER ";
2100 INPUT E$
E$=LEFT$(E$,1)
IF E$="Y" OR E$="N" THEN RETURN
PRINT "PLEASE ANSWER YES OR NO"
GO TO 2100
9999 CLOSE(1)
END