home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
The World of Computer Software
/
World_Of_Computer_Software-02-385-Vol-1of3.iso
/
p
/
pcsp2_0.zip
/
DRV_SRC.ZIP
/
VIDEO7H.ASM
< prev
Wrap
Assembly Source File
|
1993-01-10
|
2KB
|
100 lines
;Pcspace-Grafiktreiber VIDEO7- 256Farben
;
;Zum Erstellen von VIDEO7H.drv:
; tasm video7h
; tlink video7h
; exe2bin video7h
; ren video7h.bin video7h.drv
;
; Achtung: Maximallänge der drv datei: 128 Bytes
prog segment para 'code'
assume cs:prog
assume ds:prog
assume ss:prog
assume es:prog
start proc far
; Einsprung Videomodus initialisieren
jmp short init
; Einsprung 64k Bank setzen und Segmentadresse nach ex
; in al ist die bank nr.
jmp short bank
;Treiberparameter
db 255 ;Anzahl der Farben-1
;Parametertabelle für Initialisierung
db 67h ;Modus 0: Auflösung 640*480
db 69h ;Modus 1: Auflösung 800*600
db -1 ;Modus 2: Auflösung 1024*768 (nicht vorhanden)
db "Video7 256Farben" ;Identifizierungstext für Setup
db 0 ;Länge kann variabel sein
;Videomodus initialisieren
;Verwedete Register: ax,bx
init: ;al wurde mit dem Wert der Parametertabelle besetzt
;Auflösung nicht vorhanden (Par.-1) wurde schon abgefangen.
mov bl,al
xor bh,bh
mov ax,6f05h
int 10h
db 0cbh ;retf
;Videobank setzen
;Verwedete Register: ax,dx,es
bank: mov dx,0a000h
mov es,dx
push bx
mov bl,al
mov dx,03c4h
mov al,0f9h
out dx,al
inc dx
mov al,bl
and al,01h
out dx,al
mov dl,0cch
in al,dx
and al,0dfh
mov ah,bl
and ah,02h
shl ah,1
shl ah,1
shl ah,1
shl ah,1
or al,ah
mov dl,0c2h
out dx,al
mov dl,0c4h
mov al,0f6h
out dx,al
inc dx
in al,dx
and al,0f0h
mov ah,bl
shr ah,1
shr ah,1
mov bh,bl
and bh,4
or ah,bh
or al,ah
out dx,al
pop bx
db 0cbh ;retf
start endp
prog ends
end start