Generous Efforts of Many/gemcd.zip/GEM.CD.B.po/GAMES:BASIC.2/MINOTAUR.bas

BASIC Source File | 2010-05-14 | 6KB | 118 lines

10  TEXT : HOME
20  GOSUB 9000
30  DIM N(20),S(20),E(20),W(20),NOUN$(5)
40  FOR A = 1 TO 20
50  READ N(A),S(A),E(A),W(A)
60  NEXT A
70  FOR A = 1 TO 5
80  READ NOUN$(A)
90  NEXT A
100  FOR A = 1 TO 5
110 OB(A) = 22
120  NEXT
130 R = 1:DES$ = "YOU ARE IN A MUSTY DANK CORRIDOR.": POKE 34,1: GOTO 1520: REM      STARTING ROOM
1000  REM  PARSER
1010 V1$ = "":N1$ = "": PRINT "COMMAND? ";: INPUT "";A$
1020  FOR A = 1 TO  LEN(A$)
1030  IF  MID$ (A$,A,1) = " "  THEN X = A -1:A = 0: GOTO 1060
1040  NEXT A
1050 V1$ = A$: GOTO 1220
1060 V1$ =  LEFT$(A$,X)
1070 N1$ =  RIGHT$(A$, LEN(A$) -(X +1))
1200  REM  VERB HANDLING SECTION
1210  IF V1$ = "GO"  THEN V1$ = N1$
1220  IF V1$ = "NORTH"  OR V1$ = "SOUTH"  OR V1$ = "EAST"  OR V1$ = "WEST"  THEN  GOTO 1400
1230  IF V1$ = "INVENTORY"  OR V1$ = "INV"  THEN  GOTO 1900
1240  IF V1$ = "GET"  THEN  GOTO 1700
1250  IF V1$ = "DROP"  THEN  GOTO 2000
1260  IF V1$ = "QUIT"  THEN  GOTO 10390
1270  PRINT : PRINT "I DON'T KNOW HOW TO ";V1$;".": PRINT : GOTO 1010
1400  REM  MOVING AROUND ROUTINE
1410  IF V1$ = "NORTH"  THEN R = N(R)
1420  IF V1$ = "SOUTH"  THEN R = S(R)
1430  IF V1$ = "EAST"  THEN R = E(R)
1440  IF V1$ = "WEST"  THEN R = W(R)
1450  IF R = 4  THEN DES$ = "A SIGN ON THE WALL SAYS 'GO EAST.'"
1460  IF R = 10  THEN DES$ = "A SIGN ON THE WALL SAYS 'GO NORTH.'"
1470  IF R = 19  THEN DES$ = "A SIGN ON THE WALL SAYS 'DON'T GO WEST."
1480  IF R = 6  THEN DES$ = "A SIGN SAYS ABSOLUTELY DON'T GO NORTH."
1490  IF R = 5  THEN  GOTO 10260
1500  IF R = 20  THEN  GOTO 10330
1510  IF R = 21  THEN  GOTO 10200
1520  HOME : VTAB 1: CALL  -868: PRINT DES$: VTAB 24
1530 DES$ = "YOU ARE IN A MUSTY DARK CORRIDOR."
1540  PRINT : PRINT "OBJECTS HERE ARE:": PRINT
1550 X = R: GOSUB 2200
1560 X = 0
1570  GOTO 1010
1700  REM  GET STARTS HERE
1710  GOSUB 2100
1720  IF OB(X) = R  OR OB(X) = 22  THEN  GOTO 1740
1730  PRINT : PRINT "THAT ISN'T HERE.": PRINT : GOTO 1760
1740 OB(X) = 22
1750  PRINT : PRINT "YOU'VE GOT THE ";NOUN$(X);" GEM.": PRINT
1760 X = 0: GOTO 1010
1900  REM  INVENTORY ROUTINE
1910 X = 22
1920  PRINT : PRINT "YOU ARE CARRYING: ": PRINT
1930  GOSUB 2200
1940  GOTO 1010
2000  REM  DROP ROUTINE
2010  GOSUB 2100
2020  IF OB(X) = 22  THEN  GOTO 2040
2030  PRINT : PRINT "I DON'T HAVE THAT": PRINT : GOTO 2060
2040 OB(X) = R
2050  PRINT : PRINT "I'VE DROPPED THE ";NOUN$(X)" GEM.": PRINT
2060  GOTO 1010
2100  REM   ROUTINE FOR CHECKING NOUN
2110  FOR A = 1 TO 5
2120  IF N1$ = NOUN$(A)  THEN X = A:A = 0: RETURN
2130  NEXT
2140  PRINT : PRINT "I DON'T SEE ";N1$;"..."
2150  POP : PRINT : GOTO 1010
2200  REM  ROUTINE FOR LISTING OUT OBJECTS
2210  IF X = OB(1)  THEN  PRINT "A RED GEM":Y = 1
2220  IF X = OB(2)  THEN  PRINT "A GREEN GEM":Y = 1
2230  IF X = OB(3)  THEN  PRINT "A GOLD GEM":Y = 1
2240  IF X = OB(4)  THEN  PRINT "A PINK GEM":Y = 1
2250  IF X = OB(5)  THEN  PRINT "A BLUE GEM":Y = 1
2260  IF Y = 0  THEN  PRINT "NOTHING"
2270  PRINT
2280 Y = 0: RETURN
9000  REM  GAME INTRODUCTION
9010  HTAB 5: PRINT "THE LABYRINTH OF THE MINOTAUR"
9020  PRINT
9030  PRINT "BECAUSE OF THE SORDID LIFE YOU LIVE,YOU HAVE BEEN TRANSPORTED BACK TO ANCIENT   CRETE AND UNCEREMONIOUSLY DUMPED INTO   THE LABYRINTH OF THE MINOTAUR."
9040  PRINT : PRINT "HOWEVER, BECAUSE YOU ONCE GAVE A SMALL  DONATION TO AN OBSCURE CHARITY, THE     FATES HAVE ORDAINED THAT YOU SHALL HAVE A SLIM CHANCE TO SURVIVE BEING A MCRIB  SANDWICH FOR THE MINOTAUR."
9050  PRINT : PRINT "YOU HAVE BEEN PROVIDED WITH A BAG OF    COLORED (WORTHLESS) GEMS IN ORDER TO    SOLVE THE RIDDLE OF THE MAZE. THE       INSTRUCTIONS IN THE BAG SAY: "
9060  PRINT
9070  HTAB 5: PRINT "THE GEMS WITHIN ARE RED AND GREEN"
9080  HTAB 5: PRINT "AND GOLD AND PINK AND BLUE"
9090  HTAB 5: PRINT "SAY 'DROP' OR 'GET' AND NAME A GEM"
9100  HTAB 5: PRINT "TO HELP YOU MUDDLE THROUGH."
9110  PRINT : PRINT "PRESS ANY KEY TO CONTINUE: ";: GET A$
9120  RETURN
10000  REM   DATA STARTS HERE
10010  DATA  2,7,1,1,1,7,3,2,3,8,3,3,3,4,5,4,5,5,5,5,21,16,16,16,1,1,7,7,4,8,8,9,4,9,10,8,5,15,15,15,7,16,11,11,17,7,12,12,8,13,13,12,9,19,14,14,15,15,14,15,11,16,16,6,12,17,17,11,13,18,18,18,18,20,20,20,20,20,20,20
10020  DATA  "RED","GREEN","GOLD","PINK","BLUE"
10200  REM  MISCELLANEOUS MESSAGES
10210  TEXT : HOME
10220  PRINT : PRINT "HOORAY...YOU'VE WON....SORT OF."
10230  PRINT : PRINT "AS YOU EXIT THE LABYRINTH THROUGH A     TURNSTILE, YOU SEE WHAT LOOKS LIKE A    LARGE SIGN HANGING FROM A TREE."
10240  PRINT : PRINT "UPON CLOSER EXAMINATION YOU SEE IT IS   REALLY A MIRROR.": PRINT : PRINT "GAZING INTO THE MIRROR YOU SEE A        MINOTAUR GAZING BACK AT YOU."
10250  PRINT : PRINT "SUDDENLY YOU FEEL LIKE GOING INTO TOWN  AND WREAKING HAVOC.": END
10260  TEXT : HOME
10270  VTAB 1: PRINT "YOU ARE IN A WINECELLAR.": POKE 34,1
10280  PRINT : PRINT "THERE ARE RACKS AND RACKS OF WINE UPON  THE WALL. ON THE FLOOR ARE AMPHORAE     CONTAINING MORE OF THE SAME LIQUID."
10290  PRINT : PRINT "LOOKING AROUND YOU KNOW YOU'RE IN       TROUBLE AS THE DOOR HAS SWUNG SHUT AND  BLENDED INTO THE WALLS."
10300  PRINT : PRINT "A SIGN ON THE WALL SAYS": PRINT : PRINT  TAB( 5)"DISREGARD PREVIOUS SIGN."
10310  PRINT
10320  GOTO 1540
10330  TEXT : HOME
10340  FLASH : PRINT "MINOTAUR'S KITCHEN": NORMAL
10350  PRINT : PRINT "YOU HAVE BEEN CLEVERLY LURED HERE BY    THE SIGN WHICH THE MINOTAUR HUNG ON     THE KITCHEN DOOR.
10360  PRINT : PRINT "THE MINOTAUR GLANCES UP FROM THE CORNER WHERE HE IS READING 'ONE THOUSAND AND   ONE WAYS TO PREPARE ADVENTURERS' BY     JULIA CHILDS.
10370  PRINT : PRINT "AS HE GETS UP AND MOVES TOWARD YOU,     SNORTING AND SNUFFLING, WE GENTLY CLOSE THE DOOR AND LEAVE YOU."
10380  PRINT : PRINT "AU REVOIR,SWEET FRICASEE.": FOR V1 = 1 TO 9000: NEXT
10390  TEXT : HOME
10400  PRINT : PRINT  CHR$(4)"RUN STARTUP"