home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / SIMTEL / CPMUG / CPMUG003.ARK / BAGELS.BAS < prev    next >
BASIC Source File  |  1984-04-29  |  2KB  |  64 lines
  1. 5 DIM N(10),A(10)
  2. 10 PRINT:PRINT:PRINT"THE BAGELS GAME:"
  3. 60 PRINT
  4. 70 INPUT "WOULD YOU LIKE THE RULES";A$
  5. 80 IF A$="N" OR A$="NO" THEN 160
  6. 90 PRINT"I AM THINKING OF A 3 DIGIT NUMBER.  YOU CAN GUESS WHAT"
  7. 100 PRINT"NUMBER I HAVE IN MIND AND I WILL TELL YOU:"
  8. 120 PRINT"PICO - ONE DIGIT IS IN THE WRONG PLACE"
  9. 130 PRINT"FERMI - ONE DIGIT IS IN THE CORRECT PLACE"
  10. 140 PRINT"BAGELS - NO DIGIT IS CORRECT"
  11. 160 RANDOMIZE
  12. 165 N(3)=INT(RND*9+1)
  13. 170 N(2)=INT(RND *10)
  14. 180 IF N(2)=N(3) THEN 170
  15. 190 N(1)=INT(RND *10)
  16. 200 IF N(1)=N(2) THEN 190
  17. 210 IF N(1)=N(3) THEN 190
  18. 220 PRINT: PRINT "OK, IHAVE A NUMBER."
  19. 240 G=0
  20. 260 PRINT:PRINT:PRINT "YOUR GUESS";
  21. 290 INPUT X
  22. 300 G=G+1
  23. 310 A(3)=INT(X/100)
  24. 320 A(2)=INT(X/10)-A(3)*10
  25. 330 A(1)=X-INT(X/10)*10
  26. 340 IF A(3)>9 THEN 410
  27. 350 IF A(3)<1 THEN 410
  28. 360 IF INT(X)<>X THEN 410
  29. 370 IF A(1)=A(2) THEN 410
  30. 380 IF A(2)=A(3) THEN 410
  31. 390 IF A(1)=A(3) THEN 410
  32. 400 GOTO 450
  33. 410 PRINT "   PICK A 3 DIGIT NUMBER FROM 102 TO 987"
  34. 420 PRINT "   HINT: IN MY NUMBER ALL THE DIGITS ARE DIFFERENT"
  35. 430 GOTO 260
  36. 450 F=0:P=0
  37. 460 FOR I=1 TO 3
  38. 470 FOR J=1 TO 3
  39. 480 IF A(I)=N(J) THEN 540
  40. 490 NEXT J
  41. 500 NEXT I
  42. 510 IF F+P<>0 THEN 590
  43. 520 PRINT"BAGELS ";
  44. 530 GOTO 260
  45. 540 IF I=J THEN 570
  46. 550 P=P+1
  47. 560 GOTO 490
  48. 570 F=F+1
  49. 580 GOTO 490
  50. 590 IF P=0 THEN 630
  51. 600 FOR K=1 TO P
  52. 610 PRINT "PICO ";
  53. 620 NEXT K
  54. 630 IF F=0 THEN 260
  55. 640 IF F=3 THEN 700
  56. 650 FOR K=1 TO F
  57. 660 PRINT "FERMI  ";
  58. 670 NEXT K
  59. 680 GOTO 260
  60. 700 PRINT "YOU GOT IT IN ";G;"GUESSES!!!"
  61. 750 PRINT:INPUT "ANOTHER GAME";A$
  62. 760 IF LEFT$(A$,1)="Y" THEN 160
  63. 770 END
  64.