home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er 1995 June
/
64er_Magazin_95-06_1995_Markt__Technik_de_Side_B.d64
/
eingabe
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2022-10-26
|
1KB
|
41 lines
6999 rem daten eingeben
7000 if fl=0 then print"[203]eine [196]atei im [210]echner!": return
7010 printchr$(147)chr$(18)" [196]ateneingabe-[205]aske "chr$(13)
7020 printtab(2)"[206]achname: "
7022 printtab(2)"[214]orname : "
7024 printtab(2)"[211]trasse : "
7026 printtab(2)"[208][204][218] : "
7028 printtab(2)"[215]ohnort : "
7030 printtab(2)"[212]elefon : "
7040 sp=12: rem eingabespalte bleibt gleich!
7045 for zl=2 to 7
7047 gosub 7900: rem eingabe-cursor positionieren
7050 poke19,64:inputds$(zl-2):poke19,0:print
7060 next zl
7070 rem eingabe in indexdatei vermerken
7080 ad=ad+1: rem datensatzanzahl inkrementieren
7090 id$(ad)=ds$(1): rem schluesseldatenfeld
7100 in(ad)=rn: rem recordnummer
7110 :
7120 rem datenfelder mit passender laenge ausstatten
7130 gosub 5000: rem unterprogramm muss auf sechs datenfelder eingerichtet sein
7199 :
7200 rem dateneingabe zur speicherung zusammenfassen
7210 rc$="": rem evtl. record-inhalt loeschen
7220 for c=1 to 6
7222 rc$=rc$+ds$(c)
7224 next c
7228 :
7229 rem datensatz speichern
7230 :
7240 rn=ad:rp=1:gosub 2000: rem record positionieren
7250 print#lf,rc$: rem datensatz schreiben
7260 gosub 4000: rem fehlerkanal
7270 printchr$(13)tab(2)chr$(18)" [196]atensatz wurde gesichert!"
7280 return
7888 :
7899 rem up cursor-positionierung
7900 poke214,zl:poke 211,sp
7902 sys 58640
7904 return