74 PRINT "MANY HIDDEN TREASURES IN THEM.": PRINT : PRINT
76 PRINT " FEW EXPLORE THEM FOR IT IS SAID "
78 PRINT "THAT PIRATES AND DRAGONS LIVE THERE-----"
82 PRINT "BESIDES, THERE ARE DEEP PITS INTO WHICH "
84 PRINT "MANY HAVE FALLEN AND DIED."
86 PRINT : PRINT : PRINT : PRINT
88 PRINT " -O- HIT ANY KEY TO CONTINUE -O-";: CALL -756
90 PRINT : PRINT : PRINT
92 PRINT " YOU, AS A SMART AND BRAVE HUMAN; "
94 PRINT "AND I, AN ALERT APPLE II, WILL EXPLORE "
96 PRINT "THE CAVES AND TRY TO FIND THE TREASURE. "
98 PRINT : PRINT " I WILL BE YOUR EYES AND EARS AND "
100 PRINT "WILL TELL YOU IF DANGER LURKS AHEAD.": PRINT
102 PRINT : PRINT " I HOPE YOU BROUGHT A MAP.": PRINT : PRINT
104 PRINT " IN CASE YOU DIDN'T,": PRINT
106 PRINT "YOU'LL HAVE TO MAKE ONE AS WE EXPLORE. "
107 PRINT
108 PRINT " TYPE '-1' TO EXIT FROM THE CAVES, "
110 PRINT "AND TYPE '0' FOR A STATUS REPORT."
115 PRINT
120 PRINT " -O- HIT ANY KEY TO CONTINUE -O-";: CALL -756
130 HOME
140 FOR I = 1 TO 3
150 N = 3 + FN R(88)
160 IF A(N) < >0 THEN 150
170 A(N) = 2
180 NEXT
190 FOR I = 3 TO 9
200 N = 3 + FN R(88)
210 IF A(N) < >0 THEN 200
220 A(N) = I
230 NEXT
240 FOR I = 288 TO 304
250 N = FN R(94)
260 IF A(N) < >0 THEN 250
270 A(N) = I
280 NEXT
290 RESTORE
300 FOR N = 1 TO 23
310 READ A$
320 NEXT
330 FOR N = 137 TO 421
340 READ A(N)
350 NEXT
360 W = 0: REM USER'S CAVE LOCATION
370 M = 0: REM BECOMES A1 WHEN CARRYING MAGIC CARPET
380 B = 200: REM BATTERY POWER LEFT
390 D = 0: REM BECOMES A1 AFTER INVISABLE DOG IS FOUND
400 VTAB 4
410 PRINT " WELCOME TO THE MARPEL CAVES WHERE YOU'LL FIND MYSTERY, TREASURE AND A D V E N T U R E ."
420 PRINT
430 GOTO 500
440 REM
450 REM ** MAIN ROUTINE **
460 REM ----------------------
470 HOME
480 B = B -1
490 IF B = 0 THEN 3740
500 IF W = 0 THEN 3140
510 REM
520 REM *** CHANCE SITUATION ***
530 REM
540 IF FN R(200) = 200 THEN GOSUB 1890
550 IF FN R(200) = 200 THEN GOSUB 2120
560 IF (D = 0) *(A(W) = 0) *( FN R(50) = 50) THEN GOSUB 2580
570 IF (A(W) = 6) *( FN R(5) = 5) THEN 3570
580 IF (M = 1) *( FN R(5) = 5) THEN GOSUB 2720
590 REM
600 REM *** SEE IF SPECIAL *** SITUATION
610 REM
620 IF A(W) = 2 THEN 3440
630 IF A(W) = 4 THEN 2890
640 IF A(W) = 5 THEN GOSUB 1770
650 IF A(W) = 7 THEN PRINT : PRINT : PRINT "THERE'S A SHY LITTLE ELF IN HERE HIDING SOMETHING."
660 IF A(W) = 8 THEN 2410
670 REM
680 REM ** WHERE YOU CAN GO NEXT
690 REM
700 GOSUB 3350
710 Z = W
720 GOSUB 4120
730 FOR N = 134 TO 136
740 IF A(N) = <0 THEN 780
750 PRINT TAB( 5);"CAVE "A(N);
760 IF A(N) = 0 THEN PRINT "- THE ENTRANCE";
770 PRINT
780 NEXT
790 REM
800 REM ** QUIT & BATTERY TEST *
810 REM
820 IF B >190 THEN 880
830 IF W < >0 THEN 880
835 PRINT : PRINT
840 INPUT "TO EXPLORE SOME MORE TYPE 1, ELSE TYPE 2";J$
850 J = VAL(J$)
860 IF J = 2 THEN 3800
870 IF J < >1 THEN 840
880 IF B = 50 THEN PRINT : PRINT " I HOPE YOU BROUGHT MORE FLASHLIGHT BATTERIES."
890 IF B = 25 THEN PRINT : PRINT " YOUR FLASHLIGHT IS STARTING TO DIM A LITTLE."
900 IF B = 8 THEN PRINT : PRINT " YOUR FLASHLIGHT IS ALMOST OUT. BETTER LEAVE RIGHT NOW!!!"
910 IF A(W) = 3 THEN GOSUB 2290
920 REM
930 REM ** ADJACENT CAVE'S ** CONTENTS
940 REM
950 K = 0
960 L = 0
970 FOR N = 134 TO 136
980 J = A(N)
990 IF J <0 THEN 1090
1000 IF A(J) = 5 THEN 1090
1010 IF (A(J) >0) *(A(J) <10) *(K = 0) THEN PRINT :K = 1
1020 IF (A(J) = 2) *(L = 0) THEN PRINT " THERE ARE PITS NEARBY. WATCH YOUR STEP.":L = 1
1030 IF A(J) = 3 THEN PRINT " CAREFUL, THERE'S A PIRATE NEARBY."
1040 IF A(J) = 4 THEN PRINT " I HEAR A HUNGRY DRAGON, HE'S WAITING FOR HIS SUPPER."
1050 IF A(J) = 6 THEN PRINT " THERE'S A SIGN HERE THAT SAYS: >>> D A N G E R <<<"
1060 IF A(J) = 7 THEN PRINT " SOUNDS LIKE SOMEBODY IS SINGING. IT MUST BE AN ELF."
1070 IF A(J) = 8 THEN PRINT " THERE'S A STRANGE MIST IN HERE."
1080 IF A(J) = 9 THEN PRINT CHR$(34)"RUFF RUFF" CHR$(34)" I HEAR A DOG BARKING."
1090 NEXT
1100 IF A(131) = 0 THEN 1200
1110 PRINT
1120 PRINT "YOU'RE CARRYING :"
1130 FOR N = 131 TO 133
1140 IF A(N) <100 THEN 1180
1150 Z = A(N)
1160 GOSUB 4040
1170 PRINT A$,
1180 NEXT
1190 PRINT
1200 IF A(W) <100 THEN PRINT : GOTO 1440
1210 REM
1220 REM **TREASURE IN THIS CAVE
1230 REM
1240 PRINT
1250 A = A(W)
1260 GOSUB 4040
1270 PRINT " THIS CAVE HAS "A$" IN IT."
1280 PRINT "DO YOU WANT TO TAKE IT WITH YOU ?"
1290 INPUT "(Y OR N) ";J$
1300 IF J$ = "N" THEN 1440
1310 IF J$ < >"Y" THEN 1290
1320 IF Z = 290 THEN GOSUB 1630
1330 IF Z = 290 THEN 1440
1340 IF Z = 291 THEN M = 1
1350 IF Z = 294 THEN GOSUB 1990
1360 IF Z = 1 THEN 1440
1370 IF Z = 295 THEN 3650
1380 FOR N = 131 TO 133
1390 IF A(N) = 0 THEN A(N) = A(W):A(W) = 0: GOTO 1430
1400 NEXT
1410 PRINT " YOU CAN'T PICK IT UP NOW. YOUR'RE CARRYING TOO MUCH."
1420 GOTO 1440
1430 PRINT "O,K, YOU'VE GOT "A$"."
1440 IF A(W) = 7 THEN A(W) = 307
1450 REM
1460 REM ** WHERE TO NEXT **
1470 REM
1480 INPUT " WHAT CAVE DO YOU WANT TO EXPLORE NEXT ? ";J
1490 FOR N = 134 TO 136
1495 IF J = -1 THEN 835
1497 IF J = 0 THEN 3140
1500 IF A(N) = -1 THEN 840
1510 IF J = A(N) THEN W = J: GOTO 470
1520 NEXT
1530 IF (M = 1) *(J > = 0) *(J < = 94) *( INT(J) = J) THEN W = J: GOTO 470
1540 PRINT " SORRY, BUT YOU CAN'T GET THERE FROM HERE."
1550 GOTO 1480
1560 REM
1570 REM
1580 REM ** SPECIAL SITUATION SUBROUTINES
1590 REM -----------------------
1600 REM
1610 REM *** LOCK BOX ***
1620 REM
1630 FOR N = 131 TO 133
1640 IF A(N) = 289 THEN 1680
1650 NEXT
1660 PRINT "YOU CAN'T TAKE IT, IT'S TOO HEAVY."
1670 RETURN
1680 PRINT " THE BOX WAS TOO HEAVY SO I OPENED IT WITH YOUR KEYS. BY THE WAY THERE IS A RUBY IN IT THAT YOU CAN TAKE."
1690 A(W) = 308
1700 Z = 308
1710 GOSUB 4040
1720 RETURN
1730 REM
1740 REM ** VENDING MACHINE **
1750 REM
1760 VTAB 4
1770 PRINT "THERE'S A VENDING MACHINE HERE."
1780 FOR N = 131 TO 133
1790 IF A(N) = 288 THEN 1820
1800 NEXT
1810 RETURN
1820 PRINT " I'LL GET SOME BATTERIES WITH YOUR GOLD COINS."
1830 B = 200
1840 A(W) = 0
1850 RETURN
1860 REM
1870 REM *** EARTHQUAKE ***
1880 REM
1890 FOR N = 1 TO 10
1900 Z = 3 + FN R(88)
1910 GOSUB 3950
1920 NEXT
1930 VTAB 6
1940 PRINT " GUESS WHAT ? WE JUST HAD AN EARTH-QUAKE, BUT I'M O.K."
1950 RETURN
1960 REM
1970 REM **MAGIC WAND ROUTINE **
1980 REM
1990 FOR N = 131 TO 133
2000 IF A(N) = 293 THEN 2040
2010 NEXT
2020 PRINT " IT'S STUCK IN THE ROCKS AND CAN'T BE PULLED OUT."
2030 Z = 1: RETURN
2040 PRINT " LET ME USE YOUR MAGIC WAND A SEC. ";
2050 FOR Z = 0 TO 2000: NEXT
2060 PRINT : PRINT "HOCUS,POCUS..."
2070 FOR Z = 0 TO 2000: NEXT
2080 A(W) = 310:Z = 0
2090 RETURN
2100 REM
2110 REM *** BATS SHOW UP ***
2115 REM
2120 VTAB 6: PRINT "<CTRL-G>": REM *** CONT-G ***
2130 PRINT " A SUPERBAT JUST FLEW INTO THE CAVE AND PICKED YOU UP."
2140 IF A(131) = < >0 THEN PRINT "YOU DROPPED ALL OF YOUR TREASURES."
2150 FOR N = 131 TO 133
2160 IF A(N) = 0 THEN 2180
2170 A(0) = A(N):A(N) = 0:Z = 0: GOSUB 3950
2180 NEXT
2190 N = FN R(94)
2200 IF A(N) < >0 THEN 2190
2210 W = N
2220 PRINT " THE BAT JUST DROPPED YOU INTO CAVE "W" !!!"
2230 PRINT " IF YOU'RE ALRIGHT HIT " CHR$(34)"RETURN" CHR$(34);: CALL -756
2240 HOME
2250 RETURN
2260 REM
2270 REM *** PIRATE HERE ***
2280 REM
2290 PRINT : PRINT " THERE WAS A PIRATE IN HERE."
2300 IF A(131) < >0 THEN PRINT " HE JUST STOLE ALL YOUR TREASURES !"
2310 FOR N = 131 TO 133
2320 A(N) = 0
2330 NEXT
2340 Z = W
2350 GOSUB 2950
2360 PRINT " HE'S GONE NOW."
2370 RETURN
2380 REM
2385 REM ** MAGICIAN ROUTINE **
2390 REM
2400 HOME
2410 VTAB 6: PRINT "": REM *** CONT-G ***
2420 PRINT " THERE'S A MAGICIAN IN THIS CAVE. HE SAYS HE LOST HIS MAGIC BOOK. HE SAYSHE'D GIVE YOU A GOLDEN HARP IF YOU'LL TELL HIM WHERE IT IS."
2425 PRINT : PRINT "TYPE IN THE CAVE NUMBER. IF YOU DON'T KNOW, THEN JUST"
2430 PRINT "TYPE " CHR$(34)"99" CHR$(34)"."
2440 PRINT
2450 INPUT "WHERE'S HIS MAGIC BOOK ? ";J$
2460 J = INT( VAL(J$))
2470 IF (J <0) +(J >95) THEN 2520
2480 IF IF A(J) < >295 THEN 3840
2490 A(W) = 309
2500 A(J) = 0
2510 GOTO 470
2520 Z = W
2530 GOSUB 3950
2540 GOTO 470
2550 REM
2560 REM *** INVISABLE MAN *** ROUTINE
2570 REM
2580 VTAB 6: PRINT "<CTRL-G>": REM ** CONT-G **
2590 PRINT " THE INVISIBLE MAN IS HERE LOOKING FOR HIS INVISIBLE DOG. HE SAYS HE'LL GIVE YOU A $1000 REWARD IF YOU CAN TELL HIM WHERE HIS DOG IS. IF YOU DON'T KNOWTHEN GUESS."
2600 PRINT
2610 INPUT "WHAT CAVE IS THE INVISIBLE DOG IN ? ";J$
2620 HOME
2630 J = INT( VAL(J$))
2640 IF (J <0) +(J >95) +( INT(J) < >J) +(A(J) < >9) THEN RETURN
2650 A(W) = 305
2660 A(J) = 0
2670 D = 1
2680 RETURN
2690 REM
2700 REM *** MAGIC CARPET *** DISAPEARS
2710 REM
2720 FOR N = 131 TO 133
2730 IF A(N) = 291 THEN 2770
2740 NEXT
2750 M = 0
2760 RETURN
2770 A(N) = 0
2780 IF N = 133 THEN 2830
2790 FOR J = N TO 132
2800 A(J) = A(J +1)
2810 A(J +1) = 0
2820 NEXT
2830 PRINT " POOF !!! YOUR MAGIC CARPET JUST DISAPPEARED."
2840 M = 0
2850 RETURN
2860 REM
2870 REM *** DRAGON ROUTINE ***
2880 REM
2890 FOR N = 131 TO 133
2900 IF A(N) = 292 THEN 2930
2910 NEXT
2920 GOTO 3500
2930 VTAB 6
2940 PRINT " Y-I-K-E-S !!!! THERE'S A DRAGON IN HERE."
2950 PRINT : PRINT "GIVE ME YOUR GUN, QUICK !!!"
2960 FOR N = 0 TO 2000: NEXT
2970 HOME
2980 FOR N = 1 TO 5
2990 VTAB FN R(23): HTAB FN R(25): PRINT "B A N G ! ! !"
3000 FOR J = 0 TO 500: NEXT : HOME
3010 NEXT
3020 PRINT TAB( FN R(30));"POOF !!!"
3030 FOR J = 0 TO 500: NEXT : HOME
3040 PRINT " INCREDIBLE ??? THE DRAGON JUST VANISHED WHEN I SHOT HIMRIGHT BETWEEN HIS BLOOD-SHOT EYES."
3050 PRINT : PRINT " BUT LOOK AT THIS. HE LEFT BEHIND HIS LITTLE BLACK BOOK WITH THE ADDRESS AND PHONE NUMBERS OF EVERY BEAUTIFUL PRINCESS IN PENNSYLVANIA."
3060 PRINT
3070 PRINT " HIT THE " CHR$(34)"RETURN" CHR$(34)" KEY WHEN YOU CATCH YOUR BREATH.";: CALL -756
3080 A(W) = 306
3090 B = B +1
3100 GOTO 470
3110 REM
3120 REM * AT ENTRANCE ROUTINE *
3130 REM
3140 IF A(131) = 0 THEN 3210
3150 FOR N = 131 TO 133
3160 IF A(N) = 0 THEN 3200
3170 J = 96
3180 IF A(J) < >0 THEN J = J +1: GOTO 3180
3190 A(J) = A(N)
3200 NEXT
3210 IF A(96) = 0 THEN 3270
3220 PRINT " SO FAR,YOU'VE FOUND THESE TREASURESIN THE CAVES !"
3230 FOR N = 96 TO 130
3240 IF A(N) = 0 THEN 3270
3250 Z = A(N): GOSUB 4040: PRINT A$",";: IF PEEK(36) >28 THEN PRINT
3260 NEXT
3270 FOR N = 131 TO 133:A(N) = 0: NEXT
3280 PRINT : PRINT
3290 PRINT : PRINT " YOU'RE AT A CAVE ENTRANCE THAT LEADS TO :"
3300 B = B +1
3310 GOTO 710
3320 REM
3330 REM *** IN ROUTINE ***
3340 REM
3350 PRINT : PRINT : PRINT " YOU'RE IN CAVE "W" WHICH LEADS TO :"
3360 RETURN
3370 REM
3380 REM
3390 REM ** END OF PROGRAM ** ROUTINES
3400 REM -----------------------
3410 REM
3420 REM ** FELL INTO A PIT **
3430 REM
3440 VTAB 6: PRINT "": PRINT " SORRY, BUT I TRIED TO WARN YOU."
3450 PRINT "YOU FELL INTO A DEEP PIT AND KILLED YOURSELF !!!"
3460 GOTO 11000
3470 REM
3480 REM *** EATEN BY THE *** DRAGON
3490 REM
3500 VTAB 6: PRINT "<CTRL-G>": REM ** CONT-G **
3510 PRINT " SORRY, BUT I TRIED TO WARN YOU ABOUT THAT SOUND. SUPPER IS NOW BEING SERVED HERE IN THE DRAGON'S CHAMBER..."
3520 PRINT : PRINT : FOR I = 1 TO 4000: NEXT : INVERSE : PRINT "AND YOU ARE THE SUPPER !!!": NORMAL
3530 GOTO 11000
3540 REM
3550 REM *** ROOF FELL IN ***
3560 REM
3570 VTAB 6: PRINT "<CTRL-G><CTRL-G><CTRL-G><CTRL-G><CTRL-G>": REM ** CONT-G **
3580 PRINT " THE ROOF JUST CAVED IN AND BURIED YOU ALIVE. TOO BAD I DON'T HAVE A SHOVEL OR I'D DIG YOU OUT."
3590 PRINT
3600 PRINT " SEE YAH LATER."
3610 GOTO 11000
3620 REM
3630 REM * PICKED UP MAGIC BOOK*
3640 REM
3650 HOME
3660 VTAB 6: PRINT "<CTRL-G>": REM ** CONT-G **
3670 PRINT " I DON'T THINK YOU SHOULD HAVE DONE THAT. THE MAGICIAN WHO OWNS THAT MAGIC BOOK PUT A SPELL ON IT. ANYBODY THAT TRIES TO PICK IT UP TURNS INTO A FROG. "
3680 PRINT
3690 PRINT "EXCUSE ME WHILE I LOOK FOR SOME FLIES."
3700 GOTO 11000
3710 REM
3720 REM ** BATTERIES WENT DEAD *
3730 REM
3740 VTAB 6: PRINT "": REM ** CONT-G **
3750 PRINT " NOW LOOK WHAT YOU DID. YOUR FLASH-LIGHT WENT OUT AND YOU FELL INTO A PIT AND KILLED YOURSELF. TOO BADESPECIALLY AFTER YOU WERE DOING SO WELL."
3760 GOTO 11000
3770 REM
3780 REM *** USER QUITS ***
3781 REM
3782 HOME
3783 IF A(131) = 0 THEN 3790
3784 FOR N = 131 TO 133
3785 IF A(N) = 0 THEN 3802
3786 J = 96
3787 IF A(J) < >0 THEN J = J +1: GOTO 3787
3788 A(J) = A(N)
3789 NEXT
3790 IF A(96) = 0 THEN 3812
3800 HOME : VTAB 6
3802 PRINT "YOU FOUND THE FOLLOWING TREASURES: "
3804 FOR N = 96 TO 130
3806 IF A(N) = 0 THEN 3810
3808 Z = A(N): GOSUB 4040: PRINT A$",";: IF PEEK(36) >28 THEN PRINT
3810 NEXT
3812 FOR N = 131 TO 133:A(N) = 0: NEXT
3814 PRINT : PRINT
3816 PRINT "THE TREASURES ARE YOURS TO KEEP": PRINT
3818 PRINT "I ENJOYED SPELUNKING WITH YOU": PRINT
3820 PRINT "PLEASE ! RETURN SOON, I GET LONESOME.": PRINT
3822 PRINT " -O- GOOD LUCK ! ! ! -O-
3823 GOTO 11000
3825 REM
3830 REM ** MAGICIAN UPSET **
3835 REM
3840 VTAB 6
3850 PRINT " YOU'VE MADE THE MAGICIAN VERY ANGRY."
3855 PRINT "CAVE "J" DOESN'T HAVE A MAGIC BOOK IN IT.": PRINT
3860 FLASH : PRINT " TO PUNISH YOU FOR FIBBING, "
3863 PRINT "THE MAGICIAN CASTS A SPELL ON YOU "
3866 PRINT "AND NOW YOU ARE ONLY TWO INCHES TALL. ": NORMAL : PRINT
3870 PRINT " WORSE YET, THE MAGICIAN PUT YOU "
3873 PRINT "INTO A SMALL JAR AND LOCKED YOU IN HIS "
3876 PRINT "CUPBOARD. IF YOU EVER GET OUT OF THIS "
3880 PRINT "MESS, LET ME KNOW."
3885 GOTO 11000
3890 REM
3900 REM *** UTILITY SUBROUTINES
3910 REM -----------------------
3920 REM
3930 REM ** MOVE ITEM TO NEW ** CAVE LOCATION
3940 REM
3950 Y = 3 + FN R(88)
3960 IF A(Y) < >0 THEN 3950
3970 IF (Y = W) +(Y = Z) THEN 3950
3980 A(Y) = A(Z)
3990 A(Z) = 0
4000 RETURN
4010 REM
4020 REM ** MAKE A$ NAME OF ** TREASURE
4030 REM
4040 RESTORE
4050 FOR X = 0 TO Z -288
4060 READ A$
4070 NEXT
4080 RETURN
4090 REM
4100 REM ** SET UP CONNECTING ** CAVE NUMBERS
4110 REM
4120 FOR X = 0 TO 2
4130 A(134 +X) = A(137 +X +(Z *3))
4140 NEXT
4150 RETURN
4160 REM
4170 REM
4180 REM * TREASURE LIST *
4190 REM -----------------------
9910 DATA "GOLD COINS
9911 DATA "SOME KEYS
9912 DATA "A LOCK BOX
9913 DATA "A MAGIC CARPET
9914 DATA "AN OLD GUN
9915 DATA "A MAGIC WAND
9916 DATA "A SWORD
9917 DATA "A MAGIC BOOK
9918 DATA "AN OLD CLOCK
9919 DATA "FURS
9920 DATA "A SILVER BELL
9921 DATA "A NECKLACE
9922 DATA "A PEARL
9923 DATA "A DIAMOND
9924 DATA "A GOLD WATCH
9925 DATA "AN EMRALD
9926 DATA "JEWELRY
9927 DATA "A $1000 BILL
9928 DATA "A BLACK BOOK
9929 DATA "SOME ELF FOOD
9930 DATA "A RUBY
9931 DATA "A GOLDEN HARP
9932 DATA "A SWORD
9997 REM
9998 REM DATA FOR CONNECTING CAVES
9999 REM ---------------------
10000 DATA 1,94,-1
10001 DATA 0,2,3
10002 DATA 1,4,5
10003 DATA 1,6,7
10004 DATA 2,8,9
10005 DATA 2,10,11
10006 DATA 3,12,13
10007 DATA 3,14,15
10008 DATA 4,16,17
10009 DATA 4,18,19
10010 DATA 5,20,21
10011 DATA 5,22,23
10012 DATA 6,24,25
10013 DATA 6,26,27
10014 DATA 7,28,29
10015 DATA 7,30,31
10016 DATA 8,32,33
10017 DATA 8,34,35
10018 DATA 9,36,37
10019 DATA 9,38,39
10020 DATA 10,40,41
10021 DATA 10,42,43
10022 DATA 11,44,45
10023 DATA 11,46,47
10024 DATA 12,48,49
10025 DATA 12,50,51
10026 DATA 13,52,53
10027 DATA 13,54,55
10028 DATA 14,56,57
10029 DATA 14,58,59
10030 DATA 15,60,61
10031 DATA 15,62,63
10032 DATA 16,63,64
10033 DATA 16,34,64
10034 DATA 17,33,65
10035 DATA 17,36,65
10036 DATA 18,35,66
10037 DATA 18,38,66
10038 DATA 19,37,67
10039 DATA 19,40,67
10040 DATA 20,39,68
10041 DATA 20,42,68
10042 DATA 21,41,69
10043 DATA 21,44,69
10044 DATA 22,43,70
10045 DATA 22,46,70
10046 DATA 23,45,71
10047 DATA 23,48,71
10048 DATA 24,47,72
10049 DATA 24,50,72
10050 DATA 25,49,73
10051 DATA 25,52,73
10052 DATA 26,51,74
10053 DATA 26,54,74
10054 DATA 27,53,75
10055 DATA 27,56,75
10056 DATA 28,55,76
10057 DATA 28,58,76
10058 DATA 29,57,77
10059 DATA 29,60,77
10060 DATA 30,59,78
10061 DATA 30,62,78
10062 DATA 31,61,79
10063 DATA 31,32,79
10064 DATA 32,33,80
10065 DATA 34,35,80
10066 DATA 36,37,81
10067 DATA 38,39,81
10068 DATA 40,41,82
10069 DATA 42,43,82
10070 DATA 44,45,83
10071 DATA 46,47,83
10072 DATA 48,49,84
10073 DATA 50,51,84
10074 DATA 52,53,85
10075 DATA 54,55,85
10076 DATA 56,57,86
10077 DATA 58,59,86
10078 DATA 60,61,87
10079 DATA 62,63,87
10080 DATA 64,65,88
10081 DATA 66,67,88
10082 DATA 68,69,89
10083 DATA 70,71,89
10084 DATA 72,73,90
10085 DATA 74,75,90
10086 DATA 76,77,91
10087 DATA 78,79,91
10088 DATA 80,81,92
10089 DATA 82,83,92
10090 DATA 84,85,93
10091 DATA 86,87,93
10092 DATA 88,89,94
10093 DATA 90,91,94
10094 DATA 0,92,93
11000 VTAB 24: HTAB 9: PRINT "PRESS ANY KEY TO QUIT.";: GET PT$: PRINT PT$: PRINT CHR$(4)"RUN STARTUP"
