home *** CD-ROM | disk | FTP | other *** search
/ Shareware Overload / ShartewareOverload.cdr / games / basgame.zip / CIVILWAR.BAS < prev    next >
BASIC Source File  |  1983-10-30  |  10KB  |  273 lines
  1. 10 KEY OFF:CLS
  2. 20 SCREEN 0
  3. 30 WIDTH 40
  4. 40 PRINT"░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░"
  5. 50 PRINT"░┌───────────────────────────────────┐░"
  6. 60 PRINT"░│                                   │░"
  7. 70 PRINT"░│            5020-A.BAS             │░"
  8. 80 PRINT"░│            CIVIL  WAR             │░"
  9. 90 PRINT"░│                                   │░"
  10. 100 PRINT"░│                                   │░"
  11. 110 PRINT"░│ BROUGHT TO YOU BY THE MEMBERS OF  │░"
  12. 120 PRINT"░│      ▄▄▄▄▄ ▄▄▄▄▄ ▄▄▄▄▄ ▄▄▄▄▄      │░"
  13. 130 PRINT"░│        █   █   █ █     █   █      │░"
  14. 140 PRINT"░│        █   █▄▄▄█ █     █   █      │░"
  15. 150 PRINT"░│        █   █     █     █   █      │░"
  16. 160 PRINT"░│      ▄▄█▄▄ █     █▄▄▄▄ █▄▄▄█      │░"
  17. 170 PRINT"░│                                   │░"
  18. 180 PRINT"░│      International PC Owners      │░"
  19. 190 PRINT"░│                                   │░"
  20. 200 PRINT"░│P.O. Box 10426, Pittsburgh PA 15234│░"
  21. 210 PRINT"░│                                   │░"
  22. 220 PRINT"░└───────────────────────────────────┘░"
  23. 230 PRINT"░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░"
  24. 240 PRINT
  25. 250 PRINT "       PRESS ANY KEY TO CONTINUE
  26. 260 A$=INKEY$: IF A$="" THEN 260
  27. 270 WIDTH 80
  28. 280 CLS
  29. 1000 CLS:KEY OFF
  30. 1010 LET L=0:LET W=0:LET R1=0:LET P1=0
  31. 1020 LET Q1=0:LET M3=0:LET M4=0
  32. 1030 LET P2=0:LET T1=0:LET T2=0
  33. 1040 REM REMARKABLE PROGRAM BY L. CRAM , L. GOODIE , AND D. HIBBARD
  34. 1050 PRINT TAB(30)"CIVIL WAR" :PRINT
  35. 1060 PRINT "DO YOU WANT DESCRIPTIONS (0=YES, 1=NO)";
  36. 1070 INPUT Z
  37. 1080 FOR U=1 TO 6 
  38. 1090 PRINT
  39. 1100 NEXT U 
  40. 1110 IF Z=1 THEN 1350
  41. 1120 PRINT "THIS IS A CIVIL WAR SIMULATION."
  42. 1130 PRINT "TO PLAY, TYPE A RESPONSE WHEN THE COMPUTER ASKS." 
  43. 1140 PRINT "REMEMBER THAT ALL FACTORS ARE INTERRELATED AND THAT YOUR" 
  44. 1150 PRINT "RESPONSES COULD CHANGE HISTORY. FACTS AND FIGURES USED ARE" 
  45. 1160 PRINT "BASED ON THE ACTUAL OCCURENCE. MOST BATTLES TEND TO RESULT" 
  46. 1170 PRINT "AS THEY DID IN THE CIVIL WAR, BUT IT ALL DEPENDS ON YOU!!"
  47. 1180 PRINT
  48. 1190 PRINT "THE OBJECT OF THE GAME IS TO WIN AS MANY BATTLES AS POSSIBLE" 
  49. 1200 PRINT
  50. 1210 PRINT "YOUR CHOICES FOR DEFENSIVE STRATEGY ARE:" 
  51. 1220 PRINT "       (1) ARTILLERY ATTACK"
  52. 1230 PRINT "       (2) FORTIFICATION AGAINST FRONTAL ATTACK"
  53. 1240 PRINT "       (3) FORTIFICATION AGAINST FLANKING MANUEVERS"
  54. 1250 PRINT "       (4) FALLING BACK"
  55. 1260 PRINT "YOUR CHOICES FOR OFFENSIVE STRATEGY ARE:" 
  56. 1270 PRINT "       (1) ARTILLERY ATTACK"
  57. 1280 PRINT "       (2) FRONTAL ATTACK"
  58. 1290 PRINT "       (3) FLANKING MANUEVERS"
  59. 1300 PRINT "       (4) ENCIRCLEMENT"
  60. 1310 PRINT "YOU MAY SURRENDER BY TYPING A '5' FOR YOUR STRATEGY." 
  61. 1320 PRINT "YOU ARE THE CONFEDERACY.       GOOD LUCK!"
  62. 1330 PRINT:PRINT "Press any key to continue"
  63. 1340 A$=INKEY$:IF A$="" THEN 1340
  64. 1350 READ M1,M2,C1,C2,M,A,U 
  65. 1360 LET I1=10+(L-W)*2
  66. 1370 LET I2=10+(W-L)*2
  67. 1380 LET D1=100*INT((M1*(100-I1)/2000)*(1+(R1-Q1)/(R1+1))+.5)
  68. 1390 LET D2=100*INT(M2*(100-I2)/2000+.5) 
  69. 1400 LET F1=5*M1/6
  70. 1410 LET A1=Z 
  71. 1420 FOR U=1 TO 4 
  72. 1430 PRINT
  73. 1440 NEXT U 
  74. 1450 PRINT "THIS IS THE BATTLE OF ";
  75. 1460 GOSUB 2460
  76. 1470 PRINT " ","CONFEDERACY","  UNION"
  77. 1480 PRINT "MEN"," ";INT(M1*(1+(P1-T1)/(M3+1)))," ";
  78. 1490 PRINT INT(M2*(1+(P2-T2)/(M4+1))) 
  79. 1500 PRINT "MONEY","$";D1,"$";D2
  80. 1510 PRINT "INFLATION"," ";I1+15;"%"," ";I2;"%" 
  81. 1520 PRINT
  82. 1530 PRINT "HOW MUCH DO YOU WISH TO SPEND FOR FOOD";
  83. 1540 INPUT F
  84. 1550 IF F<0 THEN 2410
  85. 1560 PRINT "HOW MUCH DO YOU WISH TO SPEND FOR SALARIES";
  86. 1570 INPUT S
  87. 1580 IF S<0 THEN 2410
  88. 1590 PRINT "HOW MUCH DO YOU WISH TO SPEND FOR AMMUNITION";
  89. 1600 INPUT B
  90. 1610 IF B<0 THEN 2410
  91. 1620 PRINT
  92. 1630 IF F+S+B<=D1 THEN 1660
  93. 1640 PRINT "THINK AGAIN!   YOU HAVE ONLY $" D1
  94. 1650 GOTO 1520 
  95. 1660 LET O=((2*F^2+S^2)/F1^2+1) 
  96. 1670 IF O<10 THEN 1700 
  97. 1680 PRINT "MORALE IS HIGH" 
  98. 1690 GOTO 1740 
  99. 1700 IF O<5 THEN 1730
  100. 1710 PRINT "MORALE IS FAIR" 
  101. 1720 GOTO 1740 
  102. 1730 PRINT "MORALE IS POOR" 
  103. 1740 IF M<>3 THEN 1770 
  104. 1750 PRINT "YOU ARE ON THE OFFENSIVE" 
  105. 1760 GOTO 1810 
  106. 1770 IF M<>1 THEN 1800 
  107. 1780 PRINT "YOU ARE ON THE DEFENSIVE" 
  108. 1790 GOTO 1810 
  109. 1800 PRINT "BOTH SIDES ARE ON THE OFFENSIVE"
  110. 1810 PRINT
  111. 1820 PRINT "YOUR STRATEGY";
  112. 1830 INPUT Y
  113. 1840 IF Y=5 THEN 3310 
  114. 1850 IF ABS(Y-3)<3 THEN 1880 
  115. 1860 PRINT "YOU JERK!  USE THE OTHER SET OF STRATEGIES!!" 
  116. 1870 GOTO 1810 
  117. 1880 PRINT
  118. 1890 PRINT " ","CONFEDERACY","UNION"
  119. 1900 LET C5=(2*C1/5)*(1+1/(2*(ABS(INT(4*RND(1)+1)-Y)+1))) 
  120. 1910 LET C5=INT(C5*(1+1/O)*(1.28+F1/(B+1))+.5) 
  121. 1920 IF C5+100/O<M1*(1+(P1-T1)/(M3+1)) THEN 1970 
  122. 1930 LET C5=INT(13*M1/20*(1+(P1-T1)/(M3+1)))
  123. 1940 LET E=7*C5/13
  124. 1950 LET U=1
  125. 1960 GOTO 1980 
  126. 1970 LET E=100/O
  127. 1980 PRINT "CASUALTIES",C5,INT(17*C2*C1/(C5*20)+.5)
  128. 1990 PRINT "DESERTIONS",INT(E),INT(5*O) 
  129. 2000 PRINT
  130. 2010 IF C5-C1>=0 THEN 2040 
  131. 2020 PRINT "YOUR CASUALTIES WERE"INT(100*(C1-C5)/C1+.5);"% LESS THAN"
  132. 2030 GOTO 2050 
  133. 2040 PRINT "YOUR CASUALTIES WERE"INT(100*(C5-C1)/C1+.5);"% MORE THAN"
  134. 2050 PRINT "THE ACTUAL CASUALITIES AT ";
  135. 2060 LET A1=1 
  136. 2070 GOSUB 2460
  137. 2080 IF U=1 THEN 2100
  138. 2090 IF C5+E<17*C2*C1/(C5*20)+5*O THEN 2130
  139. 2100 PRINT "YOU LOSE "; 
  140. 2110 LET L=L+1
  141. 2120 GOTO 2150 
  142. 2130 PRINT "YOU WIN ";
  143. 2140 LET W=W+1
  144. 2150 GOSUB 2460
  145. 2160 IF W=8 THEN 3330 
  146. 2170 LET T1=T1+C5+E 
  147. 2180 LET T2=T2+17*C2*C1/(C5*20)+5*O 
  148. 2190 LET P1=P1+C1 
  149. 2200 LET P2=P2+C2 
  150. 2210 LET Q1=Q1+(F+S+B)
  151. 2220 LET R1=R1+M1*(100-I1)/20 
  152. 2230 LET M3=M3+M1
  153. 2240 LET M4=M4+M2 
  154. 2250 IF A=14 THEN 3340
  155. 2260 GOTO 1350 
  156. 2270 DATA 18000,18500,1967,2708,1,1,0 
  157. 2280 DATA 40000,44894,10699,13047,3,2,0 
  158. 2290 DATA 95000,115000,20614,15849,3,3,0
  159. 2300 DATA 54000,63000,10000,14000,2,4,0 
  160. 2310 DATA 40000,50000,10000,12000,3,5,0 
  161. 2320 DATA 75000,120000,5377,12653,1,6,0 
  162. 2330 DATA 38000,45000,11000,12000,1,7,0 
  163. 2340 DATA 32000,90000,13000,17197,2,8,0 
  164. 2350 DATA 50000,70000,12000,19000,1,9,0 
  165. 2360 DATA 72500,85000,20000,23000,3,10,0
  166. 2370 DATA 66000,60000,18000,16000,2,11,0
  167. 2380 DATA 37000,60000,6700,5800,2,12,0
  168. 2390 DATA 62000,110000,17723,18000,2,13,0 
  169. 2400 DATA 65000,100000,8500,3700,1,14,0 
  170. 2410 PRINT "GO TO JAIL."
  171. 2420 PRINT "GO DIRECTLY TO JAIL." 
  172. 2430 PRINT "DO NOT PASS GO."
  173. 2440 PRINT "DO NOT COLLECT $200"
  174. 2450 GOTO 1420 
  175. 2460 IF A<>1 THEN 2530 
  176. 2470 PRINT "BULL RUN" 
  177. 2480 IF A1=1 THEN 3290
  178. 2490 PRINT"JULY 21,1861    GEN. BEAUREGARD COMMANDING THE SOUTH MET THE" 
  179. 2500 PRINT"UNION FORCES WITH GEN MCDOWELL IN A PREMATURE BATTLE AT BULL" 
  180. 2510 PRINT"RUN.  GEN. JACKSON HELPED PUSH BACK THE UNION ATTACK."
  181. 2520 GOTO 3290 
  182. 2530 IF A<>2 THEN 2590 
  183. 2540 PRINT "SHILOH" 
  184. 2550 IF A1=1 THEN 3290
  185. 2560 PRINT"APRIL 6-7,1862    THE CONFEDERATE SURPRISE ATTACK AT SHILOH"
  186. 2570 PRINT"FAILED DUE TO POOR ORGANIZATION." 
  187. 2580 GOTO 3290 
  188. 2590 IF A<>3 THEN 2660 
  189. 2600 PRINT "SEVEN DAYS" 
  190. 2610 IF A1=1 THEN 3290
  191. 2620 PRINT"JUNE 25-JULY 1,1862    GENERAL LEE (CSA) UPHELD THE OFFENSIVE"
  192. 2630 PRINT"THROUGHOUT THE BATTLE AND FORCED GEN. MCCLELLAN AND THE UNION"
  193. 2640 PRINT"FORCES AWAY FROM RICHMOND." 
  194. 2650 GOTO 3290 
  195. 2660 IF A<>4 THEN 2720
  196. 2670 PRINT "THE SECOND BULL RUN"
  197. 2680 IF A1=1 THEN 3290
  198. 2690 PRINT"AUG 29-30,1862    THE COMBINED CONFEDERATE FORCES UNDER LEE AND"
  199. 2700 PRINT"JACKSON DROVE THE UNION FORCES BACK INTO WASHINGTON." 
  200. 2710 GOTO 3290 
  201. 2720 IF A<>5 THEN 2780
  202. 2730 PRINT "ANTIETAM" 
  203. 2740 IF A1=1 THEN 3290
  204. 2750 PRINT"SEPT 17,1862    THE SOUTH FAILED TO INCORPORATE MARYLAND INTO"
  205. 2760 PRINT"THE CONFEDERACY." 
  206. 2770 GOTO 3290 
  207. 2780 IF A<>6 THEN 2840
  208. 2790 PRINT "FREDERICKSBURG" 
  209. 2800 IF A1=1 THEN 3290
  210. 2810 PRINT"DEC 13,1862 THE CONFEDERACY UNDER LEE SUCESSFULLY REPULSED" 
  211. 2820 PRINT"AN ATTACK BY THE UNION UNDER GEN. BURNSIDE."
  212. 2830 GOTO 3290
  213. 2840 IF A <>7 THEN 2890 
  214. 2850 PRINT "MURFREESBORO" 
  215. 2860 IF A1=1 THEN 3290
  216. 2870 PRINT"DEC 31,1862    THE SOUTH UNDER GEN. BRAGG WON A CLOSE BATTLE" 
  217. 2880 GOTO 3290
  218. 2890 IF A<>8 THEN 2950
  219. 2900 PRINT "CHANCELLORSVILLE" 
  220. 2910 IF A1=1 THEN 3290
  221. 2920 PRINT"MAY 1-6,1863    THE SOUTH HAD A COSTLY VICTORY AND LOST ONE"
  222. 2930 PRINT"OF THEIR OUTSTANDING GENERALS, 'STONEWALL' JACKSON."
  223. 2940 GOTO 3290
  224. 2950 IF A<>9 THEN 3010
  225. 2960 PRINT "VICKSBURG"
  226. 2970 IF A1=1 THEN 3290
  227. 2980 PRINT"JULY 4,1863    VICKSBURG WAS A COSTLY DEFEAT FOR THE SOUTH" 
  228. 2990 PRINT"BECAUSE IT GAVE THE UNION ACCESS TO THE MISSISSIPPI." 
  229. 3000 GOTO 3290
  230. 3010 IF A<>10 THEN 3070 
  231. 3020 PRINT "GETTYSBURG" 
  232. 3030 IF A1=1 THEN 3290
  233. 3040 PRINT"JUNE 30,1863    A SOUTHERN MISTAKE BY GEN. LEE AT GETTYSBURG" 
  234. 3050 PRINT"COST THEM ONE OF THE MOST CRUCIAL BATTLES OF THR WAR."
  235. 3060 GOTO 3290
  236. 3070 IF A<>11 THEN 3130 
  237. 3080 PRINT "CHICKAMAUGA"
  238. 3090 IF A1=1 THEN 3290
  239. 3100 PRINT"NOV 25,1863    AFTER THE SOUTH HAD SIEGED GEN. ROSENCRANS'" 
  240. 3110 PRINT"ARMY FOR THREE MONTHS, GEN. GRANT BROKE THE SIEGE." 
  241. 3120 GOTO 3290
  242. 3130 IF A<>12 THEN 3190 
  243. 3140 PRINT "CHATTANOOGA"
  244. 3150 IF A1=1 THEN 3290
  245. 3160 PRINT"SEPT 15,1863    CONFUSION IN A FOREST NEAR CHICKAMAUGA LED" 
  246. 3170 PRINT"TO A COSTLY SOUTHERN VICTORY."
  247. 3180 GOTO 3290
  248. 3190 IF A<>13 THEN 3250 
  249. 3200 PRINT "SPOTSYLVANIA" 
  250. 3210 IF A1=1 THEN 3290
  251. 3220 PRINT"MAY 5,1864    GRANT'S PLAN TO KEEP LEE ISOLATED BEGAN TO FAIL"
  252. 3230 PRINT"HERE, AND CONTINUED AT COLD HARBOR AND PETERSBURG." 
  253. 3240 GOTO 3290
  254. 3250 PRINT "ATLANTA"
  255. 3260 IF A1=1 THEN 3290
  256. 3270 PRINT"AUGUST, 1864   SHERMAN AND THREE VETERAN ARMIES CONVERGED ON" 
  257. 3280 PRINT"ATLANTA AND DEALT THE DEATH BLOW TO THE CONFEDERACY." 
  258. 3290 PRINT
  259. 3300 RETURN 
  260. 3310 PRINT "THE CONFEDERACY HAS SURRENDERED"
  261. 3320 GOTO 3340
  262. 3330 PRINT "THE UNION HAS SURRENDERED"
  263. 3340 PRINT
  264. 3350 PRINT "YOU HAVE WON" W; "BATTLES AND LOST" L; "BATTLES." 
  265. 3360 IF Y=5 THEN 3400 
  266. 3370 IF W<=L THEN 3400
  267. 3380 PRINT "THE CONFEDERACY HAS WON THE WAR"
  268. 3390 GOTO 3420
  269. 3400 PRINT "THE UNION HAS WON THE WAR"
  270. 3410 GOTO 3420
  271. 3420 FOR I=1 TO 2000:NEXT I
  272. 3430 CHAIN "MENU",1000
  273.