home *** CD-ROM | disk | FTP | other *** search
/ 64'er 1987 September / 64er_Magazin_87-09_1987_Markt__Technik_de_Side_A.d64 / hilbert (.txt) < prev    next >
Commodore BASIC  |  2022-10-26  |  2KB  |  60 lines
  1. 10 rem ****************************
  2. 20 rem *      hilbert-kurve       *
  3. 30 rem ****************************
  4. 40 :
  5. 50 if a=0 then a=1:load "fractal.obj"
  6. 60 :
  7. 70 open 1,8,15,"u9":close 1: rem diese zeeile kann bei problemen mit dem
  8. 80 rem floppyspeeder weggelassen werden!
  9. 90 poke53280,0:poke53281,0
  10. 100 input "[147]grad ";gr
  11. 110 sp=95/2^(gr):se=95/2^(gr-1):xp=65+sp:yp=195-sp:w=0:r=1
  12. 120 :
  13. 130 sys 50176,14,0:sys 50179,1:sys 50194:rem grafik ein
  14. 140 :
  15. 150 gosub 300: rem 'hilbert' aufrufen
  16. 160 sys 50185,0,0,319,0,1:sys 50185,319,0,319,199,1
  17. 170 sys 50185,319,199,0,199,1:sys 50185,0,199,0,0,1
  18. 180 get a$:if a$="" goto 180
  19. 190 sys 50179,0:if a$="s" then gosub 700: rem 'grafik speichern'
  20. 200 goto 60: rem neustart
  21. 260 :
  22. 270 :
  23. 280 rem ***************************
  24. 290 rem *      'hilbert'          *
  25. 300 rem ***************************
  26. 310 :
  27. 320 if gr=0 then return
  28. 330 w=w-90*r: rem 'drehe'
  29. 340 gr=gr-1:r=-r:gosub 300:r=-r: rem 'hilbert'
  30. 350 s=se:gosub 500: rem 'schreite'
  31. 360 w=w+90*r: rem 'drehe'
  32. 370 gosub 300: rem 'hilbert'
  33. 380 s=se:gosub 500: rem 'schreite'
  34. 390 gosub 300: rem 'hilbert'
  35. 400 w=w+90*r: rem 'drehe'
  36. 410 s=se:gosub 500: rem 'schreite'
  37. 420 r=-r:gosub 300:r=-r:gr=gr+1: rem 'hilbert'
  38. 430 w=w-90*r: rem 'drehe'
  39. 440 return
  40. 450 :
  41. 460 :
  42. 470 rem ***************************
  43. 480 rem *      'schreite'         *
  44. 490 rem ***************************
  45. 500 :
  46. 510 xs=s*cos(w*(NULL)/180)
  47. 520 ys=s*sin(w*(NULL)/180)
  48. 530 xp=xp+xs:yp=yp+ys
  49. 540 sys 50185,xp-xs,yp-ys,xp,yp,1:rem linie
  50. 550 return
  51. 650 :
  52. 660 :
  53. 670 rem ***************************
  54. 680 rem *   'grafik speichern'    *
  55. 690 rem ***************************
  56. 700 :
  57. 710 input "grafik-name ";n$
  58. 720 open 2,8,2,"pi."+n$+",p,w":sys 50191:close 2
  59. 730 return
  60.