home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Shareware Overload
/
ShartewareOverload.cdr
/
comm
/
qns311.zip
/
Q-MM1.SCR
< prev
next >
Wrap
Text File
|
1991-02-19
|
4KB
|
76 lines
;┌──────────────────────────────────────────────────────────────────────────┐
;│ Q-MM1.SCR Copyright 1988-1991 by Rik Brown │
;│ │
;│ Markmail 1.x door script │
;└──────────────────────────────────────────────────────────────────────────┘
SEND "^~OPEN $maildoor^M" ; Open netmail door
WHEN ; Clear all WHENs
WHEN "(NS)?" "^~N^M"
WHEN "upcoming board function" LOGOFF ; Logoff if event is non-sliding
WHEN "Fatal Error" LOGOFF ; Logoff if door problem
TIMEOUT 40 DIALSEQUENCE ; Wait max 40 secs for next line
WAITFOR "ommand?"
ULMAIL:
WHEN
WHEN "NO CARRIER" DIALSEQUENCE ; Error handling (carrier loss)
EXIST $maildir\SUCCESS.SND DLMAIL ; Error handling (carrier loss)
IF "$2" = "0" DLMAIL ; Download mail if no mail to send
IF "$4" = "$maxulmail" DLMAIL ; Counter check: ul attempts
INCR 4 ; Increment ULMAIL counter
SEND "^~^M" ; Get "command" prompt
TIMEOUT 10 DLMAIL ; Online test (grab command prompt)
WAITFOR "ommand?"
SEND "^~U^M" ; Upload current mail packet
TIMEOUT 60 DIALSEQUENCE ; Wait max 60 seconds for ready
WAITFOR "(Ctrl-X) Aborts Transfer" ; MarkMail door is read to receive
PAUSE 1000 ; Pause 1 sec (or overrun next cmd)
DOS "qnssz.bat $maildir $mailUL" ; Call transfer BAT file
IF $OFFLINE DIALSEQUENCE ; Error handling (carrier loss)
PAUSE 1000
DOS "if exist $maildir\SUCCESS.SND del $maildir\$mailUL"
; If mail upload was successful, it will be deleted. But if mail upload
; failed, it will be uploaded the next time the script is run. In this
; way no replies are lost. Pending mail files must be successfully uploaded
; before a totally new mail file can be created.
CLRSCR ; Exit DSZ status line
EXIST $maildir\SUCCESS.SND DLMAIL ; Set to your location
PAUSE 6000 ; 6 sec pause for door to recycle
GOTO ULMAIL
DLMAIL:
WHEN
WHEN "NO CARRIER" DIALSEQUENCE ; Error handling (carrier loss)
WHEN "No Messages Found" LOGOFF ; Skip download if no mail is found
WHEN "[G]oodbye When Done?" "^~^~Y^M" ; Download the packet. No auto-logoff
WHEN "Error Zip'ing Packet" DLMAIL ; Try again if error
WHEN "Pointers NOT Updated" DLMAIL ; Try again if error
EXIST $maildir\SUCCESS.RCV LOGOFF ; Error handling (prior carrier loss)
IF "$3" = "$maxdlmail" LOGOFF ; Counter check: dl attempts
INCR 3 ; Increment DLMAIL counter
SEND "^~^M" ; Get "command" prompt
TIMEOUT 60 LOGOFF ; Keep large
WAITFOR "ommand?"
SEND "^~D^M" ; Download mail packet
TIMEOUT 2000 DIALSEQUENCE ; Wait max 20 minutes for packet
WAITFOR "(Ctrl-X) Aborts Transfer" ; Wait for file to compress
PAUSE 1000 ; Pause 1 sec (or overrun next cmd)
DOS "if exist $maildir\$mailDL del $maildir\$mailDL"
; Delete any prior non-completed Zmodem download of a incoming mail file
DOS "qnsrz.bat $maildir $mailDL" ; Call transfer BAT file
IF $OFFLINE DIALSEQUENCE ; Error handling (carrier loss)
CLRSCR ; Exit DSZ status line
EXIST $maildir\SUCCESS.RCV LOGOFF ; Log off is DL successful
PAUSE 10000 ; 10 sec pause for door to cycle
GOTO DLMAIL ; Try again if unsuccessful
RETURN
DIALSEQUENCE:
SCRIPT Q-LOGON.SCR
LOGOFF:
SCRIPT Q-LOGOFF.SCR