home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD1.mdf / pascal / library / dos / teseract / source / tsint16.asm < prev    next >
Encoding:
Assembly Source File  |  1988-10-02  |  6.7 KB  |  232 lines
  1. IFNDEF TP4
  2.         PAGE 60,132
  3. ;----------------------------------------------------------------------------
  4. SUBTTL  TesSeRact Revision Level 1
  5. ;-----------------------------------------------------------------------------
  6. ;   TesSeRact(tm) -- A Library of Routines for Creating Ram-Resident (TSR)
  7. ;                    programs for the IBM PC and compatible Personal
  8. ;                    Computers.
  9. ;
  10. ;The software, documentation and source code are: 
  11. ; 
  12. ;       Copyright (C) 1986, 1987, 1988 Tesseract Development Team
  13. ;       All Rights Reserved 
  14. ; 
  15. ;       c/o Chip Rabinowitz
  16. ;       Innovative Data Concepts
  17. ;       2084 Woodlawn Avenue
  18. ;       Glenside, PA 19038
  19. ;       1-215-884-3373
  20. ;
  21. ;-----------------------------------------------------------------------------
  22. ;   This product supports the TesSeRact Standard for Ram-Resident Program 
  23. ;   Communication.  For information about TesSeRact, contact the TesSeRact 
  24. ;   Development Team at:
  25. ;       Compuserve:    70731,20
  26. ;       MCIMAIL:       315-5415
  27. ;   This MCIMAIL Account has been provided to the TesSeRact Development
  28. ;   Team by Borland International, Inc.  The TesSeRact Development Team
  29. ;   is in no way associated with Borland International, Inc.
  30. ;-----------------------------------------------------------------------------
  31.  
  32. INCLUDE TESS.INC
  33. IFDEF   ALLPUBLIC
  34. INCLUDE tsint16.pub     ;public definitions (uses Periscope PUBLIC.COM /E)
  35. ENDIF
  36.  
  37. .MODEL small
  38. .CODE
  39.  
  40. EXTRN _TESSKEYSTAT:near
  41.  
  42. EXTRN TESS_GLOBALS:byte
  43.  
  44. PUBLIC newint16, _TESSSTUFFKEYS
  45.  
  46. ENDIF
  47.  
  48. BUFFER_TAIL     equ     1ch
  49. BUFFER_HEAD     equ     1ah
  50. BUFFER_START    equ     80h
  51. BUFFER_END      equ     82h
  52.  
  53.  
  54. _TESSSTUFFKEYS proc near
  55. ;
  56. ;       on entry, AX contains ASCII/SCAN CODE pair to stuff
  57. ;       on exit, AX contains FFFF if keyboard is full, else
  58. ;           AX is 0
  59. ;       DI contains the stuffing speed.  If DI is zero, then a keystroke
  60. ;           is only placed into the buffer if the buffer is empty!
  61. ;           
  62. ;
  63.         ASSUMENODS
  64.  
  65.         push    es
  66.         push    si
  67.         push    bx
  68.  
  69.         pushf
  70.         cli
  71.  
  72.         push    ax
  73.         xor     ax,ax
  74.         mov     ax,40h
  75.         mov     es,ax
  76.         pop     ax
  77.  
  78.         mov     bx,es:[BUFFER_TAIL]     ;get tail of kbd buffer
  79.         mov     si,bx                   ;save it for later
  80.  
  81.         or      di,di                   ;if SLOW speed, then ....
  82.         jnz     not_slow
  83.  
  84.         cmp     bx,es:[BUFFER_HEAD]     ;if head=tail then
  85.         jne     bad_stuff               ;buffer is empty and
  86.                                         ;we can continue
  87. not_slow:
  88.         inc     bx
  89.         inc     bx                      ;advance to next position
  90.         cmp     bx,es:[BUFFER_END]      ;check for warap-around
  91.         jne     no_wrap
  92.  
  93.         mov     bx,es:[BUFFER_START]    ;start from beginning again
  94. no_wrap:
  95.         cmp     bx,es:[BUFFER_HEAD]     ;is the buffer full?
  96.         je      bad_stuff               ;yep -- return right away!
  97.  
  98.         mov     es:[si],ax              ;store the character
  99.         mov     es:[BUFFER_TAIL],bx     ;move the tail pointer up
  100.         xor     ax,ax
  101.         jmp     short stuff_out
  102.  
  103. bad_stuff:
  104.         xor     ax,ax
  105.         dec     ax
  106. stuff_out:
  107.         POPFF
  108.         pop     bx
  109.         pop     si
  110.         pop     es
  111.         ret
  112.  
  113. _TESSSTUFFKEYS endp
  114.  
  115.  
  116. newint16 PROC FAR
  117.  
  118.         ASSUMENODS
  119.  
  120. ; ..lf -- we may have to go thru here and check for flag modifications 
  121. ; ..cr - yep -- we're blowing the flags -- fix ASAP
  122. ;
  123. start_again:                    ; ..lf
  124.         or      BPTR [SOFTINTFLAGS],ININT16 ;indicate our int16 is active
  125.  
  126.         cmp     ax,55ffh                ;is it msword?
  127.         je      check_word              ;yes!!
  128.  
  129.         test    ah,10h                  ;check for new bios function ..lf
  130.         jz      gobios16                ;if zero, then have char request.
  131.  
  132.         mov     BPTR [NEWKBDFLAG],10h   ;say new_bios function involved
  133.         and     ah,0EFh                 ;just clear out the one bit
  134.                                         ;force test w/o new_bios flag
  135.  
  136. gobios16:
  137.         cmp     ah,00                   ;if char request,
  138.         je      func00                  ;loop for character
  139.         cmp     ah,01                   ;if character availability test
  140.         je      func01                  ;go check for char
  141.  
  142. bios16:
  143.         and     BPTR [SOFTINTFLAGS],NOT ININT16 ;say our 16 deactivated
  144.         or      ah,BPTR [NEWKBDFLAG]
  145.         mov     BPTR [NEWKBDFLAG],00    ;clear the enyucked flag
  146.         jmp     DPTR [OLDINT16]
  147.  
  148.  
  149. check_word:
  150.         cmp     bx,4
  151.         jne     bios16
  152.  
  153.         or      cx,cx
  154.         jz      start_word
  155.         mov     BPTR [INWORD4],0
  156.         jmp     bios16
  157.  
  158. start_word:
  159.         mov     BPTR [INWORD4],1
  160.         jmp     bios16
  161.  
  162.  
  163. ; -- USER REQUEST FOR KEYBOARD STATUS / KEY AVAILABILITY 
  164.  
  165. func01:
  166.         push    ds                      ;save regs, set our Dseg
  167.         push    cs
  168.         pop     ds
  169.  
  170.         ASSUMEDS
  171.  
  172. func01A:
  173.         call    _TESSKEYSTAT            ;look at key buffer
  174.         pushf                           ;save return flags
  175.  
  176. fret01:                                 ;return INT 16h information
  177.         mov     BPTR [NEWKBDFLAG],0     ;clear any "new bios" conditions ..lf
  178.         and     BPTR [SOFTINTFLAGS],NOT ININT16 ;Say INT16 is done
  179.         POPFF                           ;return bios int 16 status flags 
  180.  
  181.         pop     ds
  182.  
  183.         ASSUMENODS
  184.  
  185.         push    ax                      ;save return value
  186.  
  187.         pushf
  188.         pop     ax                      ;get FLAGS to AX
  189.         push    bp
  190.  
  191.         mov     bp,sp
  192.  
  193.         or      ax,200h         ;make sure INTs are enabled (on stack)
  194.  
  195.         mov     [bp+8],ax
  196.  
  197.         pop     bp
  198.         pop     ax              ;get return value back
  199.  
  200.         iret                    ;return (flags modified in place)
  201.  
  202. ; -- REQUEST TO READ/WAIT FOR  KEY FROM KEYBOARD
  203.  
  204. func00:
  205.         push    ds
  206.         push    cs
  207.         pop     ds
  208.  
  209.         ASSUMEDS
  210.  
  211. func00A:
  212.         call    _TESSKEYSTAT            ;Read & wait until key available
  213.         jz      func00A                 ;loop 'till key from keyboard or TSR
  214.  
  215.  
  216.         pushf                           ;simulate INT 16
  217.  
  218.         mov     ah,0                    ;get the waiting key
  219.         or      ah,BPTR [NEWKBDFLAG]    ;re-insert new_bios flags ..lf
  220.  
  221.  
  222.         call    DPTR [OLDINT16] ;do bios read 
  223.  
  224. out_16A:
  225.         pushf                           ;save return flags
  226.                                         ;stack now holds FLAGS,SI,DI,IP,DS,CS,FLAGS
  227.         jmp     fret01                  ;restore and return
  228.  
  229. newint16 endp
  230.  
  231. ENDIT
  232.