home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD1.mdf / pascal / library / dos / teseract / source / tsint24.asm < prev    next >
Encoding:
Assembly Source File  |  1988-10-02  |  3.3 KB  |  116 lines
  1. IFNDEF TP4
  2.         PAGE 60,132
  3. ;----------------------------------------------------------------------------
  4. SUBTTL  TesSeRact Revision Level 1
  5. ;-----------------------------------------------------------------------------
  6. ;   TesSeRact(tm) -- A Library of Routines for Creating Ram-Resident (TSR)
  7. ;                    programs for the IBM PC and compatible Personal
  8. ;                    Computers.
  9. ;
  10. ;The software, documentation and source code are: 
  11. ; 
  12. ;       Copyright (C) 1986, 1987, 1988 Tesseract Development Team
  13. ;       All Rights Reserved 
  14. ; 
  15. ;       c/o Chip Rabinowitz
  16. ;       Innovative Data Concepts
  17. ;       2084 Woodlawn Avenue
  18. ;       Glenside, PA 19038
  19. ;       1-215-884-3373
  20. ;
  21. ;-----------------------------------------------------------------------------
  22. ;   This product supports the TesSeRact Standard for Ram-Resident Program 
  23. ;   Communication.  For information about TesSeRact, contact the TesSeRact 
  24. ;   Development Team at:
  25. ;       Compuserve:    70731,20
  26. ;       MCIMAIL:       315-5415
  27. ;   This MCIMAIL Account has been provided to the TesSeRact Development
  28. ;   Team by Borland International, Inc.  The TesSeRact Development Team
  29. ;   is in no way associated with Borland International, Inc.
  30. ;-----------------------------------------------------------------------------
  31.  
  32. INCLUDE TESS.INC
  33. IFDEF   ALLPUBLIC
  34. INCLUDE tsint24.pub
  35. ENDIF
  36.  
  37. .MODEL small
  38.  
  39. .CODE
  40.  
  41. EXTRN TESS_GLOBALS:byte
  42. EXTRN TESS_USERPARMS:byte
  43.  
  44. PUBLIC newint24, _TESS_ERROR24
  45.  
  46. ENDIF
  47.  
  48. ;---------------------------------------------------------------------;
  49. ;       I N T E R R U P T   2 4      -  Critical Error  -             ;
  50. ;---------------------------------------------------------------------;
  51. _TESS_ERROR24 dw        0
  52.  
  53. newint24 proc far
  54.         ASSUMENODS
  55.  
  56.         pushf
  57.         test    WPTR [STATUS],EXTRAINT24
  58.         jz      our24                   ;call user's INT 24 instead!
  59.  
  60.         POPFF
  61.         jmp     DPTR [USERINT24]
  62.  
  63. our24:
  64.         cmp     BPTR [DOSVERSION],3
  65.         jae     use_dos3
  66.  
  67.         POPFF                           ;for DOS 2.x only!
  68.  
  69.         add     sp,6                    ;discard DOS stack info
  70.         mov     _TESS_ERROR24,di        ;save the error
  71.  
  72.         les     di,DPTR [DOSCRITERR]    ;reset crit error flag
  73.         xor     al,al
  74.         stosb                           ;back to zero
  75.  
  76.         sti
  77.  
  78.         pop     ax
  79.         pop     bx
  80.         pop     cx
  81.         pop     dx
  82.         pop     si
  83.         pop     di
  84.         pop     bp
  85.         pop     ds
  86.         pop     es
  87.  
  88.         push    ax
  89.         push    dx
  90.         mov     ax,3300h                ;get ^C status is called
  91.         int     21h                     ;  to clear out DOS and fixup
  92.                                         ;future INT 21h calls
  93.  
  94.         pop     dx
  95.         pop     ax
  96.                                         ;now we have the caller's
  97.                                         ;CS,IP and Flags on the stack
  98.         mov     ax,_TESS_ERROR24        ;save error value
  99.         add     ax,19                   ;conform to DOS 3.+ error codes
  100.  
  101.         push    bp
  102.         mov     bp,sp
  103.  
  104.         or      WPTR [bp+6],01h ;set carry flag (01h) ...
  105.                                         ;    on stack
  106.         pop     bp
  107.         iret
  108.  
  109. use_dos3:
  110.         POPFF
  111.         mov     al,3
  112.         iret
  113. newint24 endp
  114.  
  115. ENDIT
  116.