home *** CD-ROM | disk | FTP | other *** search
/ Shareware Overload / ShartewareOverload.cdr / games / basgame.zip / CIA.BAS next >
BASIC Source File  |  1983-10-29  |  18KB  |  272 lines
  1. 10 KEY OFF:CLS
  2. 20 SCREEN 0
  3. 30 WIDTH 40
  4. 40 PRINT"░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░"
  5. 50 PRINT"░┌───────────────────────────────────┐░"
  6. 60 PRINT"░│                                   │░"
  7. 70 PRINT"░│            2078-A.BAS             │░"
  8. 80 PRINT"░│               CIA                 │░"
  9. 90 PRINT"░│                                   │░"
  10. 100 PRINT"░│                                   │░"
  11. 110 PRINT"░│ BROUGHT TO YOU BY THE MEMBERS OF  │░"
  12. 120 PRINT"░│      ▄▄▄▄▄ ▄▄▄▄▄ ▄▄▄▄▄ ▄▄▄▄▄      │░"
  13. 130 PRINT"░│        █   █   █ █     █   █      │░"
  14. 140 PRINT"░│        █   █▄▄▄█ █     █   █      │░"
  15. 150 PRINT"░│        █   █     █     █   █      │░"
  16. 160 PRINT"░│      ▄▄█▄▄ █     █▄▄▄▄ █▄▄▄█      │░"
  17. 170 PRINT"░│                                   │░"
  18. 180 PRINT"░│      International PC Owners      │░"
  19. 190 PRINT"░│                                   │░"
  20. 200 PRINT"░│P.O. Box 10426, Pittsburgh PA 15234│░"
  21. 210 PRINT"░│                                   │░"
  22. 220 PRINT"░└───────────────────────────────────┘░"
  23. 230 PRINT"░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░"
  24. 240 PRINT
  25. 250 PRINT "       PRESS ANY KEY TO CONTINUE
  26. 260 A$=INKEY$: IF A$="" THEN 260
  27. 270 WIDTH 80
  28. 280 CLS
  29. 1000 REM  Translated from TRS-80 version on CPMNET BBS
  30. 1010 REM  Pete Wohlmut 10-3-82
  31. 1020 DEF SEG= &H40
  32. 1030 POKE(&H17),PEEK(&H17) OR &H20  ' set Num Lock
  33. 1040 POKE (&H17),PEEK(&H17) OR &H40 ' set Caps Lock
  34. 1050 DEF SEG
  35. 1060 CLEAR:CLS:RANDOMIZE VAL(RIGHT$(TIME$,2)):DEFINT A-Z:GOTO 1090
  36. 1070 Z9=0:FOR R=1 TO 50:IF V1$=N$(R) AND (N(R)=LO OR N(R)=-1) THEN Z9=1:RETURN
  37. 1080 NEXT:PRINT"I DON'T SEE THAT HERE.":Z9=2:RETURN
  38. 1090 PRINT "        C.I.A  ADVENTURE"
  39. 1100 DIM N1$(50),N$(50),N(50),V$(18),LO(30,4),LO$(30):FL=1:DR=0:DG=-1:T=0:EL=0:BU=0:DO=0:CA=0:BA=0:TE=0:GL=0
  40. 1110 PA=0:RO=0:FOR R=1 TO 5:R1=INT(9*RND(9)):CO$=CO$+STR$(R1):NEXT:LO=1:A9$=">"+STRING$(62,"-")+"<"
  41. 1120 R=LEN(CO$):CO$=RIGHT$(CO$,R-1)
  42. 1130 FOR R=1 TO 50:READ N1$(R),N$(R),N(R):NEXT
  43. 1140 FOR R=1 TO 30:READ LO$(R),LO(R,1),LO(R,2),LO(R,3),LO(R,4):NEXT
  44. 1150 FOR R=1 TO 18:READ V$(R):NEXT
  45. 1160 REM
  46. 1170 PRINT"WE ARE ";LO$(LO);"."
  47. 1180 FOR R=1 TO 46:IF N(R)=LO THEN PRINT"I CAN SEE ";N1$(R);"."
  48. 1190 NEXT:B=0:FOR R=1 TO 4:IF LO(LO,R)>0 THEN B=1
  49. 1200 NEXT:IF B=0 THEN 1250
  50. 1210 PRINT"WE COULD EASILY GO: ";:IF LO(LO,1)>0 THEN PRINT"NORTH  ";
  51. 1220 IF LO(LO,2)>0 THEN PRINT"SOUTH  ";
  52. 1230 IF LO(LO,3)>0 THEN PRINT"EAST  ";
  53. 1240 IF LO(LO,4)>0 THEN PRINT"WEST  ";
  54. 1250 PRINT:PRINT A9$
  55. 1260 T=T+1:IF DG>0 THEN DG=DG-1
  56. 1270 IF T=1 THEN INPUT"ENTER YOUR NAME PARTNER";NA$
  57. 1280 GOTO 2810
  58. 1290 N=0:FOR R=1 TO 46:IF N(R)=-1 THEN N=N+1
  59. 1300 NEXT
  60. 1310 PRINT:INPUT"WHAT DO YOU THINK WE SHOULD DO";A$
  61. 1320 GOSUB 2940:V$=LEFT$(A$,3):GOSUB 3000:FOR R=1 TO 18:IF V$=V$(R) THEN 1350 ELSE NEXT
  62. 1330 IF V$="ORD" THEN 3260
  63. 1340 PRINT"I DON'T KNOW HOW TO DO THAT.":GOTO 1310
  64. 1350 IF V$="QUI" THEN 2700
  65. 1360 V=R:FOR R=1 TO LEN(A$):IF MID$(A$,R,1)=" " THEN 1410 ELSE NEXT
  66. 1370 IF V$="LOO" THEN 1160
  67. 1380 IF V$="BON" THEN 2720
  68. 1390 IF V$="INV" THEN 2740
  69. 1400 PRINT"PLEASE USE 2 WORD COMMANDS SO I CAN UNDERSTAND YOU.":GOTO 1310
  70. 1410 V1$=MID$(A$,R+1,3):FOR R=1 TO 49:IF V1$=N$(R) THEN 1440 ELSE NEXT
  71. 1420 IF V1$="NOR" OR V1$="SOU" OR V1$="EAS" OR V1$="WES" THEN 1440
  72. 1430 PRINT"I DON'T KNOW WHAT IT IS YOU ARE TALKING ABOUT.":GOTO 1310
  73. 1440 ON V GOTO 1450,1580,1670,1730,1850,1890,2090,2190,2350,2370,2410,2500,2540,2590,2650,2700,2720,2740
  74. 1450 IF V1$="NOR" AND LO(LO,1)>0 THEN LO=LO(LO,1):GOTO 1160
  75. 1460 IF V1$="SOU" AND LO(LO,2)>0 THEN LO=LO(LO,2):GOTO 1160
  76. 1470 IF V1$="EAS" AND LO(LO,3)>0 THEN LO=LO(LO,3):GOTO 1160
  77. 1480 IF V1$="WES" AND LO(LO,4)>0 THEN LO=LO(LO,4):GOTO 1160
  78. 1490 IF V1$="NOR" OR V1$="SOU" OR V1$="EAS" OR V1$="WES" THEN 1570
  79. 1500 GOSUB 1070:IF Z9=2 THEN 1260
  80. 1510 IF R=8 THEN LO=5:GOTO 1160
  81. 1520 IF R=37 AND RO=1 AND LO=20 THEN LO=21:GOTO 1160
  82. 1530 IF R=10 THEN LO=11:GOTO 1160
  83. 1540 IF R=14 THEN LO=13:GOTO 1160
  84. 1550 IF R=33 THEN LO=3:GOTO 1160
  85. 1560 IF R=34 AND DO=1 THEN LO=9:GOTO 1160
  86. 1570 PRINT"I CAN'T GO THAT WAY AT THE MOMENT.":GOTO 1260
  87. 1580 GOSUB 1070:IF Z9=2 THEN 1260
  88. 1590 IF R=2 OR R=3 OR R=4 OR R=6 OR R=15 OR R=16 OR R=20 OR R=21 OR R=22 OR R=23 OR R=25 OR R=26 OR R=27 OR R=28 OR R=30 OR R=31 OR R=37 OR R=39 OR R=40 OR R=42 OR R=44 OR R=45 OR R=46 THEN 1610
  89. 1600 PRINT"I CAN'T CARRY THAT!":GOTO 1260
  90. 1610 IF N(R)=-1 THEN PRINT"I ALREADY HAVE IT.":GOTO 1260
  91. 1620 IF N>=5 THEN PRINT"I CAN'T CARRY ANYMORE.":GOTO 1260
  92. 1630 PRINT"O.K.":N(R)=-1
  93. 1640 IF V1$="PAI" AND PA=0 THEN PRINT"SOMETHING FELL FROM THE FRAME!":N(31)=LO:PA=1
  94. 1650 IF V1$="TEL" THEN TE=0
  95. 1660 GOTO 1260
  96. 1670 FOR R=1 TO 46:IF V1$=N$(R) AND N(R)=-1 THEN 1690 ELSE NEXT
  97. 1680 PRINT"I DON'T SEEM TO BE CARRYING IT.":GOTO 1260
  98. 1690 IF R=30 THEN PRINT"I DROPPED THE CUP BUT IT BROKE INTO SMALL PEICES.":PRINT"THE COFFEE SOAKED INTO THE GROUND.":N(30)=0:DR=0:GOTO 1260
  99. 1700 IF R=45 THEN GL=0
  100. 1710 IF R=31 AND N(30)=-1 THEN PRINT"O.K. I DROPPED IT.":PRINT"BUT IT FELL IN THE COFFEE!":N(31)=0:DR=1:GOTO 1260
  101. 1720 PRINT"O.K. I DROPPED IT.":N(R)=LO:GOTO 1260
  102. 1730 IF V1$="BUT" AND LO=3 AND DO=0 THEN PRINT"THE DOORS OPEN WITH A WHOOSH!":DO=1:GOTO 1260
  103. 1740 IF N(46)=-1 AND V1$="BUT" THEN PRINT"I PUSH THE BUTTON ON THE BOX AND":GOTO 1820
  104. 1750 GOSUB 1070
  105. 1760 IF Z9=2 THEN 1260
  106. 1770 IF R=17 AND GL<>1 THEN PRINT"THERE'S ELECTRICITY COURSING THRU THE SQUARE!":PRINT"I'M BEING ELECTROCUTED!":GOTO 3380
  107. 1780 IF R=35 AND BU=0 THEN PRINT"THE BUTTON ON THE WALL GOES IN .....":PRINT"CLICK! SOMETHING SEEMS DIFFFERENT NOW.":BU=1:GOTO 1260
  108. 1790 IF R=47 AND FL<>1 THEN LO(9,1)=3:FL=1:GOTO 1840
  109. 1800 IF R=48 AND FL<>2 THEN LO(9,1)=8:FL=2:GOTO 1840
  110. 1810 IF R=49 AND FL<>3 THEN LO(9,1)=10:FL=3:GOTO 1840
  111. 1820 IF N(46)=-1 AND (LO=6 OR LO=29)THEN PRINT"THERE IS A BLINDING FLASH....":FORR=1TO3000:NEXT:LO=1:FL=1:LO(9,1)=3:GOTO 1160
  112. 1830 PRINT"NOTHING HAPPENS.":GOTO 1260
  113. 1840 PRINT"THE DOORS CLOSE AND I FEEL AS IF THE ROOM IS MOVING.":PRINT"SUDDENLY THE DOORS OPEN AGAIN.":FOR R=1 TO 5000:NEXT:GOTO 1160
  114. 1850 GOSUB 1070:IF Z9=2 THEN 1260
  115. 1860 IF R=18 AND GL<>1 THEN PRINT"THE LEVER HAS ELECTRICITY COURSING THRU IT!":PRINT"I'M BEING ELECTROCUTED!":GOTO 3380
  116. 1870 IF R=18 AND EL=0 THEN PRINT"THE LEVER GOES ALL THE WAY UP AND CLICKS.":PRINT"SOMETHING SEEMS DIFFERENT NOW.":EL=1:GOTO 1260
  117. 1880 PRINT"NOTHING HAPPENS.":GOTO 1260
  118. 1890 REM
  119. 1900 IF V1$="DRA" AND LO=5 THEN PRINT"IT LOOKS FRAGILE.":GOTO 1260
  120. 1910 GOSUB 1070:IF Z9=2 THEN 1260
  121. 1920 IF R=1 AND BA<>1 THEN PRINT"THERE'S NO POWER FOR IT.":GOTO 1260
  122. 1930 IF R=1 AND TE<>1 THEN PRINT"THERE'S NO T.V. TO WATCH ON.":GOTO 1260
  123. 1940 IF R=6 THEN PRINT"IT LOOKS HEAVY.":GOTO 1260
  124. 1950 IF R=7 THEN PRINT"IT'S LOCKED.":GOTO 1260
  125. 1960 IF R=13 THEN PRINT"IT'S A VERY STRONG BAG.":GOTO 1260
  126. 1970 IF R=19 THEN PRINT"I CAN SEE A LOCKED DRAWER IN IT.":GOTO 1260
  127. 1980 IF R=22 OR R=27 THEN PRINT"THERE'S WRITING ON IT.":GOTO 1260
  128. 1990 IF R=34 AND DO=1 THEN PRINT"THE DOORS ARE OPEN.":GOTO 1260
  129. 2000 IF R=24 THEN PRINT"I CAN SEE A GLEAMING STONE IN IT.":GOTO 1260
  130. 2010 IF R=9 THEN PRINT"THERE IS A SMALL SLIT NEAR THE DOOR.":GOTO 1260
  131. 2020 IF R=34 THEN PRINT"THERE'S A BUTTON NEAR THE DOORS.":GOTO 1260
  132. 2030 IF R=41 AND BU=1 THEN PRINT"THE SCREEN IS DARK.":GOTO 1260
  133. 2040 IF R=41 THEN PRINT"I SEE A METAL PIT 1000'S OF FEET DEEP ON ONE MONITOR.":PRINT"ON THE OTHER SIDE OF THE PIT,I SEE A LARGE HOOK.":GOTO 1260
  134. 2050 IF R=43 AND BU=1 THEN PRINT"THE SCREEN IS DARK.":GOTO 1260
  135. 2060 IF R=43 THEN PRINT"I SEE A ROOM WITH A CASE ON A PEDESTAL IN IT.":GOTO 1260
  136. 2070 IF R=44 THEN PRINT"I SEE A PICTURE OF A GRINNING JACKAL.":GOTO 1260
  137. 2080 PRINT"I SEE NOTHING OF INTEREST.":GOTO 1260
  138. 2090 GOSUB 1070:IF Z9=2 THEN 1260
  139. 2100 IF R<>3 AND R<>2 AND R<>4 AND R<>28 THEN PRINT"I CAN'T INSERT THAT!":GOTO 1260
  140. 2110 INPUT"TELL ME, IN ONE WORD, INTO WHAT";A3$:A3$=LEFT$(A3$,3)
  141. 2120 R1=R:V1$=A3$:GOSUB 1070:IF Z9=2 THEN 1260
  142. 2130 IF R1=3 AND R=1 THEN PRINT"O.K.":BA=1:N(3)=0:BA=1:GOTO 1260
  143. 2140 IF R1=4 AND R=50 AND DG<=0 THEN PRINT"THE GUARD WON'T LET ME!":GOTO 1260
  144. 2150 IF R1=2 AND R=1 THEN PRINT"O.K. THE TAPE IS IN THE RECORDER.":N(2)=0:TA=1:GOTO 1260
  145. 2160 IF R1=4 AND R=50 THEN PRINT"POP! A SECTION OF THE WALL OPENS.....":PRINT"REVEALING SOMETHING VERY INTERESTING.":N(4)=0:N(5)=LO:GOTO 1260
  146. 2170 IF R1=28 AND R=29 THEN PRINT"POP! A CUP OF COFFEE COMES OUT OF THE MACHINE.":N(28)=0:N(30)=LO:GOTO 1260
  147. 2180 PRINT"NOTHING HAPPENED.":GOTO 1260
  148. 2190 REM
  149. 2200 IF V1$="DRA" AND LO=5 AND N(23)=0 THEN PRINT"IT's STUCK.":GOTO 1260
  150. 2210 GOSUB 1070:IF Z9=2 THEN 1260
  151. 2220 IF R=7 OR R=9 OR R=13 OR R=15 OR R=23 OR R=32 OR R=5 THEN 2240
  152. 2230 PRINT"I CAN'T OPEN THAT!":GOTO 1260
  153. 2240 IF R=7 AND N(16)=-1 THEN PRINT"O.K. I OPENED THE DOOR.":N(7)=0:N(8)=4:GOTO 1260
  154. 2250 IF R=9 THEN PRINT"I CAN'T. IT DOESN'T WORK.":GOTO 1260
  155. 2260 IF R=13 AND N(16)=-1 THEN PRINT"O.K. THE CLOSET IS OPENED.":N(13)=0:N(14)=14:GOTO 1260
  156. 2270 IF R=15 THEN PRINT"I CAN'T. IT'S TOO STRONG.":GOTO 1260
  157. 2280 IF R=23 THEN PRINT"IT'S STUCK.":GOTO 1260
  158. 2290 IF R=32 AND N(28)=0 AND N(4)=0 AND SC=1 THEN PRINT "I OPEN THE SCULPTURE.":PRINT"SOMETHING FALLS OUT.":N(28)=LO:N(4)=LO:GOTO 1260
  159. 2300 IF R<>5 THEN 2340
  160. 2310 INPUT"WHAT'S THE COMBINATION";C$
  161. 2320 IF C$=CO$ THEN PRINT"THE DOOR IS SLOWLY OPENING.":N(5)=0:N(9)=0:N(10)=10:GOTO 1260
  162. 2330 PRINT"YOU MUST HAVE THE WRONG COMBINATION OR YOU ARE NOT":PRINT"SAYING IT RIGHT.":GOTO 1260
  163. 2340 PRINT"I CAN'T DO THAT......YET!":GOTO 1260
  164. 2350 IF V1$="GLO" AND N(45)=-1 THEN PRINT"O.K. I'M NOW WEARING THE GLOVES.":GL=1:GOTO 1260
  165. 2360 PRINT"I CAN'T WEAR THAT!":GOTO 1260
  166. 2370 IF V1$<>"SIG" AND V1$<>"NOT" THEN PRINT"I CAN'T READ THAT.":GOTO 1260
  167. 2380 GOSUB 1070:IF Z9=2 THEN 1260
  168. 2390 IF R=22 THEN PRINT"IT SAYS:":PRINT NA$;",":PRINT"  WE HAVE DISCOVERED ONE OF CHAOSES SECRET WORDS.":PRINT"IT IS: BOND-007- .TO BE USED IN A -TASTEFUL- SITUATION.":GOTO 1260
  169. 2400 IF R=27 THEN PRINT"IT SAYS: WATCH OUT! DANGEROUS!":GOTO 1260
  170. 2410 IF V1$<>"REC" THEN PRINT"I CAN'T START THAT.":GOTO 1260
  171. 2420 GOSUB 1070:IF Z9=2 THEN 1260
  172. 2430 IF BA<>1 OR TE<>1 OR TA<>1 THEN 2490
  173. 2440 PRINT"THE RECORDER STARTS UP AND PRESENTS A SHORT MESSAGE:"
  174. 2450 PRINTNA$;","
  175. 2460 PRINT"WE HAVE UNCOVERED A NUMBER THAT MAY HELP YOU."
  176. 2470 PRINT"THAT NUMBER IS:";CO$;". PLEASE WATCH OUT FOR HIDDEN TRAPS."
  177. 2480 PRINT"ALSO, THERE IS SOMETHING IN THE SCULPTURE.":SC=1:GOTO 1260
  178. 2490 PRINT"NOTHING HAPPENED.":GOTO 1260
  179. 2500 IF V1$<>"DRA" THEN PRINT"I'M TRYING TO BREAK IT, BUT I CAN'T.":GOTO 1260
  180. 2510 IF N(6)<>-1 THEN PRINT"I CAN'T DO THAT YET.":GOTO 1260
  181. 2520 IF LO=5 THEN PRINT"IT'S HARD....BUT I GOT IT. TWO THINGS FELL OUT.":N(3)=LO:N(22)=LO:N(23)=LO:GOTO 1260
  182. 2530 PRINT"NOTHING HAPPENS.":GOTO 1260
  183. 2540 GOSUB 1070:IF Z9=2 THEN 1260
  184. 2550 IF R<>15 AND R<>24 THEN PRINT"I'M TRYING. IT DOESN'T WORK.":GOTO 1260
  185. 2560 IF N(25)<>-1 THEN PRINT"I CAN'T DO THAT YET.":GOTO 1260
  186. 2570 IF R=15 THEN PRINT"RIP! THE BAG GOES TO PIECES, AND SOMETHING FALLS OUT!":N(15)=0:N(2)=LO:GOTO 1260
  187. 2580 IF R=24 THEN PRINT"I CUT THE CASE AND REACH IN TO PULL SOMETHING OUT.":N(26)=-1:GOTO 1260
  188. 2590 IF V1$<>"ROP" THEN PRINT"I CAN'T THROW THAT.":GOTO 1260
  189. 2600 IF N(37)<>-1 THEN PRINT"I CAN'T DO THAT YET.":GOTO 1260
  190. 2610 INPUT"TELL ME,IN ONE WORD,AT WHAT";A3$:A3$=LEFT$(A3$,3)
  191. 2620 IF A3$<>"HOO" THEN PRINT"O.K. I THREW IT.":N(37)=LO:GOTO 1260
  192. 2630 IF LO<>20 THEN PRINT"I CAN'T DO THAT YET.":GOTO 1260
  193. 2640 PRINT"I THREW THE ROPE AND IT SNAGGED ON THE HOOK.":RO=1:N(37)=LO:GOTO 1260
  194. 2650 IF V1$<>"TEL" THEN PRINT"I CAN'T CONNECT THAT.":GOTO 1260
  195. 2660 IF N(40)<>LO THEN PRINT"I DON'T SEE THE TELEVISION HERE.":GOTO 1260
  196. 2670 IF TE=1 THEN PRINT"I DID THAT ALREADY.":GOTO 1260
  197. 2680 IF LO<>2 THEN PRINT"I CAN'T DO THAT....YET!":GOTO 1260
  198. 2690 PRINT"O.K. THE T.V. IS CONNECTED.":TE=1:GOTO 1260
  199. 2700 PRINT"WHAT? YOU WOULD LEAVE ME HERE TO DIE ALONE?"
  200. 2710 PRINT"JUST FOR THAT, I'M GOING TO DESTROY THE GAME.":PRINT:PRINT:PRINT:PRINT"BOOOOOOOOOOOOM!":FOR R=1 TO 5000:NEXT:GOTO 3420
  201. 2720 IF LO=14 THEN PRINT"WHOOPS! A TRAP DOOR OPENED UNDERNEATH ME AND":PRINT"I FIND MYSELF FALLING.":FOR R=1 TO 4000:NEXT:LO=17:GOTO 1160
  202. 2730 PRINT"NOTHING HAPPENED.":GOTO 1260
  203. 2740 Z8=0:PRINT"WE ARE PRESENTLY CARRYING:":FOR R=1 TO 46
  204. 2750 IF N(R)<>-1 THEN 2780
  205. 2760 PRINT N1$(R);:IF R=45 AND GL=1 THEN PRINT". WHICH I'M WEARING."ELSE PRINT" "
  206. 2770 Z8=1
  207. 2780 NEXT
  208. 2790 IF Z8=0 THEN PRINT"NOTHING"
  209. 2800 GOTO 1260
  210. 2810 IF LO=3 AND N(39)=-1 THEN PRINT"THE DOOR MAN LOOKS AT MY BADGE AND THEN THROWS ME OUT.":FOR R=1 TO 5000:NEXT:LO=1:GOTO 1160
  211. 2820 IF LO=10 AND N(42)<>-1 THEN PRINT"THE GUARD LOOKS AT ME SUSPICIOUSLY, THEN THROWS ME BACK.":FOR R=1 TO 4000:NEXT:LO=9:GOTO 1160
  212. 2830 IF LO=6 AND BU<>1 THEN PRINT"SIRENS GO OFF ALL AROUND ME!":PRINT"GUARDS RUN IN AND SHOOT ME TO DEATH!":GOTO 3380
  213. 2840 IF LO=11 AND EL<>1 THEN PRINT"THE FLOOR IS WIRED WITH ELECDRICITY!":PRINT"I'M BEING ELECTROCUTED!":GOTO 3380
  214. 2850 IF LO=10 AND N(30)=-1 AND DR=1 THEN PRINT"THE GUARD TAKES MY COFFEE":PRINT"AND FALLS TO SLEEP RIGHT AWAY.":DG=5+INT(10*RND(10)):N(11)=0:N(12)=10:DR=0:N(30)=0:GOTO 1290
  215. 2860 IF DG=0 THEN PRINT"I HEAR A NOISE LIKE SOMEONE IS YAWNING.":N(11)=10:N(12)=0:GU=-2:DG=-1:GOTO 1290
  216. 2870 IF LO=1 AND N(26)=-1 THEN PRINT"HURRAY! YOU'VE RECOVERED THE RUBY!":PRINT"YOU WIN!":GOTO 3400
  217. 2880 IF T>375 THEN PRINT"I THINK THEY ARE ON TO ME....I HEAR NOISES."
  218. 2890 IF T=400 THEN PRINT"OH NO! THEY CAUGHT UP TO ME! HELP! THEY'RE PULLING OUT GUNS!":GOTO 3380
  219. 2900 IF T=1 THEN PRINT"WRITING ON THE WALL SAYS:":PRINT"IF YOU WANT INSTRUCTIONS TYPE:ORDERS PLEASE"
  220. 2910 IF LO=6 AND LO(6,2)<>0 THEN PRINT"A SECRET DOOR SLAMS DOWN BEHIND ME!":LO(6,2)=0:GOTO 1290
  221. 2920 IF LO=10 AND GU=-2 THEN PRINT"THE GUARD DRAWS HIS GUN AND SHOOTS ME!":GOTO 3380
  222. 2930 GOTO 1290
  223. 2940 IF A$="N" THEN A$="GO NORTH":RETURN
  224. 2950 IF A$="S" THEN A$="GO SOUTH":RETURN
  225. 2960 IF A$="E" THEN A$="GO EAST":RETURN
  226. 2970 IF A$="W" THEN A$="GO WEST":RETURN
  227. 2980 IF A$="I" THEN A$="INV":RETURN
  228. 2990 RETURN
  229. 3000 IF V$="WAL" OR V$="RUN" THEN V$="GO ":RETURN
  230. 3010 IF V$="TAK" OR V$="CAR" THEN V$="GET":RETURN
  231. 3020 IF V$="LEA" THEN V$="DRO":RETURN
  232. 3030 IF V$="PRE" THEN V$="PUS":RETURN
  233. 3040 IF V$="EXA" THEN V$="LOO":RETURN
  234. 3050 IF V$="PUT" THEN V$="INS":RETURN
  235. 3060 IF V$="UNL" THEN V$="OPE":RETURN
  236. 3070 IF V$="PLA" THEN V$="STA":RETURN
  237. 3080 IF V$="SMA" THEN V$="BRE":RETURN
  238. 3090 IF V$="ATT" THEN V$="CON":RETURN
  239. 3100 IF V$="LIS" THEN V$="INV":RETURN
  240. 3110 RETURN
  241. 3120 DATA A VIDEO CASSETTE RECORDER,REC,2,A VIDEO TAPE,TAP,0,A LARGE BATTERY,BAT,0,A BLANK CREDIT CARD,CAR,0,AN ELECTRONIC LOCK,LOC,0,AN ELABORATE PAPER WEIGHT,WEI,5,A LOCKED WOODEN DOOR,DOO,4,AN OPEN WOODEN DOOR,DOO,0,A SOLID LOOKING DOOR,DOO,10
  242. 3130 DATA AN OPEN DOOR,DOO,0,AN ALERT SECURITY GUARD,GUA,10,A SLEEPING SECURITY GUARD,GUA,0,A LOCKED MAINTENANCE CLOSET,CLO,14,A MAINTENANCE CLOSET,CLO,0,A PLASTIC BAG,BAG,13,AN OLDE FASHIONED KEY,KEY,9,A SMALL METAL SQUARE ON THE WALL,SQU,16
  243. 3140 DATA A LEVER ON THE SQUARE,LEV,16,AN OLD MAHOGANY DESK,DES,5,A BROOM,BRO,13,A DUSTPAN,DUS,13,A SPIRAL NOTEBOOK,NOT,0,A MAHOGANY DRAWER,DRA,0,A GLASS CASE ON A PEDESTAL,CAS,6,A RAZOR BLADE,BLA,27,A VERY LARGE RUBY,RUB,0,A SIGN ON THE SQUARE
  244. 3150 DATA SIG,16,A QUARTER,QUA,0,A COFFEE MACHINE,MAC,8,A CUP OF STEAMING HOT COFFEE,CUP,0,A SMALL CAPSULE,CAP,0,A LARGE SCULPTURE,SCU,3,A TALL OFFICE BUILDING,BUI,1,A PAIR OF SLIDING DOORS,DOO,3,A LARGE BUTTON ON THE WALL
  245. 3160 DATA BUT,29,A PANEL OF BUTTONS NUMBERED ONE THRU THREE,PAN,9,A STRONG NYLON ROPE,ROP,17,A LARGE HOOK WITH A ROPE HANGING FROM IT,HOO,21,A C.I.A. IDENTIFICATION BADGE,BAD,-1,A PORTABLE TELEVISION,TEL,7
  246. 3170 DATA A BANK OF MONITORS,MON,7,A CHAOS I.D. CARD
  247. 3180 DATA CAR,30,A BANK OF MONITORS,MON,19,A SMALL PAINTING,PAI,23,A PAIR OF RUBBER GLOVES,GLO,13,A BOX WITH A BUTTON ON IT,BOX,24,ONE,ONE,9,TWO,TWO,9,THREE,THR,9,SLIT,SLI,10,ON A BUSY STREET,0,0,0,0,IN A VISITOR'S ROOM,0,0,3,0
  248. 3190 DATA IN THE LOBBY OF THE BUILDING,1,0,4,2,IN A DINGY ANTE ROOM,0,0,0,3
  249. 3200 DATA IN THE COMPANY PRESIDENT'S OFFICE,0,0,0,4,IN A SMALL SOUND PROOFED CUBICLE,0,12,0,0,IN A SECURITY OFFICE,0,0,8,0,IN A SMALL HALLWAY,0,14,9,7,IN A SMALL ROOM,3,0,0,0,IN A SHORT CORRIDOR,0,15,0,9,IN A HALLWAY MADE OF METAL,0,0,12,10
  250. 3210 DATA IN A SMALL PLAIN ROOM,6,0,0,11
  251. 3220 DATA IN A MAINTENANCE CLOSET,0,0,14,0,IN A CAFETERIA,8,0,0,0,IN A SIDE CORRIDOR,10,0,16,0,IN A POWER GENERATOR ROOM,0,0,0,15,IN A SUB-BASEMENT BELOW THE CHUTE,0,0,18,0,IN THE ENTRANCE TO THE SECRET COMPLEX,0,20,19,17
  252. 3230 DATA IN A SECRET MONITORING ROOM,0,0,0,18,ON A LEDGE IN FRONT OF A METAL PIT 1000'S OF FEET DEEP,18,0,0,0,ON THE OTHER SIDE OF THE PIT,0,0,22,0,IN A LONG CORRIDOR,0,25,23,21,IN A LARGE ROOM,0,26,0,22,IN A SECRET LABORATORY,0,0,25,0
  253. 3240 DATA IN A NARROW CROSS CORRIDOR,22,0,0,24,IN A CROSS EXAMINATION ROOM,23,28,0,0,IN A SMALL BATHROOM,0,0,28,0,IN THE OFFICE OF THE CHIEF OF CHAOS,26,30,0,27,IN THE CHAOS CONTROL ROOM,0,0,30,0,NEAR THE END OF THE COMPLEX,28,0,0,29
  254. 3250 DATA "GO ",GET,DRO,PUS,PUL,LOO,INS,OPE,WEA,REA,STA,BRE,CUT,THR,CON,QUI,BON,INV
  255. 3260 PRINT"YOUR MISSION,";NA$;",IS TO RECOVER A RUBY THAT IS BEING"
  256. 3270 PRINT"USED IN TOP SECRET GOVERNMENT PROJECTS AS A PART IN A"
  257. 3280 PRINT"LASER PROJECTOR."
  258. 3290 PRINT"  YOU WILL HAVE A PARTNER WHO IS NOT TOO BRIGHT AND NEEDS"
  259. 3300 PRINT"YOU TO TELL HIM WHAT TO DO. USE TWO WORD COMMANDS LIKE:"
  260. 3310 PRINT:PRINT"              GET NOTEBOOK   GO WEST  LOOK DOOR"
  261. 3320 PRINT:PRINT"SOME COMMANDS USE ONLY ONE WORD. EXAMPLE: INVENTORY"
  262. 3330 PRINT"  IF YOU WANT TO SEE CHANGES IN YOUR SURROUNDINGS TYPE: LOOK"
  263. 3340 PRINT"THE RUBY HAS BEEN CAPTURED BY A SECRET SPY RING KNOWN AS"
  264. 3350 PRINT"CHAOS. WE SUSPECT THEY ARE UNDER COVER SOMEWHERE IN THIS"
  265. 3360 PRINT"NEIGHBORHOOD. GOOD LUCK!"
  266. 3370 GOTO 1290
  267. 3380 FOR R=1 TO 5000:NEXT:PRINT"I'M DEAD!"
  268. 3390 PRINT"YOU DIDN'T WIN."
  269. 3400 INPUT"WOULD YOU LIKE TO TRY AGAIN (Y/N)";Z$
  270. 3410 IF Z$="Y" THEN RUN
  271. 3420 END
  272.