home *** CD-ROM | disk | FTP | other *** search
/ ftp.ee.lbl.gov / 2014.05.ftp.ee.lbl.gov.tar / ftp.ee.lbl.gov / mtrek.shar.Z / mtrek.shar / wrtv10.mac < prev    next >
Text File  |  1990-04-02  |  2KB  |  91 lines
  1.     .ENABL    LC
  2.     .TITLE    WRITE
  3.     .IDENT    /MTREK/
  4. ; 
  5. ;    *** Digital Equiptment VT-100 ***
  6. ;
  7. ;    FORTRAN callable routine to postion the cursor on a crt
  8. ;    terminal and write a string. There is also a routine to
  9. ;    clear the screen.
  10. ; 
  11. ;    Calling sequence:
  12. ; 
  13. ;        CALL WRITE(LINE,ICOL,STRING[,ICNT])
  14. ; 
  15. ;    LINE    Line to position cursor on
  16. ;    ICOL    Column to position cursor on
  17. ;    STRING    String of text to output
  18. ;    ICNT    Optional character count
  19. ;
  20. ;    Calling sequence:
  21. ; 
  22. ;        CALL CLEAR
  23. ; 
  24.     .GLOBL    WRITE,CLEAR
  25.  
  26.     LUN=1            ; LUN FOR QIOS
  27.  
  28. WRITE:    MOV    @2(R5),R1    ; GET LINE POSITION
  29.     MOV    #LINE,R0    ; LOC OF BUFFER
  30.     MOV    #11012,R2    ; UNSIGNED BASE 10 TWO CHARS WIDE
  31.     CALL    $CBTA        ; GO DO IT
  32.     MOV    @4(R5),R1    ; AND COLUMN POSITION
  33.     MOV    #COL,R0        ; LOC OF COL BUFFER
  34.     MOV    #11012,R2    ; UNSIGNED BASE 10 TWO CHARS WIDE
  35.     CALL    $CBTA        ; GO DO IT
  36.  
  37.     MOV    6(R5),BUFADR    ; MOVE STRING ADDRESS TO LIST
  38.     CMPB    #4,(R5)        ; CHARACTER COUNT INPUT?
  39.     BEQ    10$        ; BRANCH IF COUNT INPUT
  40.     MOV    #1,BUFARG    ; ONLY ONE ARGUMENT TO FILL
  41.     BR    20$        ; GO DO IT
  42. 10$:    MOV    #2,BUFARG    ; TWO ARGUMENTS TO FILL
  43.     MOV    10(R5),BUFCNT    ; COPY ADDRESS OF COUNT TO LIST
  44. 20$:    MOV    #WRTARG,R5    ; SET UP ARGUMENTS FOR CURSOR
  45.     CALL    FILL        ; AND SEND CURSOR
  46.     MOV    #BUFARG,R5    ; SET UP ARGUMENTS FOR STRING
  47.     TSTB    @2(R5)        ; CHECK FOR ZERO LENGTH STRING
  48.     BEQ    30$        ; BAIL OUT IF ZERO LENGTH
  49.     CALL    FILL        ; AND SEND STRING
  50. 30$:    RETURN            ; AND RETURN
  51. ;
  52. ;    Here is the entry for clear screen
  53. ;
  54. CLEAR:    MOV    #CLRARG,R5    ; SET UP THE ARGUMENTS FOR FILL
  55.     CALL    FILL        ; AND CALL FILL
  56.     RETURN            ; AND RETURN
  57. ;
  58. ;    Here are the argument lists
  59. ;
  60. WRTARG:    .WORD    2        ; NUMBER OF ARGUMENTS TO FILL
  61.     .WORD    WRTSEQ        ; ADDRESS OF CURSOR SEQUENCE
  62.     .WORD    100$        ; CHAR COUNT
  63.     .WORD    0
  64. 100$:    .WORD    WRTNUM
  65.  
  66. BUFARG:    .WORD    0        ; NUMBER OF ARGUMENTS TO FILL
  67. BUFADR:    .WORD    0        ; ADDRESS OF STRING
  68. BUFCNT:    .WORD    0        ; CHAR COUNT
  69.     .WORD    0
  70.  
  71. CLRARG:    .WORD    2        ; NUMBER OF ARGUMENTS TO FILL
  72.     .WORD    CLRSEQ        ; ADDRESS OF CLEAR SCREEN SEQUENCE
  73.     .WORD    200$        ; CHAR COUNT
  74.     .WORD    0
  75. 200$:    .WORD    CLRNUM
  76. ;
  77. ;    Here are the escape sequences
  78. ;
  79.     .NLIST    BIN
  80. CLRSEQ:    .ASCII    <33>/[H/<33>/[J/    ; ESCAPE SEQUENCE TO CLEAR SCREEN
  81. CLRNUM=.-CLRSEQ
  82.  
  83. WRTSEQ:    .BYTE    33,'[        ; ESCAPE SEQUENCE FOR CURSOR POSITION
  84. LINE:    .BLKB    2        ; LINE POSITION
  85.     .BYTE    ';        ;
  86. COL:    .BLKB    2        ; COLUMN POSITION
  87.     .BYTE    'H        ;
  88. WRTNUM=.-WRTSEQ
  89.     .EVEN
  90.     .END
  91.