home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Shareware Overload
/
ShartewareOverload.cdr
/
comm
/
qns311.zip
/
Q-LOGON.SCR
< prev
next >
Wrap
Text File
|
1991-02-19
|
8KB
|
164 lines
;┌──────────────────────────────────────────────────────────────────────────┐
;│ Q-LOGON.SCR Copyright 1988-1991 by Rik Brown │
;│ │
;│ Log on script │
;└──────────────────────────────────────────────────────────────────────────┘
ASSIGN 6 0 ; Set 0 = 1st time or carrier drop
DIALSEQUENCE:
HANGUP ; Drop any prior connection
IF "$0" >= "$maxdial" LOGOFF ; Check max # of dial attempts
IF "$1" >= "$maxconn" LOGOFF ; Check max # of handshake attempts
IF "$4" >= "$maxulmail" LOGOFF ; Quit if max UL attempts reached
IF "$3" >= "$maxdlmail" LOGOFF ; Quit if max DL attempts reached
INCR 0 ; Dials Counter
IF "$6" = "0" INITIAL_SCREEN ; Setup screen if carrier drop
IF "$0" >= "2" UPDATE_SCREEN ; Update Screen if Dial is 2 or greater
INITIAL_SCREEN:
INCR 6 ; Flag to indicate first attempt
; (1st attempt after carrier loss, too)
ATWRITE 1 1 $scrcolor "┌──────────────────────────────────────────────────────────────────────────────┐"
ATWRITE 1 2 $scrcolor "│ │"
ATWRITE 29 2 $titlecolor "QNS v3.11 (02/19/90)"
ATWRITE 1 3 $scrcolor "│ │"
ATWRITE 23 3 $titlecolor "Copyright 1988-1991 by Rik Brown"
ATWRITE 1 4 $scrcolor "├──────────────────────────────────────────────────────────────────────────────┤"
ATWRITE 1 5 $scrcolor "│ Calling to: │"
ATWRITE 38 5 $titlecolor "$bbsname"
ATWRITE 1 6 $scrcolor "│ Will upload: │"
ATWRITE 38 6 $titlecolor "$2 $mailUL"
ATWRITE 1 7 $scrcolor "│ │"
ATWRITE 1 8 $scrcolor "│ Phone 1: │"
ATWRITE 38 8 $titlecolor "$phone1"
ATWRITE 1 9 $scrcolor "│ Phone 2: │"
ATWRITE 38 9 $titlecolor "$phone2"
ATWRITE 1 10 $scrcolor "│ │"
ATWRITE 1 11 $scrcolor "│ STARTED: on Handshake attempts: │"
ATWRITE 1 12 $scrcolor "│ CURRENT: on Dialing attempts: │"
ATWRITE 1 13 $scrcolor "├──────────────────────────────────────────────────────────────────────────────┤"
ATWRITE 1 14 $scrcolor "│ The latest version of QNS is available at TRAVEL ONLINE BBS │"
ATWRITE 1 15 $scrcolor "│ 30,000 Files & 140+ Conferences with Upload Credits for Messages │"
ATWRITE 1 16 $scrcolor "│ (314) 973-4073 Hayes v.32 ■ St. Louis, MO (PC-Pursuit) │"
ATWRITE 1 17 $scrcolor "│ (314) 625-4045 Hayes v.32 ■ St. Charles, MO (Contel) │"
ATWRITE 1 18 $scrcolor "└──────────────────────────────────────────────────────────────────────────────┘"
GOTOXY 1 1
GETSCR
UPDATE_SCREEN:
GOTOXY 1 1
PUTSCR
ATWRITE 14 11 $startcolor "$stime"
ATWRITE 26 11 $startcolor "$sdate"
ATWRITE 69 11 $startcolor "$1 of $maxconn"
ATWRITE 14 12 $currentclr "$time"
ATWRITE 26 12 $currentclr "$date"
ATWRITE 69 12 $currentclr "$0 of $maxdial"
IF "$5" = "1" PHONE1
IF "$5" = "2" PHONE2
PHONE1:
ATWRITE 27 9 $scrcolor " "
ATWRITE 27 8 $scrcolor ">"
GOTO DIAL_ROTATE
PHONE2:
ATWRITE 27 8 $scrcolor " "
ATWRITE 27 9 $scrcolor ">"
GOTO DIAL_ROTATE
DIAL_ROTATE:
GOTOXY 1 19
; Following NOTE lines end with alt-255 which is required (do not change)
NOTE
NOTE
NOTE
NOTE
NOTE
GOTOXY 1 19
FLUSH ALL ; Flush COM port and keyboard buffer
IF "$5" = "1" DIAL1 ; if counter = 1 go to dial 1
IF "$5" = "2" DIAL2 ; if counter = 1 go to dial 2
IF "$5" = "3" DIAL1 ; if counter = 3 go to dial 1
DIAL1:
ASSIGN 5 1 ; reset counter to 1 if = 3
SEND "^~^~^~^~ATDp $PHONE1^M" ; call phone1
INCR 5 ; Increase counter: dial rotation
GOTO DIAL_CONNECT
DIAL2:
SEND "^~^~^~^~ATDp $PHONE2^M" ; call phone2
INCR 5 ; Increase counter: dial rotation
GOTO DIAL_CONNECT
DIAL_CONNECT:
WHEN ; Clear all WHENs
WHEN "RING" DIALSEQUENCE ; Redial if incoming call rings
WHEN "BUSY" DIALSEQUENCE ; Redial if BUSY message
WHEN "NO DIALTONE" DIALSEQUENCE ; Redial if NO DIALTONE message
WHEN "NO CONNECT" DIALSEQUENCE ; Redial if NO CONNECT message
WHEN "NO CARRIER" DIALSEQUENCE ; Redial if NO CARRIER message
TIMEOUT 60 CARRIERDROP ; Redial if no carrier within 60 secs
WAITFOR "CARRIER $minbaud" ; (Keep 60 secs or can fail)
INCR 1 ; Increase handshake counter by 1
NOTE
NOTE ----------------------------------------------------------------------
NOTE ATTEMPT STATS: DIALS ($0) HANDSHAKES ($1) TIME ($TIME $DATE)
NOTE ----------------------------------------------------------------------
NOTE
; ALT-255 at end of 1st and last NOTE line above (do not alter)
; If the script has executed this far a CARRIER has been detected. The
; following sequence ensures the minimum connect baud rate occurs.
WHEN ; Clear all WHENs
WHEN "NO CARRIER" CARRIERDROP ; Redial if carrier drops
WHEN "(Enter)=no change?" "^~^~$language^M" ; Use PCB Script Prompts
TIMEOUT 10 MNP ; Handling for BBS MNP modems
WAITFOR "(Enter)=no?"
MNP:
SEND "^~^~N Q^M" ; Non-graphic & quick log on
; Once the script has executed this far then the following lines will take
; us up to the Command prompt.
WHEN
WHEN "first name?" "^~^~$names^M" ; Send first & last name
WHEN "try again ..." "^~^~$names^M" ; Resend names if garbled
WHEN "(Dots will echo)?" "^~^~$pword^M" ; Send password
WHEN "password entered!" "^~^~$pword^M" ; Resend password if garbled
WHEN "orrect?" "^~Y^M" ; Correct city prompt
WHEN "(H)elp, More?" "^~N^M" ; Avoid successive screens
WHEN "(Enter)" "^~N^M" ; Avoid successive screens
WHEN "Access Denied" LOGOFF ; LOGOFF if access denied
WHEN "Time Limit Exceeded" LOGOFF ; LOGOFF if time exceeded
WHEN "NO CARRIER" CARRIERDROP ; Redial if carrier drops
TIMEOUT 60 DIALSEQUENCE ; Wait max 60 secs for
WAITFOR "ommand?" ; Command prompt
WHEN ; Clear all WHENS
RETURN ; Return to calling script
CARRIERDROP:
SCRIPT $CMDSCRIPT
LOGOFF:
SCRIPT Q-LOGOFF.SCR