home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD1.mdf / pascal / library / dos / teseract / source / tsint28.asm < prev    next >
Encoding:
Assembly Source File  |  1988-10-02  |  7.3 KB  |  262 lines
  1. IFNDEF TP4
  2.         PAGE 60,132
  3. ;----------------------------------------------------------------------------
  4. SUBTTL  TesSeRact Revision Level 1
  5. ;-----------------------------------------------------------------------------
  6. ;   TesSeRact(tm) -- A Library of Routines for Creating Ram-Resident (TSR)
  7. ;                    programs for the IBM PC and compatible Personal
  8. ;                    Computers.
  9. ;
  10. ;The software, documentation and source code are: 
  11. ; 
  12. ;       Copyright (C) 1986, 1987, 1988 Tesseract Development Team
  13. ;       All Rights Reserved 
  14. ; 
  15. ;       c/o Chip Rabinowitz
  16. ;       Innovative Data Concepts
  17. ;       2084 Woodlawn Avenue
  18. ;       Glenside, PA 19038
  19. ;       1-215-884-3373
  20. ;
  21. ;-----------------------------------------------------------------------------
  22. ;   This product supports the TesSeRact Standard for Ram-Resident Program 
  23. ;   Communication.  For information about TesSeRact, contact the TesSeRact 
  24. ;   Development Team at:
  25. ;       Compuserve:    70731,20
  26. ;       MCIMAIL:       315-5415
  27. ;   This MCIMAIL Account has been provided to the TesSeRact Development
  28. ;   Team by Borland International, Inc.  The TesSeRact Development Team
  29. ;   is in no way associated with Borland International, Inc.
  30. ;-----------------------------------------------------------------------------
  31.  
  32. INCLUDE TESS.INC
  33. IFDEF   ALLPUBLIC
  34. INCLUDE tsint28.pub     ;public definitions (uses Periscope PUBLIC.COM /E)
  35. ENDIF
  36.  
  37. .MODEL small
  38.  
  39. EXTRN TSRBACKCHECK:FAR
  40.  
  41. .CODE
  42.  
  43. EXTRN _TESSDOPOPUP:near
  44.  
  45. EXTRN _TESSDOBACK:near
  46. EXTRN TESSBEEP:FAR
  47.  
  48. EXTRN TESS_GLOBALS:byte
  49. EXTRN TESS_USERPARMS:byte
  50.  
  51. PUBLIC newint28, _TESSBACKGROUND
  52.  
  53. ENDIF
  54.  
  55. wait28  db      8
  56.  
  57. ; --------------------------------------------------------------------;
  58. ;       Interrupt 28  DOS idle interrupt                              ;
  59. ; --------------------------------------------------------------------;
  60.  
  61. _TESSBACKGROUND proc near
  62.  
  63.         ASSUMEDS
  64.  
  65.         mov     ax,WPTR [STATUS]        ;get TSR status flags
  66.         test    ax,BACKSET              ;do we have a routine?
  67.         jz      done_background         ;nope -- do next one
  68.  
  69.         test    ax,INT28ACTIVE          ;are we already running?
  70.         jz      chkdos_28_1
  71.         jmp     done_background
  72. chkdos_28_1:
  73.  
  74.         cld
  75.         push    ds                      ;check if dos critical error in effect
  76.         push    si
  77.         lds     si,DPTR [DOSCRITERR]    ;zero says dos is interruptable
  78.         ASSUMENODS
  79.         lodsb                           ;$ff  says dos is in a critical state
  80.         or      al,BPTR [INTFLAGS]      ;any flags says we're busy
  81.                                         ;NOTE:  Indos flag is always set here!
  82.                                         ; just check to make sure it is *only*
  83.                                         ; set to '1'
  84.         mov     ah,al                   ;save it away
  85.         lds     si,DPTR [INDOSFLAG]
  86.         lodsb
  87.  
  88.         mov     BPTR [SAVEDINDOSFLG],al
  89.         and     al,0FEh                 ;mask off first bit
  90.         or      al,ah
  91.  
  92.         pop     si
  93.         pop     ds
  94.         ASSUMEDS
  95.         jnz     done_background         ;we're busy-EXIT & try again next time
  96.  
  97.         or      WPTR [STATUS],INT28ACTIVE       ;set active bit
  98.  
  99.         push    ds
  100.         push    es
  101.  
  102.         mov     ax,WPTR [OURDSEG]
  103.         push    ax
  104.         push    ax
  105.         pop     es
  106.         pop     ds
  107.  
  108.         ASSUMENODS
  109.  
  110. IFDEF   TP4
  111. IFNDEF ASMCOM
  112.         call    DPTR PBACKCHECK         ; call users INT28 routine (TP4 ver)
  113. ELSE
  114.         call    TSRBACKCHECK            ; call users INT28 routine
  115. ENDIF
  116. ELSE
  117.         call    TSRBACKCHECK            ; call users INT28 routine
  118. ENDIF
  119.         pop     es
  120.         pop     ds
  121.  
  122.         ASSUMEDS
  123.  
  124.         or      ax,ax
  125.         jz      again_28
  126.  
  127.         call    _TESSDOBACK
  128.  
  129. again_28:
  130.         and     WPTR [STATUS],NOT INT28ACTIVE   ;set active bit
  131.         mov     BPTR [SAVEDINDOSFLG],0
  132.     xor    ax,ax
  133.     jmp    done_b2
  134.  
  135. done_background:
  136.     mov    ax,-1
  137. done_b2:
  138.     ret
  139. _TESSBACKGROUND endp
  140.  
  141.  
  142. newint28 proc far
  143.  
  144.         push    ds
  145.         push    cs
  146.         pop     ds
  147.  
  148.         ASSUMEDS
  149.  
  150.         pushf
  151.         test    WPTR [STATUS],TSRRELEASED
  152.         jnz     tfl_28
  153.  
  154.         test    WPTR [STATUS],TSRENABLED
  155.         jz      do_old28
  156.  
  157. tfl_28:
  158.         test    BPTR [SOFTINTFLAGS],ININT28     ;See if recursion has taken place
  159.         jz      start_new_int28         ;If not continue with new int 28
  160.  
  161. do_old28:
  162.         POPFF
  163.         pop     ds
  164.         ASSUMENODS
  165.         jmp     DPTR [OLDINT28]
  166.  
  167. start_new_int28:
  168.  
  169.         ASSUMEDS
  170.         POPFF
  171.  
  172.         pushf                           ;simulate interrupt ...
  173.         cli
  174.         call DPTR [OLDINT28]            ;do the original
  175.         sti
  176.  
  177.         or      BPTR [SOFTINTFLAGS],ININT28 ;Say INT 28 is active
  178.  
  179.         push    dx
  180.         push    cx                      ;save regs
  181.         push    bx
  182.         push    ax
  183.  
  184.  
  185.     call    _TESSBACKGROUND
  186.  
  187. test_28:
  188.         mov     ax,WPTR [STATUS]        ;get TSR status flags
  189.  
  190.         test    ax,INT28ACTIVE          ;are we already running?
  191.         jnz     again_28_2
  192.         test    ax,POPUPSET             ;ax holds status flags
  193.         jz      again_28_2
  194.         test    ax,HOTKEYON             ;is hot-key flag set?
  195.         jz      again_28_2
  196.         test    ax,TSRACTIVE            ;are we already running?
  197.         jnz     again_28_2              ;yep -- next one
  198.  
  199. chkdos_28:
  200.         cld
  201.         push    ds                      ;check if dos critical error in effect
  202.         push    si
  203.         lds     si,DPTR [DOSCRITERR]    ;zero says dos is interruptable
  204.         ASSUMENODS
  205.         lodsb                           ;$ff  says dos is in a critical state
  206.         or      al,BPTR [INTFLAGS]      ;any flags says we're busy
  207.                                         ;NOTE:  Indos flag is always set here!
  208.                                         ; just check to make sure it is *only*
  209.                                         ; set to '1'
  210.         mov     ah,al                   ;save it away
  211.         lds     si,DPTR [INDOSFLAG]
  212.         lodsb
  213.  
  214.         mov     BPTR [SAVEDINDOSFLG],al
  215.         and     al,0FEh                 ;mask off first bit
  216.         or      al,ah
  217.  
  218.         pop     si
  219.         pop     ds
  220.         ASSUMEDS
  221.         jnz     end_28                  ;we're busy-EXIT & try again next time
  222.  
  223.         and     BPTR [SOFTINTFLAGS],NOT ININT28 ;pretend we're out of INT28
  224.         call    _TESSDOPOPUP            ;... call the popup stuff
  225.         mov     BPTR [SAVEDINDOSFLG],0
  226. reset_28:
  227.         mov     wait28,8
  228.         jmp     short again_28_2
  229. end_28:
  230.         dec     wait28
  231.         jnz     again_28_2
  232.  
  233.         test    WPTR [STATUS],TSRRELEASED
  234.         jnz     reset_28
  235.         and     WPTR [STATUS],NOT HOTKEYON
  236. IFDEF TP4
  237. IFNDEF ASMCOM
  238.         call    FAR PTR TESSBEEP
  239. ELSE
  240.         call    TESSBEEP
  241. ENDIF
  242. ELSE
  243.         call    TESSBEEP
  244. ENDIF
  245.         jmp     short reset_28
  246.  
  247. again_28_2:
  248.         and     BPTR [SOFTINTFLAGS],NOT ININT28 ;tell we're out of INT28
  249.         mov     BPTR [WAITCOUNT],0              ;clear waiting count and ...
  250.  
  251.         pop     ax                      ;get back registers
  252.         pop     bx
  253.         pop     cx
  254.         pop     dx
  255. exit_28:
  256.         pop     ds
  257.         iret
  258.  
  259. newint28 endp
  260.  
  261. ENDIT
  262.