home *** CD-ROM | disk | FTP | other *** search
/ ftp.ee.lbl.gov / 2014.05.ftp.ee.lbl.gov.tar / ftp.ee.lbl.gov / mtrek.shar.Z / mtrek.shar / wrtv52.mac < prev    next >
Text File  |  1990-04-02  |  2KB  |  88 lines
  1.     .ENABL    LC
  2.     .TITLE    WRITE
  3.     .IDENT    /MTREK/
  4. ; 
  5. ;    *** Digital Equiptment VT-52 ***
  6. ;
  7. ;    FORTRAN callable routine to postion the cursor on a crt
  8. ;    terminal and write a string. There is also a routine to
  9. ;    clear the screen.
  10. ; 
  11. ;    Calling sequence:
  12. ; 
  13. ;        CALL WRITE(LINE,ICOL,STRING[,ICNT])
  14. ; 
  15. ;    LINE    Line to position cursor on
  16. ;    ICOL    Column to position cursor on
  17. ;    STRING    String of text to output
  18. ;    ICNT    Optional character count
  19. ;
  20. ;    Calling sequence:
  21. ; 
  22. ;        CALL CLEAR
  23. ; 
  24.     .GLOBL    WRITE,CLEAR
  25.  
  26.     LUN=1            ; LUN FOR QIOS
  27.     OFFSET=37        ; OFFSET FOR CURSOR ADDRESSING
  28.  
  29. WRITE:    MOV    @2(R5),R0    ; GET LINE POSITION
  30.     ADD    #OFFSET,R0    ; ADD OFFSET
  31.     MOVB    R0,LINE        ; AND STORE IN BUFFER
  32.     MOV    @4(R5),R0    ; NOW COLUMN POSITION
  33.     ADD    #OFFSET,R0    ; ADD OFFSET
  34.     MOVB    R0,COL        ; AND PUT IN BUFFER
  35.  
  36.     MOV    6(R5),BUFADR    ; MOVE STRING ADDRESS TO LIST
  37.     CMPB    #4,(R5)        ; CHARACTER COUNT INPUT?
  38.     BEQ    10$        ; BRANCH IF COUNT INPUT
  39.     MOV    #1,BUFARG    ; ONLY ONE ARGUMENT TO FILL
  40.     BR    20$        ; GO DO IT
  41. 10$:    MOV    #2,BUFARG    ; TWO ARGUMENTS TO FILL
  42.     MOV    10(R5),BUFCNT    ; COPY ADDRESS OF COUNT TO LIST
  43. 20$:    MOV    #WRTARG,R5    ; SET UP ARGUMENTS FOR CURSOR
  44.     CALL    FILL        ; AND SEND CURSOR
  45.     MOV    #BUFARG,R5    ; SET UP ARGUMENTS FOR STRING
  46.     TSTB    @2(R5)        ; CHECK FOR ZERO LENGTH STRING
  47.     BEQ    30$        ; BAIL OUT IF ZERO LENGTH
  48.     CALL    FILL        ; AND SEND STRING
  49. 30$:    RETURN            ; AND RETURN
  50. ;
  51. ;    Here is the entry for clear screen
  52. ;
  53. CLEAR:    MOV    #CLRARG,R5    ; SET UP THE ARGUMENTS FOR FILL
  54.     CALL    FILL        ; AND CALL FILL
  55.     RETURN            ; AND RETURN
  56. ;
  57. ;    Here are the argument lists
  58. ;
  59. WRTARG:    .WORD    2        ; NUMBER OF ARGUMENTS TO FILL
  60.     .WORD    WRTSEQ        ; ADDRESS OF CURSOR SEQUENCE
  61.     .WORD    100$        ; CHAR COUNT
  62.     .WORD    0
  63. 100$:    .WORD    WRTNUM
  64.  
  65. BUFARG:    .WORD    0        ; NUMBER OF ARGUMENTS TO FILL
  66. BUFADR:    .WORD    0        ; ADDRESS OF STRING
  67. BUFCNT:    .WORD    0        ; CHAR COUNT
  68.     .WORD    0
  69.  
  70. CLRARG:    .WORD    2        ; NUMBER OF ARGUMENTS TO FILL
  71.     .WORD    CLRSEQ        ; ADDRESS OF CLEAR SCREEN SEQUENCE
  72.     .WORD    200$        ; CHAR COUNT
  73.     .WORD    0
  74. 200$:    .WORD    CLRNUM
  75. ;
  76. ;    Here are the escape sequences
  77. ;
  78.     .NLIST    BIN
  79. CLRSEQ:    .BYTE    33,110,33,'J    ; ESCAPE SEQUENCE TO CLEAR SCREEN
  80. CLRNUM=.-CLRSEQ
  81.  
  82. WRTSEQ:    .BYTE    33,'Y        ; ESCAPE SEQUENCE FOR CURSOR POSITION
  83. LINE:    .BYTE    0        ; LINE POSITION
  84. COL:    .BYTE    0        ; COLUMN POSITION
  85. WRTNUM=.-WRTSEQ
  86.     .EVEN
  87.     .END
  88.