home *** CD-ROM | disk | FTP | other *** search
/ Generous Efforts of Many / gemcd.zip / GEM.CD.B.po / GAMES:BASIC.3 / STARS.1.2.bas < prev    next >
BASIC Source File  |  2010-05-14  |  3KB  |  57 lines
  1. 70  HOME 
  2. 80 X =  PEEK(78) +256 * PEEK(79):X =  RND(V1)
  3. 100  PRINT "***** STARS **** STARS **** STARS *****": PRINT 
  4. 120  PRINT  SPC( 9)"WELCOME TO MY GALAXY.": PRINT  SPC( 4)"I'M IN CHARGE OF THE STARS HERE
  5. 130  PRINT : PRINT  SPC( 10)"PLAY MY GAME *STARS*": PRINT  SPC( 4)"AND GET SOME STARS FOR YOURSELF!": PRINT : PRINT 
  6. 140  PRINT : PRINT  SPC( 4)"*** PROGRAMMED BY K.G. WELK ***": PRINT  SPC( 4)"*** REVISED BY DOUG TRUEMAN ***": GOSUB 10000
  7. 150  HOME : PRINT "WANT TO KNOW HOW TO PLAY ";: GET Z$: IF Z$ < >"Y"  AND Z$ < >"N"  THEN 150
  8. 170  IF Z$ < >"Y"  THEN 280
  9. 180  REM  *** HERE IS HOW TO PLAY
  10. 190  HOME 
  11. 200  PRINT "I WILL THINK OF A NUMBER FROM 1 TO 100.
  12. 210  PRINT "TRY TO GUESS MY NUMBER. AFTER YOU GUESS I WILL TYPE 1 OR MORE STARS (*). THE    CLOSER YOU ARE TO MY NUMBER, THE MORE   STARS (*) I WILL TYPE. ONE STAR (*)
  13. 240  PRINT "MEANS YOU ARE FAR AWAY FROM MY NUMBER.  SEVEN STARS (*******) MEANS YOU'RE VERY
  14. 250  PRINT "CLOSE TO MY NUMBER!!!
  15. 260  GOSUB 10000
  16. 270  REM  *** COMPUTER 'THINKS' OF A NUMBER FROM 1 TO 100
  17. 280  LET X =  INT(100 * RND(1)) +1
  18. 300  HOME : PRINT "OK, STARSEEKER, I AM THINKING OF A      NUMBER. START GUESSING.
  19. 310  REM  *** GUESSING BEGINS
  20. 320  LET N = 1
  21. 330  PRINT 
  22. 340  INPUT "WHAT IS YOUR GUESS? ";G$:G =  INT( VAL(G$))
  23. 360  IF G = X  THEN 550
  24. 370  LET D =  ABS(G -X)
  25. 375  IF D = 1  THEN  PRINT "*";
  26. 380  IF D < = 2  THEN  PRINT "*";
  27. 390  IF D < = 4  THEN  PRINT "*";
  28. 400  IF D < = 8  THEN  PRINT "*";
  29. 410  IF D < = 16  THEN  PRINT "*";
  30. 420  IF D < = 32  THEN  PRINT "*";
  31. 430  IF D < = 64  THEN  PRINT "*";
  32. 510  PRINT 
  33. 520  LET N = N +1
  34. 530  GOTO 330
  35. 540  REM  *** PLAYER HAS GUESSED THE GALACTIC NUMBER
  36. 550  HOME : IF N >20  THEN K = 1: GOTO 570
  37. 555  VTAB 5: FOR K = 1 TO 21 -N: PRINT "  <CTRL-G>* ";: NEXT : PRINT : PRINT "!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!"
  38. 560  PRINT : PRINT 
  39. 570  PRINT  SPC( 14)"THAT'S IT!!!": PRINT : PRINT  SPC( 13)"YOU GUESSED MY": PRINT  SPC( 14)"COSMIC NUMBER": PRINT  SPC( 14)"IN ";N;" GUESSES."
  40. 580  PRINT : PRINT : PRINT  SPC( 1 + INT(4 -K/6))"YOU EARNED "K -1" STARS THIS TIME";: FOR V1 = 1 TO  INT(K/3): PRINT "!";: NEXT : PRINT : GOSUB 10000
  41. 600  HOME : PRINT "WANT TO PLAY AGAIN";
  42. 620  GET Z$
  43. 630  IF Z$ = "Y"  OR Z$ = "y"  THEN 280
  44. 635  IF Z$ < >"N"  THEN 620
  45. 640  PRINT Z$: PRINT "OK, GOODBYE FOR NOW. PLAY WITH ME AGAIN SOMETIME."
  46. 650  GOSUB 10000: HOME : PRINT  CHR$(4)"-STARTUP"
  47. 10000  POKE  -16368,0: VTAB 23: HTAB 7: PRINT "PRESS ANY KEY TO CONTINUE.";: GET PT$: PRINT PT$: RETURN 
  48. 20000  REM *** REVISED 3/20/87
  49. 20010  REM *** BY DOUG TRUEMAN
  50. 20020  REM *** ADDED PAGE TURN
  51. 20030  REM *** IMPROVED TITLE PAGE
  52. 20040  REM *** IMPROVED INSTRUCTIONS
  53. 20050  REM *** IMPROVED INPUT ROUTINES
  54. 20060  REM *** ADDED TRUE RANDOM
  55. 20100  REM *** REVISES 1/22/87
  56. 20110  REM *** BY D. TRUEMAN
  57. 20120  REM *** IMPROVED END ROUTINE