home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD1.mdf / pascal / library / dos / teseract / source / tsint1c.asm < prev    next >
Encoding:
Assembly Source File  |  1988-10-02  |  3.5 KB  |  138 lines
  1. IFNDEF TP4
  2.         PAGE 60,132
  3. ;----------------------------------------------------------------------------
  4. SUBTTL  TesSeRact Revision Level 1
  5. ;-----------------------------------------------------------------------------
  6. ;   TesSeRact(tm) -- A Library of Routines for Creating Ram-Resident (TSR)
  7. ;                    programs for the IBM PC and compatible Personal
  8. ;                    Computers.
  9. ;
  10. ;The software, documentation and source code are: 
  11. ; 
  12. ;       Copyright (C) 1986, 1987, 1988 Tesseract Development Team
  13. ;       All Rights Reserved 
  14. ; 
  15. ;       c/o Chip Rabinowitz
  16. ;       Innovative Data Concepts
  17. ;       2084 Woodlawn Avenue
  18. ;       Glenside, PA 19038
  19. ;       1-215-884-3373
  20. ;
  21. ;-----------------------------------------------------------------------------
  22. ;   This product supports the TesSeRact Standard for Ram-Resident Program 
  23. ;   Communication.  For information about TesSeRact, contact the TesSeRact 
  24. ;   Development Team at:
  25. ;       Compuserve:    70731,20
  26. ;       MCIMAIL:       315-5415
  27. ;   This MCIMAIL Account has been provided to the TesSeRact Development
  28. ;   Team by Borland International, Inc.  The TesSeRact Development Team
  29. ;   is in no way associated with Borland International, Inc.
  30. ;-----------------------------------------------------------------------------
  31.  
  32. INCLUDE TESS.INC
  33. IFDEF   ALLPUBLIC
  34. INCLUDE tsint1c.pub
  35. ENDIF
  36.  
  37. .MODEL small
  38.  
  39. EXTRN TSRTIMERPROC:FAR
  40.  
  41. .CODE
  42.  
  43. EXTRN TESS_GLOBALS:byte
  44. EXTRN TESS_USERPARMS:byte
  45.  
  46. PUBLIC newint1C
  47.  
  48. ENDIF
  49.  
  50. ;---------------------------------------------------------------------;
  51. ;       I N T E R R U P T   1 C     -   t i m e r  -                  ;
  52. ;---------------------------------------------------------------------;
  53. newint1C proc far
  54.  
  55.         ASSUMENODS
  56.  
  57.         push    ds
  58.  
  59.         push    cs
  60.         pop     ds
  61.  
  62.         ASSUMEDS
  63.  
  64.         pushf
  65.  
  66.         test    WPTR [STATUS],TSRENABLED        ;is TSR enabled?
  67.         jz      do_old1c                ;no -- do original
  68.  
  69.         test    BPTR [SOFTINTFLAGS],ININT1C     ;See if recursion has taken place
  70.         jz      start_new_int1C         ;If not continue with new int 1C
  71.  
  72. do_old1c:
  73.         POPFF
  74.         pop     ds
  75.  
  76.         ASSUMENODS
  77.  
  78.         jmp     DPTR [OLDINT1C]         ;Jump to original int 1C
  79.  
  80. start_new_int1C:
  81.         ASSUMEDS
  82.  
  83.         or      BPTR [SOFTINTFLAGS],ININT1C     ;Set the int 1C active flag
  84.         POPFF
  85.  
  86.         pushf                           ;simulate interrupt ...
  87.         call DPTR [OLDINT1C]            ;do the original
  88.  
  89.         sti
  90.  
  91.         push    ax
  92.  
  93.         mov     ax,WPTR [STATUS]        ;is a Timer Procedure set?
  94.         test    ax,TIMERSET
  95.         jz      exit_1C                 ;nope
  96.  
  97.         push    bx
  98.         push    cx                      ;save registers
  99.         push    dx
  100.         push    es
  101.  
  102.         mov     ax,WPTR [OURDSEG]       ;set up data segments
  103.  
  104.         push    ax
  105.         push    ax
  106.         pop     ds
  107.         pop     es
  108.  
  109.         ASSUMENODS
  110.  
  111.         sti                             ;make sure ints are enabled ;v .66
  112.  
  113. IFDEF TP4
  114. IFNDEF ASMCOM
  115.         call    DPTR PTIMERPROC ;for TP4 must use procptr
  116. ELSE
  117.         call    TSRTIMERPROC            ;non-TP version
  118. ENDIF
  119. ELSE
  120.         call    TSRTIMERPROC            ;non-TP version
  121. ENDIF
  122.  
  123. end_1C:
  124.         pop     es
  125.         pop     dx
  126.         pop     cx
  127.         pop     bx
  128.  
  129. exit_1C:
  130.         and     BPTR [SOFTINTFLAGS],NOT ININT1C
  131.         pop     ax
  132.         pop     ds
  133.         iret
  134.  
  135. newint1C endp
  136.  
  137. ENDIT
  138.