home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Generous Efforts of Many
/
gemcd.zip
/
GEM.CD.B.po
/
GAMES:BASIC.3
/
STARTUP.bas
< prev
next >
Wrap
BASIC Source File
|
2010-05-14
|
3KB
|
51 lines
1 REM *** BIG RED APPLE CLUB
3 REM *** VERSION 1.4
4 REM *** VERSION A (NORMAL)
5 :
10 D$ = CHR$(4): PRINT D$;"PR#0": TEXT : HOME : POKE 216,0
12 PRINT D$"PREFIX": INPUT "";P$: PRINT D$"PREFIX"P$: REM FIX THANKS TO ERIC SCHECHTER
15 PRINT CHR$(21)
20 V1 = 0: GOSUB 7000
30 INVERSE :A$ = "+": GOSUB 800: NORMAL
40 VTAB 14:A$ = "DISTRIBUTED BY": GOSUB 300: VTAB 6:A$ = ISSUE$: GOSUB 300: VTAB 7:A$ = DISKNAME$: GOSUB 300
50 VTAB 16:A$ = CLUB$: GOSUB 300:A$ = "423 NORFOLK AVENUE": GOSUB 300:A$ = "NORFOLK, NE 68701": GOSUB 300
60 HTAB 8: GOSUB 5000
70 HOME : INVERSE :A$ = " ": GOSUB 810: NORMAL : VTAB 2: HTAB 2: INVERSE : FOR V1 = 1 TO 5: PRINT " ";: NEXT : HTAB 35: FOR V1 = 1 TO 5: PRINT " ";: NEXT : NORMAL
75 VTAB 1: INVERSE :A$ = ": :": GOSUB 300: VTAB 3: GOSUB 300: NORMAL
77 V1 = 13 -( LEN(ISSUE$)/2):I2$ = IS$: FOR V2 = 1 TO V1:I2$ = " " +I2$ +" ": NEXT : IF LEN(I2SUE$)/2 < > INT( LEN(I2SUE$)/2) THEN I2SUE$ = I2SUE$ +" "
80 VTAB 2: INVERSE :A$ = I2SUE$: GOSUB 300: NORMAL : VTAB 23:A$ = CLUB$: GOSUB 300
90 FOR V1 = T1 TO T2: HTAB 5: VTAB 5 +V1 -T1: INVERSE
100 IF V1 >9 THEN PRINT CHR$(55 +V1);: GOTO 120
110 PRINT V1;
120 NORMAL : PRINT TAB( 10);TITLE$(V1,1): NEXT
130 VTAB 21: HTAB 10: PRINT "ENTER SELECTION ";: GET A$: PRINT A$
132 IF ASC(A$) >96 THEN A$ = CHR$( ASC(A$) -32)
135 IF A$ > = "A" AND A$ < = "Z" THEN A$ = STR$( ASC(A$) -64 +9)
140 PK = INT( VAL(A$)): IF PK <1 OR PK >W THEN CALL -198: GOTO 130
150 IF PK = W THEN TEXT : HOME : END
151 VTAB 2: INVERSE :A$ = " ": GOSUB 300: NORMAL
152 VTAB 2: INVERSE :A$ = TITLE$(PK,1): GOSUB 300: NORMAL
155 POKE 34,3: POKE 35,22: POKE 32,1: POKE 33,36: VTAB 5: HTAB 10: HOME : POKE 32,5: VTAB 6
160 IF PK <AR THEN FOR V1 = 1 TO 14: PRINT ARTICAL$(PK,V1): NEXT
161 IF PK = 15 OR PK = W THEN TEXT : GOTO 70
162 VTAB 21: PRINT "PRESS ";: INVERSE : PRINT "M";: NORMAL : PRINT " FOR MAIN MENU ";: INVERSE : PRINT "R";: NORMAL : PRINT " TO RUN ";
163 GET A$: IF ASC(A$) >96 THEN A$ = CHR$( ASC(A$) -32)
164 IF A$ < >"M" AND A$ < >"R" THEN CALL -198: GOTO 163
165 PRINT A$: IF A$ = "R" THEN TEXT : HOME : PRINT D$: PRINT D$TITLE$(PK,0)TITLE$(PK,1)
170 TEXT : GOTO 70
299 TEXT : HOME : END
300 HTAB (21 - LEN(A$)/2): PRINT A$: RETURN : REM *** CENTER LINE
400 VTAB 21: HTAB 3: PRINT "M = MENU R = RUN PROGRAM ";: GET A$: PRINT A$
410 IF A$ < >"M" AND A$ < >"R" THEN CALL -198: GOTO 400
420 VTAB 3: HOME : RETURN
799 REM *** PRINT BORDERS
800 VTAB 1: FOR X = 1 TO 40: PRINT A$;: NEXT
810 VTAB 23: FOR X = 1 TO 40: PRINT A$;: NEXT : VTAB 2: FOR X = 2 TO 22: HTAB 1: PRINT A$;: HTAB 40: PRINT A$;: NEXT : RETURN
5000 POKE -16368,0: VTAB 22: INVERSE : PRINT "PRESS ANY KEY TO CONTINUE ";: NORMAL : GET PT$: PRINT PT$: HOME : VTAB 6: RETURN
6999 REM ***READ TEXT FILE
7000 PRINT D$: PRINT D$"OPEN HELLO.TXT": PRINT D$"READ HELLO.TXT": INPUT ARTICLE: DIM TITLE$(AR,1): FOR V1 = 1 TO AR: INPUT TITLE$(V1,0): INPUT TITLE$(V1,1): NEXT : INPUT ISSUE$: INPUT DISKNAME$: INPUT FILE$
7010 DIM ARTICLE$(AR -1,14): FOR V2 = 1 TO AR -1: FOR V1 = 1 TO 14: INPUT ARTICLE$(V2,V1): NEXT : NEXT
7020 PRINT D$: PRINT D$"CLOSE"
7030 T1 = 1:W = AR:T2 = W
7040 CLUB$ = " BIG RED COMPUTER CLUB "
7050 RETURN