home *** CD-ROM | disk | FTP | other *** search
/ Share Gallery 1 / share_gal_1.zip / share_gal_1 / BF / BF177B.ZIP / INSTALL.BAT next >
DOS Batch File  |  1991-07-06  |  8KB  |  193 lines
  1. :INSTALL.BAT for use with VIDEO TAPE INVOICING and PKWARE, INC.
  2. :May specify A:INSTALL A: C: where A: is source and C: is destination
  3. echo off
  4. cls
  5. echo off
  6. echo VIDEO TAPE INVOICING
  7. echo Installation and Updating Routine
  8. echo Copyright (C)) 1985-1991 Danny A. Stewart
  9. echo 615 Oak Street,  Prescott, ARkansas 71857
  10. echo Phone (501) 887-5930 (6:30-9:00 p.m. Central Time)
  11. echo ─────────────────────────────────────────────────────────────────────────────
  12. :SETSOUR
  13. if ""=="%1" set sour=A:
  14. if ""=="%1" goto SETDEST
  15. set sour=%1
  16. :SETDEST
  17. if ""=="%2" set dest=C:
  18. if ""=="%2" goto ALLSET
  19. set dest=%2
  20. :ALLSET
  21. if ""=="%sour%" goto ENVERR
  22. if ""=="%dest%" goto ENVERR
  23. echo This routine plans to install/update from %sour%\*.*
  24. echo   to %dest%\VTI\*.* and to %dest%\VTITUT\*.*
  25. echo If this is not correct, abort with Ctrl-C.  Enter the correct parameters with:
  26. echo   INSTALL  A:  C:
  27. echo   where A: is the source and C: is the destination.
  28. echo See the README file for other information.
  29. echo ─────────────────────────────────────────────────────────────────────────────
  30. echo Press Ctrl-C to abort this routine, or
  31. pause
  32. if not exist %sour%\NUL goto END
  33. if exist %dest%\NUL goto CHGTOHD
  34. goto END
  35. :CHGTOHD
  36. %dest%
  37. if exist %sour%\COPYVTI.EXE goto VTIINST
  38. if exist %sour%\VTIUPDAT.EXE goto VTIINST
  39. goto ERROR
  40. :VTIINST
  41. if exist %dest%\VTI\NUL goto VTIUPD
  42. cls
  43. echo VIDEO TAPE INVOICING
  44. echo Installing VTI from %sour%\ to %dest%\VTI\
  45. echo (Using PKWARE to explode and unskrink files)
  46. echo ═════════════════════════════════════════════════════════════════════════════
  47. echo CD %dest%\VTI > %dest%\vti.bat
  48. echo SET CLIPPER=V016;R016 >> %dest%\vti.bat
  49. echo VTIMENU >> %dest%\vti.bat
  50. echo CD %dest%\ >> %dest%\vti.bat
  51. echo Created %dest%\VTI.BAT as your loading file.
  52. echo ─────────────────────────────────────────────────────────────────────────────
  53. mkdir %dest%\vti
  54. if not exist %dest%\vti\NUL goto CANTDO
  55. cd %dest%\vti
  56. if exist %sour%\copyvti.exe  %sour%\copyvti
  57. if exist %sour%\vtiupdat.exe %sour%\vtiupdat
  58. if not exist pkunzip.exe goto CANTDO
  59. if exist vtitutor.zip del vtitutor.zip
  60. if exist %sour%\params.vti copy %sour%\params.vti %dest%\VTI\params.mem
  61. if exist %sour%\params2.vti copy %sour%\params2.vti %dest%\VTI\params2.mem
  62. goto TUTINST
  63. :VTIUPD
  64. cls
  65. echo VIDEO TAPE INVOICING
  66. echo Updating %dest%\VTI\ from %sour%\
  67. echo (Using PKWARE to explode and unskrink files)
  68. echo ═════════════════════════════════════════════════════════════════════════════
  69. cd %dest%\vti
  70. if exist %sour%\copyvti.exe  %sour%\copyvti  -e -o vtimenu.exe readme.vti
  71. if exist %sour%\vtiupdat.exe %sour%\vtiupdat -e -o vtimenu.exe readme.vti
  72. goto TUTINST
  73. :TUTINST
  74. if exist %dest%\vtitut\NUL goto TUTUPD
  75. cls
  76. echo VIDEO TAPE INVOICING
  77. echo Installing VTI from %sour%\ to %dest%\VTITUT\
  78. echo (Using PKWARE to explode and unskrink files)
  79. echo ═════════════════════════════════════════════════════════════════════════════
  80. echo CD %dest%\VTITUT > %dest%\vtitut.bat
  81. echo SET CLIPPER=V016;R016 >> %dest%\vtitut.bat
  82. echo VTIMENU >> %dest%\vtitut.bat
  83. echo CD %dest%\ >> %dest%\vtitut.bat
  84. echo Created %dest%\VTITUT.BAT as your loading file.
  85. echo ─────────────────────────────────────────────────────────────────────────────
  86. mkdir %dest%\vtitut
  87. if not exist %dest%\vtitut\NUL goto CANTDO
  88. cd %dest%\vtitut
  89. if exist %sour%\copyvti.exe  %sour%\copyvti
  90. if exist %sour%\vtiupdat.exe %sour%\vtiupdat
  91. if not exist pkunzip.exe goto CANTDO
  92. if not exist vtitutor.zip goto CANTDO
  93. pkunzip vtitutor.zip
  94. del vtitutor.zip
  95. goto END1
  96. :TUTUPD
  97. cls
  98. echo VIDEO TAPE INVOICING
  99. echo Updating %dest%\VTITUT\ from %sour%\
  100. echo (Using PKWARE to explode and unskrink files)
  101. echo ═════════════════════════════════════════════════════════════════════════════
  102. cd %dest%\vtitut
  103. if exist %sour%\copyvti.exe  %sour%\copyvti  -e -o vtimenu.exe readme.vti manual.txt
  104. if exist %sour%\vtiupdat.exe %sour%\vtiupdat -e -o vtimenu.exe readme.vti
  105. goto END1
  106. :END1
  107. cls
  108. echo VIDEO TAPE INVOICING
  109. echo ═════════════════════════════════════════════════════════════════════════════
  110. if not exist %2\config.sys goto ADDCS
  111. type %2\config.sys
  112. echo ─────────────────────────────────────────────────────────────────────────────
  113. echo Please check your existing (shown above) CONFIG.SYS for statements
  114. echo    FILES=20
  115. echo    BUFFERS=20
  116. echo or higher numbers.  This routine does NOT change that file.
  117. echo ─────────────────────────────────────────────────────────────────────────────
  118. goto PART2
  119. :ADDCS
  120. echo Creating %2\CONFIG.SYS file . . .
  121. echo FILES=20 > %2\config.sys
  122. echo BUFFERS=20 >> %2\config.sys
  123. echo You must reboot your computer to make the CONFIG.SYS file effective.
  124. echo ─────────────────────────────────────────────────────────────────────────────
  125. :PART2
  126. echo echo off > part2.bat
  127. if exist %sour%\COPYVTI.EXE goto NODISK2
  128. echo cls >> part2.bat
  129. echo echo VIDEO TAPE INVOICING >> part2.bat
  130. echo :TRYAGAIN >> part2.bat
  131. echo echo ═════════════════════════════════════════════════════════════════════════════ >> part2.bat
  132. echo echo Please insert Diskette #2 (Manual diskette) containing >> part2.bat
  133. echo echo the VTIDOCS.EXE file into drive %sour% and >> part2.bat
  134. echo pause >> part2.bat
  135. echo if not exist %sour%\vtidocs.exe goto TRYAGAIN >> part2.bat
  136. echo %sour%\vtidocs -o >> part2.bat
  137. :NODISK2
  138. echo cls >> part2.bat
  139. echo echo VIDEO TAPE INVOICING >> part2.bat
  140. echo echo ═════════════════════════════════════════════════════════════════════════════ >> part2.bat
  141. echo echo Video Tape Invoicing installed or updated: >> part2.bat
  142. echo echo    %dest%\VTI >> part2.bat
  143. echo echo    %dest%\VTITUT >> part2.bat
  144. echo echo (unless errors were reported). >> part2.bat
  145. echo echo ───────────────────────────────────────────────────────────────────────────── >> part2.bat
  146. echo echo To print the manual, enter these commands: >> part2.bat
  147. echo echo     CD %2\VTITUT >> part2.bat
  148. echo echo     COPY  MANUAL.TXT  PRN: >> part2.bat
  149. echo echo ───────────────────────────────────────────────────────────────────────────── >> part2.bat
  150. echo echo If you just updated, be sure your loading files contain >> part2.bat
  151. echo echo     SET CLIPPER=V016;R016 >> part2.bat
  152. echo echo with numbers at least 16. >> part2.bat
  153. echo echo ───────────────────────────────────────────────────────────────────────────── >> part2.bat
  154. echo cd %dest%\ >> part2.bat
  155. pause
  156. part2
  157. :CANTDO
  158. echo ─────────────────────────────────────────────────────────────────────────────
  159. echo Unable to complete the installation or update.
  160. echo The problem may be a missing file:
  161. echo     VTITUTOR.ZIP
  162. echo     PKUNZIP.EXE
  163. echo The problem may be a disk error which prevented creation of
  164. echo     one of these directories:
  165. echo     %dest%\VTI
  166. echo or  %dest%\VTITUT
  167. goto END
  168. :ERROR
  169. echo ─────────────────────────────────────────────────────────────────────────────
  170. echo At least one of the files necessary to run the Install or Update is
  171. echo not available.  Check your distribution diskette for
  172. echo     COPYVTI.EXE
  173. echo or  VTIUPDAT.EXE and VTIDOCS.EXE
  174. echo If you have more than one diskette, try another diskette.
  175. goto END
  176. :ENVERR
  177. echo The "out of environment space" error can be fixed.  Then you can use this
  178. echo   routine to install VTI onto your computer.  To fix the error, either
  179. echo   * temporarily reduce the size of your PATH statement with a command
  180. echo     similar to:  PATH=C:\DOS
  181. echo   * temporarily eliminate some of your system's other SET commands
  182. echo   * permanently increase the environment space by adding a command to
  183. echo     your CONFIG.SYS file similar to:  SHELL=C:\COMMAND.COM /P /E:00500
  184. echo Consult your DOS manual under these topics for more details.
  185. echo ─────────────────────────────────────────────────────────────────────────────
  186. goto ENDEND
  187. :END
  188. echo ─────────────────────────────────────────────────────────────────────────────
  189. if not exist %sour%\NUL echo Please insert distribution diskette and try again
  190. if not exist %dest%\NUL echo You do not have a drive %dest%
  191. if exist %dest%\NUL cd %dest%\
  192. :ENDEND
  193. echo on