home *** CD-ROM | disk | FTP | other *** search
/ The World of Computer Software / World_Of_Computer_Software-02-385-Vol-1of3.iso / t / t_append.zip / T_APPEND.ASM < prev    next >
Assembly Source File  |  1993-01-21  |  5KB  |  179 lines
  1.     name    tee
  2.     page    55,132
  3.     title    'TEE - tee junction for DOS pipes'
  4. ;
  5. ; TEE --- A "tee" junction for DOS 2.x pipes
  6. ;         after the fashion of the Unix function TEE  
  7. ; 
  8. ; By A. K. Head, 6 Duffryn Place, Melbourne, Australia 3142
  9. ;    Somewhat overhauled & with error handling added by Ray Duncan
  10. ;
  11. ; 01/21/93 This is a slight modification of TEE --> T_APPEND
  12. ;            by Scott McEndree, 747 Maple Av, Newark, Ohio 43055
  13. ;
  14. ; T_APPEND reads from the standard input (redirectable) and
  15. ; outputs to both the standard output (redirectable)
  16. ; and a file, e.g.:   DIR | T_APPEND outfile.ext
  17. ;
  18. ; The output file "outfile.ext" is appended with the data.
  19. ; If it doesn't exist, it is created.
  20. ;
  21. ; This is great for creating log files where you want data to go to
  22. ; the screen and a log file.
  23. ;
  24. ; The file can be CON, LPT1, etc.  If it is CON, then
  25. ; keyboard Control-S pauses the display as usual.
  26.  
  27. command equ     80h             ; buffer for command tail
  28. buflen    equ    16384        ; buffer length, alter to taste
  29.  
  30. cr    equ    0dh        ; ASCII carriage return
  31. lf    equ    0ah        ; ASCII line feed
  32. ff    equ    0ch        ; ASCII form feed
  33. eof    equ    01ah        ; End-of-file marker
  34. tab    equ    09h        ; ASCII tab code
  35. blank   equ     20h             ; ASCII blank
  36.  
  37.                 ; DOS 2.x pre-defined handles
  38. stdin    equ    0000        ; standard input file
  39. stdout    equ    0001        ; standard output file
  40. stderr    equ    0002        ; standard error file
  41. stdaux    equ    0003        ; standard auxilliary file
  42. stdprn    equ    0004        ; standard printer file
  43.  
  44.  
  45. cseg    segment para public 'CODE'
  46.  
  47.     assume    cs:cseg,ds:cseg
  48.  
  49.     org    100H        ; start .COM at 100H
  50.  
  51. tee    proc    far
  52.  
  53.         mov     cl,ds:command   ; get length of command tail.
  54.     xor    ch,ch 
  55.                                 ; address of command string.
  56.         mov     si,offset command+1
  57.         mov     di,offset command+1
  58.  
  59. tee1:                ; squeeze out leading spaces.
  60.     mov    al,byte ptr [si]
  61.         cmp     al,blank
  62.     jbe    tee2
  63.     mov    byte ptr [di],al
  64.     inc    di
  65.  
  66. tee2:   inc     si              ; look through command tail
  67.     loop    tee1        ; until it's exhausted.
  68.     mov    byte ptr [di],0 ; make ASCIIZ string.
  69.         mov     al,02h          ; read/write access
  70.         mov     ah,3dh          ; create output file.
  71.     mov    cx,0        ; attribute=0.
  72.         mov     dx,offset command+1
  73.     int    21h
  74.         mov     handle,ax       ; save token for file.
  75.         jnc     append          ; if exist append
  76.  
  77.         mov     ah,3ch          ; create output file.
  78.     mov    cx,0        ; attribute=0.
  79.         mov     dx,offset command+1
  80.         int     21h
  81.         mov     handle,ax       ; save token for file.
  82.         jc      tee6            ; can't create file
  83.  
  84. append: mov     ah,42h
  85.         mov     al,02h          ; offset from end of file
  86.         mov     bx,handle       ; set file handle
  87.         mov     cx,00h
  88.         mov     dx,00h
  89.         int     21h             ; move file pointer
  90.  
  91.         jc      tee8            ; can't create file
  92.  
  93. tee3:    mov    ah,3fh        ; read standard input.
  94.     mov    bx,stdin
  95.     mov    cx,buflen
  96.     lea    dx,buffer
  97.     int    21h
  98.     jc    tee4        ; jump, error.
  99.     mov    nchar,ax    ; save length of read.
  100.     cmp    ax,0        ; nothing read in?
  101.     je    tee4        ; end of file, exit.
  102.     mov    ah,40h        ; write to file...
  103.     mov    bx,handle
  104.     mov    cx,nchar
  105.     int    21h
  106.     jc    tee7        ; jump, write failed.
  107.     cmp    ax,nchar
  108.     jne    tee7        ; jump, write failed.
  109.     mov    ah,40h        ; now write to standard output...
  110.     mov    bx,stdout
  111.     int    21h
  112.     jc    tee7        ; jump, write failed.
  113.     cmp    ax,nchar
  114.     jne    tee7        ; jump, write failed.
  115.     jmp     tee3        ; read again until end of file.
  116.  
  117. tee4:    mov    ah,3eh        ; close output file.
  118.     mov    bx,handle
  119.     int    21h
  120.  
  121. tee5:    mov    ax,4c00h    ; exit with return code=0.
  122.     int    21h
  123.  
  124. tee6:    mov    dx,offset err1    ; print "Can't create file".
  125.     mov    cx,err1len
  126.          mov    ah,40h        ; display error message and exit.
  127.     mov    bx,stderr
  128.     int    21h
  129.     mov    ax,4c01h    ; exit with return code=1.
  130.     int    21h
  131.  
  132. tee7:    mov    dx,offset err2    ; print "Disk is full".
  133.     mov    cx,err2len
  134.          mov    ah,40h        ; display error message and exit.
  135.     mov    bx,stderr
  136.     int    21h
  137.     mov    ah,3eh        ; close output file.
  138.     mov    bx,handle
  139.     int    21h
  140.     mov    ax,4c02h    ; exit with return code=2.
  141.     int    21h
  142.  
  143. tee8:   mov     dx,offset err3  ; print "Can't append file".
  144.         mov     cx,err3len
  145.          mov    ah,40h        ; display error message and exit.
  146.     mov    bx,stderr
  147.     int    21h
  148.     mov    ax,4c01h    ; exit with return code=1.
  149.     int    21h
  150.  
  151. tee     endp
  152.  
  153.  
  154. nchar    dw     0        ; number of chars actually input.
  155. handle    dw    0        ; token for output file.
  156.  
  157. err1       db    cr,lf
  158.     db    'tee: Cannot create file' 
  159.     db    cr,lf
  160. err1len equ    (this byte)-(offset err1) 
  161.  
  162. err2     db    cr,lf
  163.     db    'tee: Disk is full.'
  164.     db    cr,lf
  165. err2len equ    (this byte)-(offset err2) 
  166.  
  167. err3    db      cr,lf
  168.         db      'tee: Cannot append file'
  169.     db    cr,lf
  170. err3len equ     (this byte)-(offset err1)
  171.  
  172. buffer  equ     this byte       ; data is read here from
  173.                 ; standard input
  174.  
  175. cseg    ends
  176.  
  177.     end    tee
  178. 
  179.