home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ftp.barnyard.co.uk
/
2015.02.ftp.barnyard.co.uk.tar
/
ftp.barnyard.co.uk
/
cpm
/
walnut-creek-CDROM
/
MBUG
/
MBUG059.ARC
/
TABLEOFC.DOC
< prev
next >
Wrap
Text File
|
1979-12-31
|
13KB
|
315 lines
10 REM Documentation for the Genealogy ON DISPLAY Programs
20 REM All data is in the form of DATA statements.
30 REM By: Melvin O. Duke. Updated June 1983.
40 DATA Genealogy
50 DATA User's Manual
60 DATA -5
70 DATA 1
80 INDENT = 0
90 DASHES$ = "+"+STRING$(54,45)+"+"
100 TRIM.LINE$ = "(Trim-line)"
110 REM Program begins here
120 READ TITLE$, DOC.NAME$, PAGE.NO, LINE.NO
130 IF PAGE.NO MOD 2 = 0 THEN TAB.POS = 8 ELSE TAB.POS = 13
140 GOSUB 500 'For trim line and heading space
150 FOR I = 1 TO 6 : LPRINT : NEXT I
160 LPRINT CHR$(14); 'Set Expanded Print
170 LPRINT TAB(TAB.POS-2);TITLE$
180 LPRINT CHR$(18); 'Return to normal
190 FOR I = 1 TO 3 : LPRINT : NEXT I
200 LPRINT CHR$(27); "E"; 'Set Emphasized mode
210 LPRINT TAB(TAB.POS+12);"ON DISPLAY"
220 LPRINT CHR$(27); "F"; 'Return to normal
222 LPRINT : LPRINT : LPRINT
224 LPRINT TAB(TAB.POS+11);"Version 1.3"
230 FOR I = 1 TO 11 : LPRINT : NEXT I
240 LPRINT TAB(TAB.POS+10); DOC.NAME$
250 LINE.NO = LINE.NO + 27
260 '
270 READ REPLY$
280 IF LEFT$(REPLY$,1) = "." THEN GOSUB 850: GOTO 270
290 IF LINE.NO > 44 THEN GOSUB 610
300 REM Print the line if not a command
310 LPRINT TAB(TAB.POS);REPLY$
320 LINE.NO = LINE.NO + 1
330 IF PAGE.NO MOD 2 = 0 THEN TAB.POS = 8 ELSE TAB.POS = 13
340 GOTO 270
350 REM Data for the Copyright Page
354 DATA ".pa"
358 DATA "Anyone may request a copy of these"
362 DATA "programs by sending two blank diskettes"
366 DATA "to the author of the programs (one for"
370 DATA "the programs, and the second for the"
374 DATA "documentation)."
378 DATA ".sp"
382 DATA "An addressed, postage-paid return"
386 DATA "mailer must accompany the diskettes (no"
390 DATA "exceptions, please).
394 DATA ".sp"
398 DATA "A copy of the programs with documenta-"
402 DATA "tion will be sent by return mail."
406 DATA ".sp"
410 DATA "Regardless of whether a contribution"
414 DATA "is made, the user is encouraged to"
418 DATA "copy and share the program with others."
422 DATA "Payment for use is discretionary on"
426 DATA "the part of each subsequent user."
430 DATA ".vt 4"
434 DATA "If you are using these programs, and"
438 DATA "finding them of value, your contribution"
442 DATA "($35 suggested) will be appreciated."
446 DATA ".sp"
450 DATA "Melvin O. Duke"
454 DATA "P. O. Box 20836"
458 DATA "San Jose, CA 95160"
462 DATA ".vt 4"
466 DATA "Copyright (c) 1983, by:"
470 DATA "Melvin O. Duke."
474 DATA ".sp"
478 DATA "All rights reserved."
482 '
500 REM Top of each page routine
510 IF PAGE.NO MOD 2 = 0 THEN TAB.POS = 8 ELSE TAB.POS = 13
520 LPRINT
530 LPRINT TAB(30); TRIM.LINE$
540 LPRINT DASHES$ 'Dashes
550 FOR I = 1 TO 6
560 LPRINT
570 NEXT I
580 LINE.NO = LINE.NO + 6
590 RETURN
600 '
610 REM Bottom of each page Routine
620 IF PAGE.NO < 1 THEN LPRINT : LPRINT : LPRINT : GOTO 740
630 LPRINT TAB(TAB.POS); STRING$(40,45) 'on line 46
640 LPRINT TAB(TAB.POS+3); TITLE$+" ON DISPLAY. Version 1.3" 'on line 47
650 IF PAGE.NO MOD 2 = 1 THEN 690
660 LPRINT TAB(TAB.POS);"Page";PAGE.NO;
670 LPRINT TAB(TAB.POS+27);"User's Manual"
680 GOTO 740
690 LPRINT TAB(TAB.POS); "User's Manual";
700 IF PAGE.NO < 10 THEN DELTA = 34
710 IF PAGE.NO > 9 THEN DELTA = 33
720 IF PAGE.NO > 99 THEN DELTA = 32
730 LPRINT TAB(TAB.POS+DELTA); "Page"; PAGE.NO 'on line 48
740 LPRINT : LPRINT : LPRINT
750 LPRINT DASHES$ 'dashes after 51
760 LPRINT TAB(30); TRIM.LINE$
770 LPRINT CHR$(12);
780 PAGE.NO = PAGE.NO + 1
790 LINE.NO = 1
800 IF REPLY$ = ".eof" THEN 820 'Bypass after last page
810 GOSUB 500 'For top of next page
820 IF PAGE.NO MOD 2 = 0 THEN TAB.POS = 8 ELSE TAB.POS = 13
830 RETURN
840 '
850 REM Command Processor
860 IF LEFT$(REPLY$,3) = ".h1" THEN 960
870 IF LEFT$(REPLY$,3) = ".h2" THEN 1100
880 IF LEFT$(REPLY$,3) = ".h3" THEN 1210
890 IF LEFT$(REPLY$,3) = ".sp" THEN 1320
900 IF LEFT$(REPLY$,4) = ".eof" THEN 1370
910 IF LEFT$(REPLY$,3) = ".pa" THEN 1410
920 IF LEFT$(REPLY$,3) = ".vt" THEN 1480
930 IF LEFT$(REPLY$,3) = ".pk" THEN 1590
940 IF LEFT$(REPLY$,3) = ".in" THEN 1720
950 STOP
960 REM Head 1 Processor
970 FOR I = LINE.NO TO 44
980 LPRINT
990 NEXT I
1000 GOSUB 610 'Bottom of page Routine
1010 IF PAGE.NO MOD 2 = 0 THEN GOSUB 1410 'For h1 on Odd pages
1020 LPRINT CHR$(14); 'Set expanded print
1030 IF PAGE.NO MOD 2 = 0 THEN ADJUST = -4 ELSE ADJUST = -7
1040 LPRINT TAB(TAB.POS+ADJUST); RIGHT$(REPLY$,LEN(REPLY$)-4)
1050 LPRINT CHR$(18); 'Return to normal
1060 LINE.NO = LINE.NO+1
1070 IF PAGE.NO MOD 2 = 0 THEN TAB.POS = 8 ELSE TAB.POS = 13
1080 RETURN
1090 '
1100 REM Head 2 Processor
1110 IF LINE.NO = 7 THEN 1130 'skip spacing if at top of page
1120 IF LINE.NO > 43 THEN GOSUB 1410 ELSE LPRINT:LPRINT:LINE.NO = LINE.NO+2
1130 LPRINT CHR$(27); "E"; 'Set emphasized print
1140 LPRINT TAB(TAB.POS); RIGHT$(REPLY$,LEN(REPLY$)-4)
1150 LPRINT CHR$(27); "F"; 'Return to normal
1160 LPRINT
1170 LINE.NO = LINE.NO + 2
1180 IF PAGE.NO MOD 2 = 0 THEN TAB.POS = 8 ELSE TAB.POS = 13
1190 RETURN
1200 '
1210 REM Head 3 Processor
1220 IF LINE.NO = 7 THEN 1240 'skip spacing if at top of page
1230 IF LINE.NO > 43 THEN GOSUB 1410 ELSE LPRINT:LPRINT:LINE.NO = LINE.NO+2
1240 LPRINT CHR$(27); "E"; 'Set emphasized print
1250 LPRINT TAB(TAB.POS); RIGHT$(REPLY$,LEN(REPLY$)-4)
1260 LPRINT CHR$(27); "F"; 'Return to normal
1270 LPRINT
1280 LINE.NO = LINE.NO + 2
1290 IF PAGE.NO MOD 2 = 0 THEN TAB.POS = 8 ELSE TAB.POS = 13
1300 RETURN
1310 '
1320 REM Single Space Processor
1330 IF LINE.NO = 7 THEN 1350
1340 IF LINE.NO > 44 THEN GOSUB 1410 ELSE LPRINT : LINE.NO = LINE.NO + 1
1350 IF PAGE.NO MOD 2 = 0 THEN TAB.POS = 8 ELSE TAB.POS = 13
1360 RETURN
1370 REM End of File Processor
1380 GOSUB 1410 'Bottom of Page
1390 LPRINT CHR$(12);
1400 GOTO 15470
1410 REM Page Eject Processor
1420 FOR I = LINE.NO TO 44
1430 LPRINT
1440 LINE.NO = LINE.NO + 1
1450 NEXT I
1460 GOSUB 610 'Bottom of Page Processing
1470 RETURN
1480 REM Vertical Tab Processor
1490 IF LINE.NO = 7 THEN 1580
1500 IF LINE.NO > 44 THEN GOSUB 610 'End of page
1510 QTY = VAL(RIGHT$(REPLY$,LEN(REPLY$)-3))
1520 FOR I = 1 TO QTY
1530 LPRINT
1540 LINE.NO = LINE.NO + 1
1550 IF LINE.NO > 44 THEN I = QTY
1560 NEXT I
1570 IF PAGE.NO MOD 2 = 0 THEN TAB.POS = 8 ELSE TAB.POS = 13
1580 RETURN
1590 REM Pack Processor
1600 IF LINE.NO > 44 THEN GOSUB 610
1610 IF TAB.POS = 8 THEN ADJUST = 4
1620 IF TAB.POS = 13 THEN ADJUST = 7
1630 TAB.POS = TAB.POS + ADJUST + INDENT
1640 LPRINT CHR$(15); 'Packed printing
1650 WIDTH "lpt1:", 132 'set condensed width
1660 LPRINT TAB(TAB.POS); RIGHT$(REPLY$,LEN(REPLY$)-3)
1670 LPRINT CHR$(18); 'Return to normal
1680 WIDTH "lpt1:", 80 'return to normal
1690 LINE.NO = LINE.NO + 1
1700 IF PAGE.NO MOD 2 = 0 THEN TAB.POS = 8 ELSE TAB.POS = 13
1710 RETURN
1720 REM Indent Processor
1730 INDENT = VAL(RIGHT$(REPLY$,LEN(REPLY$)-3))
1740 RETURN
1750 DATA ".h1 TABLE OF CONTENTS"
1760 DATA ".sp"
1770 DATA "INTRODUCTION - - - - - - - - - - - - 1"
1780 DATA " OVERVIEW - - - - - - - - - - - - - 1"
1790 DATA " CAPABILITIES - - - - - - - - - - - 1"
1800 DATA " Display the Genealogy - - - - - 2"
1810 DATA " Print Pedigree Charts - - - - - 2"
1820 DATA " Print Family Group Sheets - - - 3"
1830 DATA " Create the Data Files - - - - - 3"
1840 DATA " Update the Data Files - - - - - 3"
1850 DATA " Create the Indices - - - - - - - 4"
1860 DATA " List the Records in the File - - 4"
1870 DATA " Printing the Contents of the"
1880 DATA " files - - - - - - - - - - - - 4"
1890 DATA " Alphabetical Lists - - - - - - - 5"
1900 DATA " Parent/Child Index List - - - - 5"
1910 DATA " BENEFITS/ADVANTAGES - - - - - - - 6"
1920 DATA " RESULTS - - - - - - - - - - - - - 6"
1930 DATA " REQUIREMENTS - - - - - - - - - - - 7"
1940 DATA " Hardware Requirements - - - - - 7"
1950 DATA " Software Requirements - - - - - 8"
1960 DATA ".sp"
1970 DATA "GENERAL INFORMATION - - - - - - - - 9"
1980 DATA " DESCRIPTION OF FUNCTIONS - - - - - 9"
1990 DATA " File Creation - - - - - - - - - 9"
2000 DATA " File Maintenance - - - - - - - - 9"
2010 DATA " File Indices - - - - - - - - - - 9"
2020 DATA " Summary Lists - - - - - - - - - 10"
2030 DATA " Detailed Data - - - - - - - - - 10"
2040 DATA " Displaying the Genealogy - - - - 10"
2050 DATA " Printing Pedigree Charts - - - - 11"
2060 DATA " Printing Family Group Sheets - - 11"
2070 DATA ".pa"
2080 DATA " DEFINITION OF TERMS - - - - - - - 12"
2090 DATA " Personal Information - - - - - - 12"
2100 DATA " Pedigree Information - - - - - - 12"
2110 DATA " Family Group Information - - - - 12"
2120 DATA " Ordinance Information - - - - - 13"
2130 DATA " EXPLANATION OF GENERAL CONCEPTS - 14"
2140 DATA " Persfile - - - - - - - - - - - - 15"
2150 DATA " Marrfile - - - - - - - - - - - - 16"
2160 DATA " Pcindex - - - - - - - - - - - - 17"
2170 DATA " Mindex - - - - - - - - - - - - - 17"
2180 DATA " Ordfile - - - - - - - - - - - - 18"
2190 DATA " Relationships - - - - - - - - - 19"
2200 DATA " BEFORE YOU START - - - - - - - - - 20"
2205 DATA " List of Persons - - - - - - - - 20"
2207 DATA " List of Marriages - - - - - - - 22"
2210 DATA ".sp"
2220 DATA "USING THE PROGRAM - - - - - - - - - 23"
2225 DATA " GETTING STARTED - - - - - - - - - 23"
2230 DATA " FIRST TIME USAGE - - - - - - - - - 25"
2240 DATA " Caution - - - - - - - - - - - - 26"
2260 DATA " HOW TO OPERATE - - - - - - - - - - 27"
2270 DATA " Operating the updatper program - 27"
2280 DATA " Operating the updatmar program - 29"
2290 DATA " Operating the updatord program - 30"
2295 DATA " Operating the indexpc program - 31"
2296 DATA " Operating the indexmar program - 32"
2300 DATA " Operating the display program - 33"
2310 DATA " Operating the pedigree program - 36"
2320 DATA " Operating the family program - - 37"
2330 DATA " Operating the other programs - - 38"
2340 DATA " HOW TO STOP - - - - - - - - - - - 39"
2350 DATA " Stopping the update programs - - 39"
2370 DATA " Stopping the display program - - 39"
2380 DATA " Stopping the pedigree program - 39"
2390 DATA " Stopping the family program - - 39"
2400 DATA " Stopping the other programs - - 40"
2410 DATA ".pa"
2420 DATA "REFERENCE MATERIAL - - - - - - - - - 41"
2430 DATA " SAMPLE SCREENS AND PROMPTING"
2440 DATA " MESSAGES - - - - - - - - - - - 41"
2450 DATA " Personal Information - - - - - - 44"
2460 DATA " Pedigree Information - - - - - - 45"
2470 DATA " Family Group Information - - - - 46"
2480 DATA " Ordinance Information - - - - - 47"
2490 DATA " COMMANDS USED - - - - - - - - - - 48"
2500 DATA " Basic Command - - - - - - - - - 48"
2510 DATA " Load Command - - - - - - - - - - 48"
2520 DATA " Run Command - - - - - - - - - - 48"
2530 DATA ".sp"
2540 DATA "APPENDIX A. MESSAGES - - - - - - - 49"
2550 DATA " Start-up Messages - - - - - - - - 49"
2560 DATA " Error Messages - - - - - - - - - - 50"
2570 DATA ".sp"
2580 DATA "APPENDIX B. SUMMARY - - - - - - - - 51"
2590 DATA " General Programs - - - - - - - - - 51"
2600 DATA " Documentation - - - - - - - - - - 52"
2620 DATA ".sp"
2630 DATA "APPENDIX C. HINTS - - - - - - - - - 53"
2640 DATA " Names - - - - - - - - - - - - - - 53"
2650 DATA " Dates - - - - - - - - - - - - - - 53"
2660 DATA " Commas - - - - - - - - - - - - - - 53"
2670 DATA " Replacing with Blanks - - - - - - 54"
2680 DATA " Placement of Programs - - - - - - 54"
2800 DATA ".pa"
2810 DATA "APPENDIX D. MODIFICATIONS - - - - - 55"
2820 DATA " Changing the Number of Persons - - 55"
2830 DATA " Changing the Number of Marriages - 59"
2840 DATA " Repositioning the Data Files - - - 62"
2850 DATA " Persons File - - - - - - - - - - 62"
2860 DATA " Marriages File - - - - - - - - - 63"
2870 DATA " Ordinances File - - - - - - - - 64"
2880 DATA " Parent/Child Index - - - - - - - 65"
2890 DATA " Marriages Index - - - - - - - - 66"
2900 DATA " Removing the Ordinances File - - - 67"
2910 DATA " Changing the Ordinances File - - - 68"
2920 DATA " Utilizing Other Printers - - - - - 69"
2930 DATA ".sp"
2940 DATA "APPENDIX E. TERMS & CONDITIONS - - 73"
2950 DATA " Terms - - - - - - - - - - - - - - 73"
2960 DATA " Conditions - - - - - - - - - - - - 74"
2980 DATA " Disclaimer - - - - - - - - - - - - 74"
15460 DATA ".eof"
15470 END
60 DATA "the user may have asked for a Family"
11770 DATA "Group (fg), as:"
11780 DATA ".sp"
11790 DAT