home *** CD-ROM | disk | FTP | other *** search
/ Compute! Gazette 1988 October / 1988-10.d64 / speedprint.bas (.txt) < prev    next >
Commodore BASIC  |  2022-09-20  |  2KB  |  64 lines
  1. 10 rem copyright 1988 compute! publications, inc. - all rights reserved.
  2. 20 ifll=1then100
  3. 30 ifll=2then420
  4. 40 gosub540
  5. 50 ss$="speedscript 3.2":rem speedscript filename to boot
  6. 60 fc$="[187]":rem font-change code
  7. 70 tp$="[163]":rem temporary font-change code
  8. 80 re$="[178]":rem restore-font code
  9. 90 print"[147][208]lease wait....":ll=1:load"speedprint.ml",8,1
  10. 100 pokefc,asc(fc$):poketp,asc(tp$):pokere,asc(re$)
  11. 110 gosub180:gosub250:iffi$<>""andnf<11then110
  12. 120 print"[147][194]ooting "ss$"...."
  13. 130 print"[144]load"qu$ss$qu$",8"
  14. 140 print"sys49152"
  15. 150 print"poke2473,"fnh(mem)+1:print"run"
  16. 160 fori=631to636:pokei,13:next:poke198,8:poke637,147:poke638,89
  17. 170 print"":end
  18. 180 print"[147]"tab(10)"[211]peed[208]rint [194]ooter"
  19. 190 printtab(2)"[152][195]opyright 1988 [195][207][205][208][213][212][197]! [208]ubl. [201]nc."
  20. 200 printtab(9)"[193]ll [210]ights [210]eserved"
  21. 210 print"[212]hese font types have already been":print"  installed:"
  22. 220 print"code   name":print"---- --------"
  23. 230 fori=1tonf:print"[152] "ab$(i)"  "fi$(i):next
  24. 240 return
  25. 250 print"[197]nter name of next font or <[210][197][212][213][210][206]>":print"  for no more fonts.[152]"
  26. 260 fi$="":inputfi$
  27. 270 iffi$=""thenreturn
  28. 280 ifleft$(fi$,4)="font"andmid$(fi$,7,1)="/"then310
  29. 290 input"[197]nter 2-character abbreviation[152]";a$:iflen(a$)<>2then290
  30. 300 fi$="font"+a$+"/"+fi$
  31. 310 ab$=mid$(fi$,5,2):fori=1tonf:ifab$<>ab$(i)thennext:goto330
  32. 320 print"[195]ode '"ab$"' already used.":input"[208]ress <[210][197][212][213][210][206]>";a$:return
  33. 330 print"[204]oad [198]ont: "qu$fi$qu$"[152]";:inputa$
  34. 340 ifa$="yes"ora$="y"ora$="[217]"then360
  35. 350 return
  36. 360 ll=2:open15,8,15
  37. 370 pokeaa,1:pokexx,8:pokeyy,0:sys(slfs)
  38. 380 fori=1tolen(fi$):poke52991+i,asc(mid$(fi$,i,1)):next
  39. 390 pokeaa,len(fi$):pokexx,fnl(52992):pokeyy,fnh(52992):sys(snam)
  40. 400 print"[204]oading...."
  41. 410 pokeaa,0:pokexx,fnl(mem):pokeyy,fnh(mem):sys(lod)
  42. 420 input#15,a$,b$,c$,d$:ifval(a$)>19then500
  43. 430 ab$=mid$(fi$,5,2):close15:t2=sets+nf*6
  44. 440 poket2,asc(ab$):poket2+1,asc(right$(ab$,1))
  45. 450 poket2+2,fnl(mem+2):poket2+3,fnh(mem+2)
  46. 460 m=mem+2+peek(mem)+peek(mem+1)*256:poket2+4,fnl(m):poket2+5,fnh(m)
  47. 470 poket2+6,0:poket2+7,0
  48. 480 mem=peek(xx)+256*peek(yy)+1
  49. 490 nf=nf+1:fi$(nf)=mid$(fi$,8):ab$(nf)=ab$:return
  50. 500 print"[196]isk [197]rror:":printa$" "b$" "c$" "d$
  51. 510 input"[208]ress <[210][197][212][213][210][206]>";a$
  52. 520 close 15
  53. 530 return
  54. 540 rem initialize
  55. 550 poke53280,6:poke53281,0:co$="[155]":printco$
  56. 560 dimfi$(10),ab$(10):qu$=chr$(34)
  57. 570 fi$(1)="basic":ab$(1)="ba":fi$(2)="default":ab$(2)="df":nf=2
  58. 580 sets=50302:fcchar=50299:tpchar=50300:rest=50301
  59. 590 mem=11005
  60. 600 deffnh(x)=int(x/256):deffnl(x)=x-256*fnh(x)
  61. 610 aa=780:xx=781:yy=782:ss=783
  62. 620 slfs=65466:snam=65469:lod=65493
  63. 630 return
  64.