home *** CD-ROM | disk | FTP | other *** search
/ The World of Computer Software / World_Of_Computer_Software-02-385-Vol-1of3.iso / c / cmsrc392.zip / GREEKL.MF < prev    next >
Text File  |  1992-03-30  |  22KB  |  492 lines
  1. % This lowercase Greek alphabet was prepared by D. E. Knuth in December, 1979,
  2. % inspired by the Monotype faces used in {\sl The Art of Computer Programming}.
  3. % (It has been designed for math formulas, not Greek texts.)
  4. % The programs were revised for the new \MF\ conventions in 1985.
  5.  
  6. % Character codes \0013--\0047 are generated.
  7.  
  8. cmchar "Lowercase Greek alpha";
  9. beginchar(oct"013",11u#,x_height#,0);
  10. italcorr max(1/3x_height#*slant+.5hair#+.5u#,x_height#*slant-.5u#);
  11. adjust_fit(0,0); pickup fine.nib;
  12. pos0(hair,0); pos1(vair,-90); pos2(curve,-180); pos3(vair,-270);
  13. z4=(w-3.25u,9/16h); z5=(w-2.75u,.5[vair,y4]);
  14. numeric theta; theta=angle(z4-z5)-90;
  15. pos4(stem,theta); pos5(stem,theta);
  16. pos6(vair,90); pos7(hair,180);
  17. rt x0r=hround(w-u); x1=x3=.5w-u; lft x2r=hround(1.5u-.5curve);
  18. x6=w-u; x7+.5hair=hround(w+.5hair-epsilon);
  19. top y0=vround .8[bar_height,h]; bot y1r=bot y6l=-oo;
  20. y2=.5[y1,y3]; top y3r=h+oo; y7=1/4bar_height;
  21. filldraw stroke z0e{down}...pulled_arc.e(1,2) & pulled_arc.e(2,3)
  22.  ...z4e---z5e...z6e{right}...{up}z7e; % diagonal, bowl, and hook
  23. math_fit(-.3x_height#*slant+.5curve#-u#,1/3x_height#*slant+.5hair#+.5u#);
  24. penlabels(0,1,2,3,4,5,6,7); endchar;
  25.  
  26. cmchar "Lowercase Greek beta";
  27. beginchar(oct"014",9.5u#,asc_height#,desc_depth#);
  28. italcorr .5[x_height#,asc_height#]*slant-u#;
  29. adjust_fit(0,0); pickup fine.nib;
  30. pos0(hair,180); pos1(hair,180); pos2(vair,90);
  31. pos3(stem,0); pos4(vair,-90); pos5(hair,-180);
  32. pos6(vair,-270); pos7(curve,-360); pos8(vair,-450); pos9(hair,-540);
  33. x0=x1=x9; lft x0l=hround(1.5u-.5hair); x2=x4=x6=x8=.5w+.25u;
  34. rt x3r=hround(w-1.5u); rt x7r=hround(w-1.5u+.5curve); rt x5l=hround(x4-u);
  35. bot y0=-d; y1=top y6r=x_height; top y2r=h+oo; y3=.5[y2,y4];
  36. y5=.5[y4,y6]; top y6r-bot y4r=vstem+eps; bot y8=-oo; y7=y9=.5[y6,y8];
  37. if y6l<y4l: y6l:=y4l:=y5; fi
  38. filldraw stroke z0e---z1e...pulled_arc.e(2,3)
  39.  & pulled_arc.e(3,4)...{up}z5e;  % stem and upper bowl
  40. filldraw stroke z5e{up}...pulled_arc.e(6,7)
  41.  & pulled_arc.e(7,8)...{up}z9e;  % lower bowl
  42. math_fit(desc_depth#*slant+.5hair#-u#,.7x_height#*slant+.5curve#-1.5u#);
  43. penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  44.  
  45. cmchar "Lowercase Greek gamma";
  46. beginchar(oct"015",10u#,x_height#,desc_depth#);
  47. italcorr x_height#*slant-.5u#;
  48. adjust_fit(0,0); pickup fine.nib;
  49. pos1(hair,180); pos2(vstem+dw,90);
  50. pos4(hair,0); pos5(vair,-90); pos6(hair,-180); pos7(hair,-180);
  51. bot y1=.5772156649h; top y2r=h+oo; y4=y6=-.5d;
  52. bot y5r=-d-o; top y7=h;
  53. lft x1r=hround(.5u-.5hair); x2=3u; rt x4r=hround(w-2u); x5=.5[x4,x6];
  54. rt x4r-lft x6r=hround 1/3[hair,stem]+eps; rt x7l=hround(w-u);
  55. if x4l<x6l: x4l:=x6l:=x5; fi
  56. pos3(hair,angle(z4-z2)+90); x3=superness[x2,x4]; y3=superness[y4,y2];
  57. filldraw stroke z1e{up}...z2e{right}...z3e{z4-z2}
  58.  ...z4e{down}...{left}z5e; % arc
  59. filldraw stroke z5e{left}...z6e{up}..{2(x7-x6),y7-y6}z7e;  % stem
  60. math_fit(-.5772156649x_height#*slant,ic#-u#);
  61. penlabels(1,2,3,4,5,6,7); endchar;
  62.  
  63. cmchar "Lowercase Greek delta";
  64. beginchar(oct"016",8u#,asc_height#,0);
  65. italcorr .9asc_height#*slant+.5hair#-1.5u#;
  66. adjust_fit(0,0); pickup fine.nib;
  67. x0=-u; y0=1.1h;
  68. numeric light_flare; light_flare=2/3[vair,flare];
  69. x1=w-2u-.5light_flare; y1=h-.5light_flare;
  70. numeric theta; theta=angle (z1-z0);
  71. pos1(light_flare,theta-90); pos2(.2[vair,light_flare],-90); pos3(vair,theta);
  72. x2=x3+u; y2=h;
  73. x4=x6=.5w+.5u; top y8r=x_height+oo; z4=z8;
  74. pos6(vair,-90); pos7(stem,-180); pos8(vair,-270);
  75. pos4(stem,angle(z4-z0)+90); pos5(stem,30);
  76. z3=.5[.5[z1,z4],z0];
  77. y5+.1x_height=y7=.5[y6,y8]; bot y6=-oo;
  78. lft x7r=hround(1.4u-.5stem); rt x5r=hround(w-u);
  79. filldraw stroke z1e{z0-z1e}....z2e....z3e{(z0-z1)rotated 90}
  80.  ...z4e{z4e-.8[z4,z0]}
  81.  ....z5e{down}...pulled_arc.e(6,7) & pulled_arc.e(7,8);  % hook and bowl
  82. filldraw z1r{z1r-z0}...z1l{z0-z1l}--cycle; % bulb
  83. math_fit(-.3x_height#*slant+.5curve#-u#,.7x_height#*slant-.5u#);
  84. penlabels(0,1,2,3,4,5,6,7,8); endchar;
  85.  
  86. cmchar "Lowercase Greek epsilon";
  87. beginchar(oct"017",8u#,x_height#,0);
  88. italcorr x_height#*slant+.5hair#-2u#;
  89. adjust_fit(0,0); pickup fine.nib;
  90. pos0(bar,90); pos1(bar,90); pos2(curve,180);
  91. pos3(vair,270); pos4(hair,300); pos6(bar,90); pos7(bar,90);
  92. x1=.5w+.5u; x0=x1+u; lft x2r=hround(1.5u-.5curve); x3=.5[x0,x1];
  93. x4r=good.x(w-u); x5=w+.5u; x6=x0; z7=z2l;
  94. top y0r=top y1r=h; y2=y5=y6=bar_height; bot y3r=-oo;
  95. path p; p=z3r{right}...{up}z5;
  96. numeric t; t=ypart(((x4r,y3r)--(x4r,y5))intersectiontimes p);
  97. y4r=ypart point t of p;
  98. filldraw circ_stroke z0e..pulled_arc.e(1,2) & pulled_arc.e(2,3)
  99.  ...z4e{direction t of p};  % arc
  100. filldraw circ_stroke z6e--z7e;  % bar
  101. math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
  102. penlabels(0,1,2,3,4,5,6,7); endchar;
  103.  
  104. cmchar "Lowercase Greek zeta";
  105. beginchar(oct"020",9u#,asc_height#,desc_depth#);
  106. italcorr .75[x_height#,asc_height#]*slant-1.5u#;
  107. adjust_fit(0,0); pickup fine.nib;
  108. pos0(hair,-360); pos1(vair,-270); pos2(hair,-180); pos3(vair,-90);
  109. numeric theta; theta=90-angle(25u,x_height); slope:=-x_height/25u;
  110. pos6(stem,theta); pos7(vair,-90); pos8(vair,-135);
  111. lft x0l=hround 3.5u; x1=x3=.5[x0,x2]; rt x2l=hround max(rt x0r,w-2u)+eps;
  112. top y0=h; top y3l=bot y1l+vstem+eps=vround(y0-.25(h-x_height)); y2=.5[y1,y3];
  113. if y1r>y3r: y1r:=y3r:=y2; fi
  114. lft x4l=hround u; x4r-x4l=(hround .6[vair,stem])-fine;
  115. x6+.5u=x7=w-2u; x8=.5w+.75u;
  116. y6=-.1d; y8=-3/4d-oo; bot y7r=-d-oo;
  117. ellipse_set(3l,4l,5l,6l); ellipse_set(3r,4r,5r,6r);
  118. y4l:=.9[y6,y4l]; y4=y4r:=.9[y6,y4r];
  119. filldraw circ_stroke z0e{down}...z1e{right}...{up}z2e;  % opening hook
  120. filldraw circ_stroke z8e{x7-x8,2(y7-y8)}...z7e{right}
  121.  ...z6e---z5e....{up}z4e
  122.  ..tension 1 and atleast1.5..{right}z3e...{down}z2e;  % main stroke
  123. math_fit(-.2asc_height#*slant-.5u#,0);
  124. penlabels(0,1,2,3,4,5,6,7,8); endchar;
  125.  
  126. cmchar "Lowercase Greek eta";
  127. beginchar(oct"021",9u#,x_height#,desc_depth#);
  128. italcorr .8x_height#*slant+.5stem#-u#;
  129. adjust_fit(0,0); pickup fine.nib;
  130. x0=0; x1=x2; pos2(stem,0); lft x2l=hround(2.5u-.5stem); y2-.5stem=-oo;
  131. hook_in(0,a,1);  % opening hook
  132. filldraw circ_stroke z2e--z1e;  % left stem
  133. x4+.5stem=hround(w-1.5u+.5stem); ital_arch(2,3,4);  % arch
  134. pos5(stem,0); x5=x4; y5-.5stem=-d-o;
  135. filldraw circ_stroke z5e--z4e;  % right stem
  136. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#-1/3x_height#*slant);
  137. penlabels(0,a,1,2,3,4,5); endchar;
  138.  
  139. cmchar "Lowercase Greek theta";
  140. beginchar(oct"022",8.25u#,asc_height#,0);
  141. italcorr .7asc_height#*slant+.5curve#-u#;
  142. adjust_fit(0,0); pickup fine.nib;
  143. pos1(vair,90); pos2(curve,180); pos3(vair,270); pos4(curve,360);
  144. x1=x3=.5w; lft x2r=hround(1.5u-.5curve); x4=w-x2;
  145. top y1r=h+oo; y2=y4=.5[y1,y3]; bot y3r=-oo;
  146. filldraw stroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
  147.  & pulled_arc.e(3,4) & pulled_arc.e(4,1);  % bowl
  148. pos2'(bar,90); pos4'(bar,90); z2'=z2l; z4'=z4l;
  149. filldraw stroke z2'e--z4'e;  % bar
  150. math_fit(-.3asc_height#*slant-u#+.5curve#,ic#-.5u#);
  151. penlabels(1,2,3,4); endchar;
  152.  
  153. cmchar "Lowercase Greek iota";
  154. beginchar(oct"023",5u#,x_height#,0);
  155. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  156. adjust_fit(if monospace: u#,u# else: 0,0 fi); pickup fine.nib;
  157. pos1(stem,0); lft x1l=hround(1.5u-.5stem); y1+.5stem=h+oo;
  158. x2=x1-.25u; x4=w; hook_out(2,3,4)(skewed);  % closing hook
  159. filldraw circ_stroke z1e{down}...{-u,-x_height}z2e;  % stem
  160. math_fit(0,ic#); penlabels(1,2,3,4); endchar;
  161.  
  162. cmchar "Lowercase Greek kappa";
  163. beginchar(oct"024",9u#,x_height#,0);
  164. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  165. adjust_fit(0,0); pickup fine.nib;
  166. pos1(stem,0); pos2(stem,0); pos3(vair,90); pos4(vair,90); pos5(flare,90);
  167. x1=x2=x3; lft x1l=hround(1.5u-.5stem); y1+.5stem=h+oo; y2-.5stem=-oo;
  168. filldraw z1l---z2l..z2r---z1r..cycle;  % stem
  169. y3=bar_height; top y4r=h; x4+.5flare=hround(w-1.5u); z5r=z4r;
  170. path p,q; p=z3l{right}..{right}z4l; q=z5r{right}..z5l{left}...cycle;
  171. numeric t; t=ypart(p intersectiontimes q);
  172. filldraw stroke z3e{right}..{right}z4e;  % upper diagonal
  173. filldraw subpath(0,t) of q--cycle;  % bulb
  174. pos7(stem,0); pos8(vair,90); pos9(hair,180);
  175. x9+.5hair=hround(w+.5hair-epsilon); y9=1/3x_height;
  176. lft x7l=hround(w-2.75u-.5stem); y7=1/2y3; x8=w-1.2u; bot y8l=-oo;
  177. filldraw stroke z3e{right}...z7e{down}
  178.  ...z8e{right}...{up}z9e;  % lower diagonal
  179. math_fit(0,ic#); penlabels(1,2,3,4,5,7,8,9); endchar;
  180.  
  181. cmchar "Lowercase Greek lambda";
  182. beginchar(oct"025",10.5u#,asc_height#,0);
  183. adjust_fit(0,0); pickup fine.nib;
  184. pos1(vair,90); lft x1=hround .1u; top y1r=h;
  185. x2=x1+2u; y2=.7[x_height,h]; x3=w-2u; bot y4=-oo; y3=max(.07h,y4+eps);
  186. z4-(.25u,0)=whatever[z2,z3]; numeric theta; theta=angle(z2-z3)-90;
  187. pos2(stem,theta); pos3(stem,theta); pos4(stem,0);
  188. filldraw circ_stroke z1e{right}...z2e---z3e
  189.  ...{2(x4e-x3e),y4e-y3e}z4e;  % long diagonal
  190. y5=.5[bar_height,x_height]; z5=whatever[z2,z3];
  191. x6=1.5u; y6-.5stem=-oo; pos5(hair,theta-90); pos6(stem,angle(z5-z6)-90);
  192. filldraw circ_stroke z6e--z5e; % short diagonal
  193. penlabels(1,2,3,4,5,6); endchar;
  194.  
  195. cmchar "Lowercase Greek mu";
  196. beginchar(oct"026",9u#,x_height#,desc_depth#);
  197. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  198. adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
  199. pos1(stem,-180); pos2(stem,-180); x1=x2=x3; lft x1r=hround(1.5u-.5stem);
  200. y1+.5stem=h+oo; y2-.5stem=-d-o;
  201. filldraw z1r---z2r..z2l---z1l..cycle;  % left stem
  202. pos3(stem,-180); pos4(vair,-90); pos5(hair,0); x4=.5[x3,x5];
  203. pos6(stem,0); rt x6r=hround(w-2.5u+.5stem);
  204. x5=x6=x7; x9=w; hook_out(7,8,9);  % closing hook
  205. y3=.7[y4,y5]; bot y4r=-oo; y5=.57h; y6+.5stem=h;
  206. filldraw stroke super_arc.e(3,4)...{up}z5e; % left stem and arc
  207. filldraw circ_stroke z6e--z7e;  % right stem
  208. math_fit(desc_depth#*slant+.5stem#-u#,ic#);
  209. penlabels(1,2,3,4,5,6,7,8,9); endchar;
  210.  
  211. cmchar "Lowercase Greek nu";
  212. beginchar(oct"027",8.5u#,x_height#,0);
  213. italcorr x_height#*slant+.5stem#-u#;
  214. adjust_fit(0,0); pickup fine.nib;
  215. pos3(vair,-90); pos4(stem,0); bot y3r=0; y4+.5stem=h+oo;
  216. x3-.5stem=hround(1.5u-.5stem); x4+.5stem=hround(w-1.5u+.5stem);
  217. filldraw circ_stroke z4e{down}...{-36u,-h}z3e;  % diagonal
  218. pickup tiny.nib; pos1(stem,0); pos2(stem,0);
  219. top y1=h+min(oo,serif_drop); bot y2=0; x1=x2=x3;
  220. z=((z4{down}...{-36u,-h}z3)intersectionpoint((x2r,0)--(x2r,h)));
  221. filldraw z1l--z2l--z--z1r--cycle;  % stem
  222. sloped_serif.l(1,2,a,1/3,jut,serif_drop); % upper left serif
  223. math_fit(0,ic#-1/3x_height#*slant-.5u#); penlabels(1,2,3,4); endchar;
  224.  
  225. cmchar "Lowercase Greek xi";
  226. beginchar(oct"030",9u#,asc_height#,desc_depth#);
  227. italcorr .75[x_height#,asc_height#]*slant-2u#;
  228. adjust_fit(0,0); pickup fine.nib;
  229. pos10(hair,-720); pos11(vair,-630); pos12(hair,-540); pos13(vair,-450);
  230. lft x10l=hround 1/3w; x11=x13=.5[x10,x12]; rt x12l=hround(w-2.5u);
  231. top y10=h; top y13l=bot y11l+vstem+eps=vround(y10-.25(h-x_height));
  232. y12=.5[y11,y13]; if y11r>y13r: y11r:=y13r:=y12; fi
  233. pos0(curve,-360); pos1(vair,-270); pos2(hair,-180); pos3(vair,-90);
  234. numeric theta; theta=90-angle(22u,x_height); slope:=-x_height/22u;
  235. pos6(stem,theta); pos7(vair,-90); pos8(vair,-135);
  236. lft x0l=hround u; x1=x3=x11; x2=x12;
  237. y0=.5[y13,y1]; top y3l=vround .5h=bot y1l+vstem+eps; y2=.5[y1,y3];
  238. if y1r>y3r: y1r:=y3r:=y2; fi
  239. lft x4l=hround u; x4r-x4l=hround .5[vair,stem]-fine;
  240. x6=x7=w-2u; x8=.5w+.5u; y6=-.3d; bot y7r=-d-oo; y8=max(-3/4d-oo,y7l);
  241. ellipse_set(3l,4l,5l,6l); ellipse_set(3r,4r,5r,6r);
  242. y4l:=.9[y6,y4l]; y4=y4r:=.9[y6,y4r];
  243. filldraw circ_stroke z10e{down}...z11e{right}...{up}z12e;  % opening hook
  244. filldraw stroke z12e{up}...z13e{left}...z0e{down}
  245.  ...z1e{right}...{up}z2e;  % upper arc
  246. filldraw circ_stroke z8e{x7-x8,2(y7-y8)}...z7e{right}...z6e
  247.  ---z5e...{up}z4e...{right}z3e...{down}z2e;  % main stroke
  248. math_fit(-.2asc_height#*slant-.5u#,0);
  249. penlabels(0,1,2,3,4,5,6,7,8,10,11,12,13); endchar;
  250.  
  251. cmchar "Lowercase Greek pi";
  252. beginchar(oct"031",10u#,x_height#,0);
  253. italcorr x_height#*slant+.5stem#-u#;
  254. adjust_fit(0,0); pi_stroke; % hook and bar
  255. pos4(hair,0); pos6(hair,0); x4=3.5u; x6=w-4u; y4=y6=y2;
  256. x5=3u; x7=w-2.5u; y5=y7=.5stem-oo;
  257. pair v[]; v1=(z4-z5) xscaled 3.14159; v2=(z6-z7) xscaled 3.14159;
  258. pos5(stem,angle v1-90); pos7(stem,angle v2-90);
  259. filldraw circ_stroke z5e{v1}...{up}z4e;  % left stem
  260. filldraw circ_stroke z7e{v2}...{up}z6e;  % right stem
  261. math_fit(-.7x_height#*slant+.5hair#+.5u#,ic#-1/3x_height#*slant);
  262. penlabels(1,2,3,4,5,6,7); endchar;
  263.  
  264. cmchar "Lowercase Greek rho";
  265. beginchar(oct"032",8.25u#,x_height#,desc_depth#);
  266. italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
  267. adjust_fit(0,0); pickup fine.nib;
  268. pos1(stem,180); pos2(stem,180); pos3(vair,90);
  269. pos4(curve,0); pos5(vair,-90); pos6(hair,-180);
  270. lft x2r=hround(1.5u-.5stem); x1=x2=x6; x3=x5=.5[x2,x4];
  271. rt x4r=hround(w-1.5u+.5curve);
  272. y1-.5stem=-d-o; y2=y4=y6=.5[y3,y5]; top y3r=h+oo; bot y5r=-oo;
  273. filldraw circ_stroke z1e..pulled_arc.e(2,3) & pulled_arc.e(3,4)
  274.  & pulled_arc.e(4,5) & pulled_arc.e(5,6);  % stem and bowl
  275. math_fit(desc_depth#*slant+.5stem#-u#,ic#);
  276. penlabels(1,2,3,4,5,6); endchar;
  277.  
  278. cmchar "Lowercase Greek sigma";
  279. beginchar(oct"033",10.25u#,x_height#,0);
  280. italcorr x_height#*slant+.5stem#-u#;
  281. adjust_fit(0,0); pickup fine.nib;
  282. pos1(vstem,90); pos2(stem,0); pos3(vair,-90);
  283. pos4(stem,-180); pos5(vstem,-270); pos6(vstem,-270);
  284. x1=x3=x5=.5[x2,x4]; rt x2r=hround(w-2.5u);
  285. lft x4r=hround(1.5u-.5curve);x6=w-1.5u;
  286. top y1r=h; y2=y4=.5[y1,y3]; bot y3r=-oo; y5=y6=y1;
  287. filldraw circ_stroke z6e..pulled_arc.e(5,4) & pulled_arc.e(4,3)
  288.  & pulled_arc.e(3,2) & pulled_arc.e(2,1);  % ear and bowl
  289. math_fit(-.3x_height#*slant+.5curve#-u#,ic#-1/3x_height#*slant);
  290. penlabels(1,2,3,4,5,6); endchar;
  291.  
  292. cmchar "Lowercase Greek tau";
  293. beginchar(oct"034",9u#,x_height#,0);
  294. italcorr x_height#*slant+.5stem#-u#;
  295. adjust_fit(0,0); pi_stroke; % hook and bar
  296. pos4(hair,0); pos5(stem,0);
  297. x4=x5; x5-.5stem=hround(.5w-.5u-.5stem); y4=y2; y5-.5stem=-oo;
  298. filldraw circ_stroke z5e--z4e;  % stem
  299. math_fit(-.7x_height#*slant+.5hair#+.5u#,-.5u#);
  300. penlabels(1,2,3,4,5); endchar;
  301.  
  302. cmchar "Lowercase Greek upsilon";
  303. beginchar(oct"035",9u#,x_height#,0);
  304. italcorr x_height#*slant;
  305. adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
  306. x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
  307. hook_in(0,1,2)(skewed);  % opening hook
  308. pos2'(stem,-180); z2'=z2; pos4(vair,-90); pos5(hair,0);
  309. x4=.5w+u; rt x5r=hround(w-.5u); y3=.7[y4,y5]; bot y4r=-oo; y5=.57h;
  310. filldraw stroke z2'e{-u,-x_height}...super_arc.e(3,4)
  311.  ..tension atleast 1.05..{up}z5e; % left stem and arc
  312. v_bulb(5,6);  % closing bulb
  313. math_fit(-2/3x_height#*slant+.5hair#+.5u#,2/3ic#);
  314. penlabels(0,1,2,3,4,5,6); endchar;
  315.  
  316. cmchar "Lowercase Greek phi";
  317. beginchar(oct"036",11u#,asc_height#,desc_depth#);
  318. italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
  319. adjust_fit(0,0); pickup fine.nib;
  320. numeric light_curve; light_curve=hround(.5[stem,curve]-2stem_corr);
  321. pos1(vair,90); pos2(light_curve,180); pos3(vair,270); pos4(light_curve,360);
  322. x1=x3=.5w; lft x2r=hround(1.5u-.5light_curve); x4=w-x2;
  323. top y1=x_height+oo; y2=y4=.5[y1,y3]; bot y3=-oo;
  324. filldraw stroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
  325.  & pulled_arc.e(3,4) & pulled_arc.e(4,1); % bowl
  326. pos5(hair,0); pos6(hair,0); x5=x6=.5w; top y5=h; bot y6=-d-oo;
  327. filldraw stroke z5e--z6e;  % stem
  328. math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
  329. penlabels(1,2,3,4,5,6); endchar;
  330.  
  331. cmchar "Lowercase Greek chi";
  332. beginchar(oct"037",11u#,x_height#,desc_depth#);
  333. italcorr x_height#*slant+.5hair#-1.5u#;
  334. adjust_fit(0,0); pickup fine.nib;
  335. pos1(hair,180); pos2(vair,80); pos5(vair,80); pos6(hair,180);
  336. x1-.5hair=hround-.5hair; x6=w-x1; x2=w-x5=u;
  337. y1=y2l-h/8; top y2r=h+oo; bot y5l=-d-oo; y6=y5r+h/8;
  338. z0=.5[z2,z5]; z2'=z2l+(.5u,0); z5'=z5r-(.5u,0);
  339. numeric theta; theta=angle(z5'-z2')+90;
  340. pos3(stem,theta); pos4(stem,theta);
  341. y3r=y2r-h/8; y4l=y5l+h/8; z3l=whatever[z2',z0]; z4r=whatever[z0,z5'];
  342. filldraw stroke z1e{up}...z2e{right}...z3e{z4r-z3l}
  343.  ..z4e{z4r-z3l}...{right}z5e...{up}z6e;  % major diagonal and hooks
  344. x8=w-x7=2u; y7+.5hair=h; y8-.5hair=-d;
  345. numeric theta; theta=angle(z7-z8)-90;
  346. pos7(hair,theta); pos8(hair,theta);
  347. filldraw z7l---z8l..z8r---z7r..cycle;  % minor diagonal
  348. math_fit((desc_depth#-x_height#)*slant+ic#,ic#);
  349. penlabels(0,1,2,2',3,4,5',5,6,7,8); endchar;
  350.  
  351. cmchar "Lowercase Greek psi";
  352. beginchar(oct"040",11u#,asc_height#,desc_depth#);
  353. italcorr x_height#*slant;
  354. adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
  355. x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
  356. hook_in(0,1,2)(skewed);  % opening hook
  357. pos2'(stem,-180); z2'=z2; pos4(vair,-90); pos5(hair,0);
  358. x4=.5w+u; rt x5r=hround(w-.5u);
  359. y3=.7[y4,y5]; bot y4r=-oo; y5=.57x_height;
  360. filldraw stroke z2'e{-u,-x_height}...super_arc.e(3,4)
  361.  ..tension atleast 1.05..{up}z5e; % left stem and arc
  362. v_bulb(5,6);  % closing bulb
  363. pos7(hair,0); pos8(hair,0); x7=x8=.5w+.5u; top y7=h; bot y8=-d-oo;
  364. filldraw stroke z7e--z8e;  % stem
  365. math_fit(-2/3x_height#*slant+.5hair#+.5u#,2/3ic#);
  366. penlabels(0,1,2,3,4,5,6,7,8); endchar;
  367.  
  368. cmchar "Lowercase Greek omega";
  369. beginchar(oct"041",11u#,x_height#,0);
  370. italcorr x_height#*slant;
  371. adjust_fit(0,0); pickup fine.nib;
  372. pos2(hair,-180); lft x2r=hround.5u; y2=y4=y6=y8=bar_height;
  373. y1+.5hair=h; x1=x2+.75u; pos1(hair,angle(2(x1-x2),y1-y2)+90);
  374. pos3(vstem+dw,-90); pos4(hair,0); pos5(vair,90);
  375. pos6(hair,180); pos7(vstem+dw,270); pos8(hair,360);
  376. bot y3r=bot y7r=-oo; top y5r=vround(.2[y4,h]+.5vair);
  377. x3=.5[x2,x4]; x7+.25u=.5[x6,x8]; rt x8r=hround(w-.5u);
  378. x5+.5stem=hround(.5w+.5stem)+eps;
  379. x5=.5[x4,x6]; rt x4r-lft x6r=min(stem,2hair)+2eps;
  380. if x4l<x6l: x4l:=x6l:=x5; fi
  381. filldraw circ_stroke z1e{2(x2-x1),y2-y1}...z2e{down}...z3e{right}
  382.  ...{up}z4e...{left}z5e;  % left arc
  383. filldraw stroke z5e{left}...z6e{down}...z7e{right}...{up}z8e;  % right arc
  384. v_bulb(8,9);  % closing bulb
  385. math_fit(-bar_height#*slant,2/3ic#); penlabels(1,2,3,4,5,6,7,8,9); endchar;
  386.  
  387. cmchar "Variant lowercase Greek epsilon";
  388. beginchar(oct"042",8u#,x_height#,0);
  389. italcorr x_height#*slant-.5u#;
  390. adjust_fit(0,0); pickup fine.nib;
  391. numeric light_vstem; light_vstem=Vround 2/3[vair,vstem];
  392. pos2(light_vstem,90); x2=x8=.5w+.5u; top y2r=h+o;
  393. x1+.5light_vstem=hround(w-u); y1=.2[y2,bar_height];
  394. pos1(light_vstem,angle(x1-x2,2(y1-y2))+90); pos3(hair,180); pos4(vair,270);
  395. pos5(hair,360); pos6(vair,450); pos7(hair,540); pos8(light_vstem,630);
  396. lft x3r=hround u; x4=x6=.5w; rt x5r=hround(w-2.5u); x7=x3;
  397. y3=.5[y2,y4]; y5=bar_height=.5[y4,y6]; y7=.5[y6,y8]; bot y8r=-o;
  398. top y6r-bot y4r=vstem+eps; if y6l<y4l: y6l:=y4l:=y5; fi
  399. x9+.5vair=hround(w-.5u); y9=1/3[y8,bar_height];
  400. pos9(vair,angle(x8-x9,2(y8-y9))+90);
  401. filldraw circ_stroke z1e{x2-x1,2(y2-y1)}...pulled_super_arc.e(2,3)(.5superpull)
  402.  & super_arc.e(3,4)...{up}z5e;  % upper arc
  403. filldraw circ_stroke z9e{x8-x9,8(y8-y9)}...pulled_arc.e(8,7)
  404.  & super_arc.e(7,6)...{down}z5e;  % lower arc
  405. math_fit(-.5bar_height#*slant-.5u#,ic#);
  406. penlabels(1,2,3,4,5,6,7,8,9); endchar;
  407.  
  408. cmchar "Variant lowercase Greek theta";
  409. beginchar(oct"043",9u#,asc_height#,0);
  410. italcorr .5[bar_height#,x_height#]*slant+.5vair#+.5u#;
  411. adjust_fit(0,0); pickup fine.nib;
  412. numeric light_curve; light_curve=hround .5[stem,curve];
  413. x0=0; x2-.5stem=hround(2.5u-.5stem); hook_in(0,1,2);  % opening hook
  414. pos2'(stem,-180); z2'=z2; pos3(stem,-180); pos4(vair,-90);
  415. pos5(light_curve,0); pos6(vair,90); pos7(hair,180); pos8(vair,270);
  416. x3=x2; x4=x6=.5[x3,x5]; rt x5r=hround(w-1.5u+.5light_curve);
  417. lft x7r=hround(3.25u-.5hair); x8+.5vair=hround(w+.5vair-epsilon);
  418. y3=.4x_height; bot y4r=-oo; y5=.5[y4,y6]; top y6r=h+oo;
  419. y7=.5[x_height,h]; y8=.5[bar_height,x_height];
  420. filldraw stroke z2'e..{{interim superness:=hein_super; super_arc.e(3,4)}}
  421.  & pulled_arc.e(4,5) & pulled_arc.e(5,6)
  422.  ...{down}z7e...{4(x8-x7),y8-y7}z8e;  % bowl and loop
  423. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
  424. penlabels(0,a,1,2,3,4,5,6,7,8); endchar;
  425.  
  426. cmchar "Variant lowercase Greek pi";
  427. beginchar(oct"044",14.5u#,x_height#,0);
  428. italcorr x_height#*slant+.5stem#-u#;
  429. adjust_fit(0,0); pi_stroke; % hook and bar
  430. pos4(hair,-180); pos5(hair,-180); pos6(vstem,-90);
  431. pos7(hair,0); pos7'(hair,-180); z7'=z7;
  432. pos8(vstem,-90); pos9(hair,0); pos0(hair,0);
  433. x4=x5+1.5u; lft x5r=hround 2u; x6=x4+.5u; lft x7l=hround(.5w+.25u-.5hair);
  434. x8=w-4.5u; rt x9r=hround(w-1.5u); x0=x9-1.25u;
  435. top y4=top y0=h; y5+.1h=y7-.1h=y9=bar_height; bot y6r=bot y8r=-oo;
  436. filldraw stroke z4e{2(x5-x4),y5-y4}...z5e{down}
  437.  ...z6e{right}...z7e{up};  % left bowl
  438. filldraw stroke z0e{2(x9-x0),y9-y0}...z9e{down}
  439.  ...z8e{left}...z7'e{up};  % right bowl
  440. math_fit(-.7x_height#*slant+.5hair#+.5u#,ic#-.5u#);
  441. penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  442.  
  443. cmchar "Variant lowercase Greek rho";
  444. beginchar(oct"045",8.25u#,x_height#,desc_depth#);
  445. italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
  446. adjust_fit(0,0); pickup fine.nib;
  447. pos2(stem,180); pos3(vair,90); pos4(curve,0); pos5(vair,-90); pos6(stem,-180);
  448. lft x2r=hround(1.5u-.5stem); x2=x6; x3=x5=.5[x2,x4];
  449. rt x4r=hround(w-1.5u+.5curve);
  450. y2=y4=y6=.5[y3,y5]; top y3r=h+oo; bot y5r=-oo;
  451. filldraw circ_stroke pulled_arc.e(2,3) & pulled_arc.e(3,4)
  452.  & pulled_arc.e(4,5) & pulled_arc.e(5,6);  % bowl
  453. pos2'(hair,-180); z2'r=z2r; pos1(vstem,-90); pos1'(vstem,90); z1'=z1;
  454. pos0(hair,0); rt x0r=hround(w-u); bot y0=-d; bot y1r=vround-.9d; x1=x5;
  455. interim superness:=sqrt superness;
  456. filldraw stroke pulled_arc.e(0,1'); filldraw stroke pulled_arc.e(1,2'); % tail
  457. math_fit(desc_depth#*slant+.5stem#-u#,ic#);
  458. penlabels(0,1,2,3,4,5,6); endchar;
  459.  
  460. cmchar "Variant lowercase Greek sigma";
  461. beginchar(oct"046",8u#,x_height#,.5min(desc_depth#,.5x_height#));
  462. italcorr x_height#*slant-.5u#;
  463. adjust_fit(0,0); pickup fine.nib;
  464. numeric heavy_vair; heavy_vair=.25[vair,vstem];
  465. pos1(heavy_vair,-110); pos2(vair,-90);
  466. x1+.5heavy_vair=hround(w-u); y1=.1[y2r,bar_height];
  467. x2=min(.5w+u,x1r-eps); top y2l=h+oo;
  468. filldraw circ_stroke z1e{x2-x1,2(y2-y1)}...{left}z2e;  % upper bulb
  469. numeric theta; theta=90-angle(16u,x_height); slope:=-x_height/16u;
  470. pos6(stem,theta); pos7(vair,-90); pos8(vair,-135);
  471. lft x4l=hround u; x4r-x4l=(hround .5[vair,stem])-fine;
  472. x6=x7=w-2u; x8=.5w+u; y6=.25[y8,y2]; y8=y7+1/8d; bot y7r=-d-oo;
  473. ellipse_set(2l,4l,5l,6l); ellipse_set(2r,4r,5r,6r); y4=y4r;
  474. filldraw circ_stroke z8e{x7-x8,2(y7-y8)}...z7e{right}...z6e
  475.  ---z5e...{up}z4e...{right}z2e;  % main stroke
  476. math_fit(-.5x_height#*slant-.5u#,0); penlabels(1,2,4,5,6,7,8); endchar;
  477.  
  478. cmchar "Variant lowercase Greek phi";
  479. beginchar(oct"047",11u#,x_height#,desc_depth#);
  480. italcorr .7x_height#*slant;
  481. adjust_fit(0,0); pickup fine.nib;
  482. pos1(hair,-180); x1=x2+.75u; top y1=h;
  483. pos2(hair,-180); lft x2r=hround .5u; y2=bar_height;
  484. pos3(vstem,-90); x3=.5(w+u); bot y3r=-oo;
  485. pos4(hair,0); rt x4r=hround(w-.5u); y4=y2;
  486. pos5(vstem,90); x5=.52[x6,x4]; top y5r=h+oo;
  487. pos6(hair,180); x6=x7; y6=1/3h;
  488. pos7(stem,180); lft x7r=hround(.5w-.5u-.5stem); y7-.5stem=-d-o;
  489. filldraw circ_stroke z7e---z6e...{right}z5e...{down}z4e...{left}z3e
  490.  ...{up}z2e...{3(x1-x2),y1-y2}z1e;  % bowl and stem
  491. math_fit(-.3x_height#*slant,ic#); penlabels(1,2,3,4,5,6,7); endchar;
  492.