home *** CD-ROM | disk | FTP | other *** search
/ ftp.ee.lbl.gov / 2014.05.ftp.ee.lbl.gov.tar / ftp.ee.lbl.gov / mtrek.shar.Z / mtrek.shar / rdast.mac < prev    next >
Text File  |  1990-04-02  |  3KB  |  122 lines
  1.     .ENABL    LC
  2.     .TITLE    RDAST
  3.     .IDENT    /MTREK/
  4. ; 
  5. ;    This is a Fortran callable subroutine the uses
  6. ;    the IO.ATA feature of the QIO$ directive to
  7. ;    handle unsolicited input and store characters
  8. ;    in a common to allow a Fortran task access
  9. ;    the characters.
  10. ;
  11. ;    The AST routine buffers the characters until it
  12. ;    is time to issue them.
  13. ;
  14. ;    Some characters are "immediate mode" type and
  15. ;    must be issued right after receiving them.
  16. ;
  17. ;    Lower case characters are changed to upper case.
  18. ;
  19. ;    Event flag 25 is set when a line is complete.
  20. ; 
  21. ;     Calling sequence:
  22. ; 
  23. ;        CALL RDAST
  24. ; 
  25.     .MCALL    DIR$,QIO$,ASTX$S,CMKT$,CLEF$,SETF$,DECL$
  26.     .GLOBL    RDAST
  27.  
  28.     LUN = 1            ; LUN FOR QIOS
  29.     FLAG = 25.        ; EVENT FLAG
  30. ;
  31. ;    Here is where we set up to do the character AST
  32. ;
  33. RDAST:    MOV    #TMP,POINT    ; ADDRESS OF TMP BUFFER
  34.     CLR    CNT        ; CLEAR THE COUNT
  35.     CLRB    CMD        ; RESET THE LOCATION
  36.     DIR$    #SCLR        ; MAKE SURE THE FLAG IS CLEAR
  37.     DIR$    #SAST        ; SET UP FOR UNSOLICITED READ
  38.     RETURN            ; GO BACK TO MAIN
  39. ;
  40. ;    Here is the entry point when we get a character
  41. ;
  42. AST:    MOVB    (SP)+,CHAR    ; GET THE CHAR
  43.     BEQ    END        ; SKIP IT IF IT'S NULL
  44.     CMPB    #177,CHAR    ; IS IT A DELETE?
  45.     BNE    20$        ; EQUAL IF DELETE
  46.     CMP    POINT,#TMP    ; ARE THERE ANY CHARS TO DELETE?
  47.     BLOS    END        ; BRANCH IF NO CHARS TO DELETE
  48.     DEC    POINT        ; DELETE THE CHAR
  49.     BR    END        ; EXIT UNTIL NEXT TIME
  50. 20$:    CMPB    #25,CHAR    ; IS IT A KILL LINE? (^U)
  51.     BNE    30$        ; EQUAL IF YES
  52.     MOV    #TMP,POINT    ; RESET POINTER
  53.     BR    END        ; EXIT UNTIL NEXT TIME
  54. ;
  55. ;    Here is where we convert lower case to upper
  56. ;
  57. 30$:    CMPB    CHAR,#141    ; SEE IF LOWER CASE
  58.     BLO    40$        ; LOWER IF NOT LOWER CASE
  59.     CMPB    CHAR,#172    ; SEE IF LOWER CASE
  60.     BHI    40$        ; HIGHER IF NOT LOWER CASE
  61.     BICB    #40,CHAR    ; MAKE IT A UPPER CASE
  62.  
  63. 40$:    MOVB    CHAR,@POINT    ; STORE IT
  64.     INC    POINT        ; INC POINTER
  65.     CMPB    #15,CHAR    ; END OF LINE?
  66.     BEQ    ISSUE        ; ZERO IF YES
  67.     CMP    POINT,#TMP+10    ; RUN OUT OF BUFFER YET?
  68.     BHI    ISSUE        ; ISSUE IF SO
  69.     CMPB    #32,CHAR    ; CONTROL Z?
  70.     BEQ    NOW        ; ISSUE THE NOW MODE COMMAND
  71.     CMPB    #'R,CHAR    ; RESET?
  72.     BEQ    NOW        ; ISSUE THE NOW MODE COMMAND
  73.     CMPB    #'X,CHAR    ; DETONATE?
  74.     BEQ    NOW        ; ISSUE THE NOW MODE COMMAND
  75.     CMPB    #'F,CHAR    ; FADE?
  76.     BEQ    NOW        ; ISSUE THE NOW MODE COMMAND
  77.     CMPB    #'A,CHAR    ; APPEAR?
  78.     BNE    END        ; ALL FOR NOW
  79. NOW:    MOVB    #15,@POINT    ; PUT A CR IN THE LINE
  80.     INC    POINT        ; AND INCREASE THE POINTER
  81. ISSUE:    MOV    R0,-(SP)    ; SAVE R0
  82.     MOV    R1,-(SP)    ; SAVE R1
  83.     MOV    R2,-(SP)    ; SAVE R2
  84.     MOV    POINT,R0    ; LOCATION OF LAST CHAR
  85.     SUB    #TMP,R0        ; SUB FOR COUNT
  86.     MOV    R0,CNT        ; STORE COUNT
  87.     MOV    #TMP,R1        ; ADDRESS OF TMP BUFFER
  88.     MOV    #CMD,R2        ; ADDRESS OF OUT BUFFER
  89. 50$:    MOVB    (R1)+,(R2)+    ; COPY A CHAR
  90.     SOB    R0,50$        ; LOOP UNTIL DONE
  91.     MOV    #TMP,POINT    ; RESET POINTER
  92.     DIR$    #SMAR        ; CANCEL THE MARK TIME
  93.     DIR$    #SSET        ; SET THE EVENT FLAG
  94.     DIR$    #SDEC        ; DECLARE AN EVENT
  95.     MOV    (SP)+,R2    ; RESTORE R2
  96.     MOV    (SP)+,R1    ; RESTORE R1
  97.     MOV    (SP)+,R0    ; RESTORE R0
  98. END:    ASTX$S            ; EXIT THE AST ROUTINE
  99. ;
  100. ;    Local variables
  101. ;
  102. POINT:    .WORD    0        ; STORAGE FOR POINTER ADDRESS
  103. TMP:    .BLKB    10        ; TMP BUFFER
  104. CHAR:    .BYTE    0        ; CHAR TMP STORAGE
  105.     .EVEN
  106. ;
  107. ;    Directives
  108. ;
  109. SAST:    QIO$    IO.ATA,LUN,1,,,,<AST>
  110. SMAR:    CMKT$            ; CANCEL MARK TIME
  111. SCLR:    CLEF$    FLAG        ; CLEAR FLAG 25
  112. SSET:    SETF$    FLAG        ; SET FLAG 25
  113. SDEC:    DECL$            ; DECLARE A SIG EVENT
  114. ;
  115. ;    Here is the psect for the common
  116. ;
  117.     .PSECT    COMMND,D,GBL,REL,OVR
  118. CNT:    .WORD    0        ; COUNT
  119. CMD:    .BLKB    10        ; COMMAND LINE STORAGE
  120.     .EVEN
  121.     .END
  122.