home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Shareware Overload
/
ShartewareOverload.cdr
/
games
/
alpha.zip
/
LOPASS.BAS
< prev
next >
Wrap
BASIC Source File
|
1986-12-31
|
1KB
|
34 lines
5 REM Copyright 1986, Arnold B. Krueger, Grosse Pointe Woods, MI, 48236
10 DEF FNAMLP2(W,WC,D) = 1 / SQR(1+(WC/W)^4+(D*D-2.000001)*(WC/W)^2)
20 DEF FNDBV(AMP) = 20!*LOG(AMP)/LOG(10!)
30 PI = ATN(SQR(3!))*3!
40 PRINT "Unity Gain Low Pass Filter Program"
50 INPUT "Enter desired Q: hit enter for Butterworth (.707) ",Q
60 IF Q = 0 THEN Q = 1!/SQR(2!)
70 INPUT "Enter desired Design Frequency: (1000 Hz) ",F
80 IF F = 0 THEN F = 1000
90 SCALF = 1000!/F
100 INPUT "Enter desired C1 values: (10,000 pF) ",C
110 IF C = 0 THEN C = 10000
120 SCALC = 16000/C
130 R = 10000!*SCALC*SCALF*Q*2!
140 C2 = C*.25/(Q*Q)
150 PRINT "C1 = ";C;"pF C2 = ";C2;"pF"
155 PRINT " R(1) & R(2) = ";R;" R feedback ";2!*R;"ohms"
160 F1 = 2!*F
170 F2 = F/2
180 W1 = F1*2!*PI
190 W2 = F2*2!*PI
200 W = F *2!*PI
210 D = 1! / Q
220 AMP1 = FNAMLP2(W1,W,D)
230 AMP2 = FNAMLP2(W2,W,D)
240 AMP = FNAMLP2(W,W,D)
250 AMP1DB = FNDBV(AMP1)
260 AMP2DB = FNDBV(AMP2)
270 AMPDB = FNDBV(AMP)
280 PRINT "F(half design) ";F2;"Hz,response ";AMP1DB;" dB"
290 PRINT "F(design) ";F;"Hz, response ";AMPDB;" dB"
300 PRINT "F(double design) ";F1;"Hz response ";AMP2DB;" dB"