10 REM COPYRIGHT 1988 COMPUTE! PUBLICATIONS, INC. - ALL RIGHTS RESERVED.
20 IFLL=1THEN100
30 IFLL=2THEN420
40 GOSUB540
50 SS$="SPEEDSCRIPT 3.2":REM SPEEDSCRIPT FILENAME TO BOOT
60 FC$="[187]":REM FONT-CHANGE CODE
70 TP$="[163]":REM TEMPORARY FONT-CHANGE CODE
80 RE$="[178]":REM RESTORE-FONT CODE
90 PRINT"[147][208]LEASE WAIT....":LL=1:LOAD"SPEEDPRINT.ML",8,1
100 POKEFC,ASC(FC$):POKETP,ASC(TP$):POKERE,ASC(RE$)
110 GOSUB180:GOSUB250:IFFI$<>""ANDNF<11THEN110
120 PRINT"[147][194]OOTING "SS$"...."
130 PRINT"[144]LOAD"QU$SS$QU$",8"
140 PRINT"SYS49152"
150 PRINT"POKE2473,"FNH(MEM)+1:PRINT"RUN"
160 FORI=631TO636:POKEI,13:NEXT:POKE198,8:POKE637,147:POKE638,89
170 PRINT"":END
180 PRINT"[147]"TAB(10)"[211]PEED[208]RINT [194]OOTER"
190 PRINTTAB(2)"[152][195]OPYRIGHT 1988 [195][207][205][208][213][212][197]! [208]UBL. [201]NC."
200 PRINTTAB(9)"[193]LL [210]IGHTS [210]ESERVED"
210 PRINT"[212]HESE FONT TYPES HAVE ALREADY BEEN":PRINT"  INSTALLED:"
220 PRINT"CODE   NAME":PRINT"---- --------"
230 FORI=1TONF:PRINT"[152] "AB$(I)"  "FI$(I):NEXT
240 RETURN
250 PRINT"[197]NTER NAME OF NEXT FONT OR <[210][197][212][213][210][206]>":PRINT"  FOR NO MORE FONTS.[152]"
260 FI$="":INPUTFI$
270 IFFI$=""THENRETURN
280 IFLEFT$(FI$,4)="FONT"ANDMID$(FI$,7,1)="/"THEN310
290 INPUT"[197]NTER 2-CHARACTER ABBREVIATION[152]";A$:IFLEN(A$)<>2THEN290
300 FI$="FONT"+A$+"/"+FI$
310 AB$=MID$(FI$,5,2):FORI=1TONF:IFAB$<>AB$(I)THENNEXT:GOTO330
320 PRINT"[195]ODE '"AB$"' ALREADY USED.":INPUT"[208]RESS <[210][197][212][213][210][206]>";A$:RETURN
330 PRINT"[204]OAD [198]ONT: "QU$FI$QU$"[152]";:INPUTA$
340 IFA$="YES"ORA$="Y"ORA$="[217]"THEN360
350 RETURN
360 LL=2:OPEN15,8,15
370 POKEAA,1:POKEXX,8:POKEYY,0:SYS(SLFS)
380 FORI=1TOLEN(FI$):POKE52991+I,ASC(MID$(FI$,I,1)):NEXT
390 POKEAA,LEN(FI$):POKEXX,FNL(52992):POKEYY,FNH(52992):SYS(SNAM)
400 PRINT"[204]OADING...."
410 POKEAA,0:POKEXX,FNL(MEM):POKEYY,FNH(MEM):SYS(LOD)
420 INPUT#15,A$,B$,C$,D$:IFVAL(A$)>19THEN500
430 AB$=MID$(FI$,5,2):CLOSE15:T2=SETS+NF*6
440 POKET2,ASC(AB$):POKET2+1,ASC(RIGHT$(AB$,1))
450 POKET2+2,FNL(MEM+2):POKET2+3,FNH(MEM+2)
460 M=MEM+2+PEEK(MEM)+PEEK(MEM+1)*256:POKET2+4,FNL(M):POKET2+5,FNH(M)
470 POKET2+6,0:POKET2+7,0
480 MEM=PEEK(XX)+256*PEEK(YY)+1
490 NF=NF+1:FI$(NF)=MID$(FI$,8):AB$(NF)=AB$:RETURN
500 PRINT"[196]ISK [197]RROR:":PRINTA$" "B$" "C$" "D$
510 INPUT"[208]RESS <[210][197][212][213][210][206]>";A$
520 CLOSE 15
530 RETURN
540 REM INITIALIZE
550 POKE53280,6:POKE53281,0:CO$="[155]":PRINTCO$
560 DIMFI$(10),AB$(10):QU$=CHR$(34)
570 FI$(1)="BASIC":AB$(1)="BA":FI$(2)="DEFAULT":AB$(2)="DF":NF=2
580 SETS=50302:FCCHAR=50299:TPCHAR=50300:REST=50301
590 MEM=11005
600 DEFFNH(X)=INT(X/256):DEFFNL(X)=X-256*FNH(X)
610 AA=780:XX=781:YY=782:SS=783
620 SLFS=65466:SNAM=65469:LOD=65493
630 RETURN