home *** CD-ROM | disk | FTP | other *** search
/ Shareware Overload / ShartewareOverload.cdr / games / alpha.zip / PLAR3W.BAS < prev    next >
BASIC Source File  |  1987-01-01  |  4KB  |  110 lines
  1. 10 REM Copyright 1987, Arnold B. Krueger, Grosse Pointe Woods, MI. 48236
  2. 20 DEF FNPHLP1(W,WC,D) =  ATN(W/WC)
  3. 30 DEF FNPHHP1(W,WC,D) =  ATN(WC/W)
  4. 40 DEF FNPHLP2(W,WC,D) = -ATN( D*W /(WC*(1.000001-(W/WC)^2 ) ) ) + PI*(W>WC)
  5. 50 DEF FNPHHP2(W,WC,D) =  ATN( D*WC/(W *(1.000001-(WC/W)^2 ) ) ) - PI*(W<WC)
  6. 60 DEF FNAMLP1(W,WC,D) = 1 / SQR(1!+(W/WC)^2)
  7. 70 DEF FNAMHP1(W,WC,D) = 1 / SQR(1!+(WC/W)^2)
  8. 80 DEF FNAMLP2(W,WC,D) = 1 / SQR(1+(W/WC)^4+(D*D-2!)*(W/WC)^2)
  9. 90 DEF FNAMHP2(W,WC,D) = 1 / SQR(1+(WC/W)^4+(D*D-2.000001)*(WC/W)^2)
  10. 100 DEF FNDBV(AMP)      = 20!*LOG(AMP)*LOGCONV
  11. 110 DEF FNPHD(RAD)     = 180!*RAD/PI
  12. 120 DEF FNSUMA(AA,AB,PA,PB) = SQR((AA*SIN(PA)+AB*SIN(PB))^2 + (AA*COS(PA)+AB*COS(PB))^2 )
  13. 130 DEF FNSUMPW(AA,AB,PA,PB) = SQR((AA*AA*SIN(PA)+AB*AB*SIN(PB))^2 +                                               (AA*AA*COS(PA)+AB*AB*COS(PB))^2 )
  14. 140 DEF FNSUMPN(AA,AB,PA,PB) =   AA*SIN(PA)+AB*SIN(PB)
  15. 150 DEF FNSUMPD(AA,AB,PA,PB) =   AA*COS(PA)+AB*COS(PB)
  16. 160 DEF FNDIRF(AA,AB,PA,PB) = ABS((SIN((PA-PB))*(((AA >= AB)*AB/AA)+((AB > AA)*AA/AB)  )))
  17. 170 PI = ATN(SQR(3!))*3
  18. 180 LOGCONV=1!/LOG(10!)
  19. 190 LOGCONV=1!/LOG(10!)
  20. 200 DIM FREQT(20)
  21. 210 FREQT(1)=20:FREQT(2)=22:FREQT(3)=25:FREQT(4)=28:FREQT(5)=32:FREQT(6)=36
  22. 220 FREQT(7)=40:FREQT(8)=44:FREQT(9)=50:FREQT(10)=56:FREQT(11)=64:FREQT(12)=72
  23. 230 FREQT(13)=80:FREQT(14)=88:FREQT(15)=100:FREQT(16)=112
  24. 240 FREQT(17)=128:FREQT(18)=144:FREQT(19)=160:FREQT(20)=180
  25. 250 SCREEN 2 : KEY OFF : CLS
  26. 260 XS = ( LOG(20000)-LOG(20) )*LOGCONV
  27. 270 REM Driver parameters:
  28. 280 N$ = "AR3W Model"
  29. 290 F1 = 45!
  30. 300 Q1 = 1.1
  31. 310 F2 = 1200
  32. 320 Q2 = 1.1
  33. 330 W1 = 2!*PI*F1
  34. 340 D1  = 1!/Q1
  35. 350 W2 = 2!*PI*F2
  36. 360 D2 = 1!/Q2
  37. 370 X = 1
  38. 380    LINE(52,1)-(639,1)
  39. 390    LINE(52,180)-(639,180)
  40. 400 FOR X = 52 TO 640 STEP 16
  41. 410    FOR ROW = 22.5 TO 157.5 STEP 22.5
  42. 420       LINE(X,ROW)-(X+1,ROW)
  43. 430    NEXT ROW
  44. 440 NEXT X
  45. 450 TOGGLE = 0
  46. 460 FOR OCT  = 0 TO 4  
  47. 470 DECADE = 10^OCT
  48. 480 XSCALE = 75!*(LOG(20!*DECADE)-2.3)
  49. 490 LINE(XSCALE,1)-(XSCALE,180)
  50. 500 XSCALE = 75!*(LOG( 50!*DECADE)-2.3)
  51. 510 LINE(XSCALE,1)-(XSCALE,180)
  52. 520 XSCALE = 75!*(LOG(100!*DECADE)-2.3)
  53. 530 LINE(XSCALE,1)-(XSCALE,180)
  54. 540 XSCALE = XSCALE + 1
  55. 550 LINE(XSCALE,1)-(XSCALE,180)
  56. 560 FOR NOTE = 1 TO 20
  57. 570   F = FREQT(NOTE)*DECADE
  58. 580   IF F > 50000! THEN GOTO 790
  59. 590   W = 2!*F*PI
  60. 600   XP = 75!*(LOG(F)-2.3)
  61. 610   Y  = FNAMHP2(W,W1,D1)*FNAMLP2(W,W2,D2)
  62. 620   YD = FNDBV(Y)
  63. 630   YP = (20!-YD)*4.5
  64. 640   IF YP<10 THEN YP = 10
  65. 650   IF YP>180 THEN YP = 180
  66. 660   IF OCT=0 THEN IF NOTE = 1 THEN GOTO 680
  67. 670   LINE(XP,YP)-(OLDX,OLDY)
  68. 680   REM OLDX = XP
  69. 690   OLDY = YP
  70. 700   Y = FNPHHP2(W,W1,D2)+FNPHLP2(W,W2,D2)
  71. 710   YD = FNPHD(Y)
  72. 720   YQ = 90-YD/2
  73. 730   IF OCT=0 THEN IF NOTE=1 THEN GOTO 760
  74. 740   IF TOGGLE = 0 THEN TOGGLE = 1 ELSE TOGGLE = 0
  75. 750   IF TOGGLE = 0 THEN LINE(XP,YQ) - (OLDX,OLDYQ)
  76. 760   OLDYQ = YQ
  77. 770   OLDX = XP
  78. 780 NEXT NOTE
  79. 790 NEXT OCT
  80. 800 LOCATE  1,1
  81. 810 PRINT USING "#### d";180;
  82. 820 LOCATE 23,1
  83. 830 PRINT USING "#### d";-180;
  84. 840 LOCATE 12,1
  85. 850 PRINT USING "### dB";0!;
  86. 860 LOCATE  6,1
  87. 870 PRINT USING "### dB";10!;
  88. 880 LOCATE 17,1
  89. 890 PRINT USING "### dB";-10!;
  90. 900 LOCATE 24,4
  91. 910 PRINT USING "### Hz";20!;
  92. 920 LOCATE 24,19
  93. 930 PRINT USING "### Hz";100!;
  94. 940 LOCATE 24,40
  95. 950 PRINT USING " ## kHz";1!;
  96. 960 LOCATE 24,62
  97. 970 PRINT USING "### kHz";10!;
  98. 980 LOCATE 24,70
  99. 990 PRINT USING "### kHz";20!;
  100. 1000 LOCATE 2,40
  101. 1010 PRINT USING "          &          ";N$;
  102. 1020 LOCATE 3,40
  103. 1030 PRINT USING "     &";"Amplitude:       Phase:          ";
  104. 1040 LINE(450,20)-(465,20)
  105. 1050 LINE(550,20)-(565,20),,,&HF0F0
  106. 1060 LOCATE 4,40
  107. 1070 PRINT USING "Fl: ##### Q1: #.## F2: ##### Q2: #.##";F1;Q1;F2;Q2;
  108. 1080 LOCATE 2,1
  109. 1090 END
  110.