home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / enterprs / cpm / utils / f / ql41.ark / QFC.LIB < prev    next >
Encoding:
Text File  |  1990-04-13  |  14.5 KB  |  591 lines
  1. ;; Changes:
  2. ;;  11/12/88:   Added line to re-display if no files selected inside ().
  3. ;;  11/08/88:    Added line at SELALL to print '*' when it's hit.
  4. ;;        Fixed help msg.
  5.  
  6. ;=======================================================================
  7. ; QFC.LIB ; 
  8. ;==========
  9. ;
  10. ; These routines form the choose-by-number interface, which is used 
  11. ; repeatedly.  The entry point is QFC.  A pointer to QFC's parameter block
  12. ; should be passed in register IX.  This is the format of the parameter block.
  13.  
  14. ;FNCNT    DS    1        ; Number of entries in table.
  15. ;FNTBL    DS    2        ; Pointer to the first entry in table.
  16. ;ENTLEN    DS    1        ; Length of an entry.
  17. ;FNOFFS    DS    1        ; Offset of filename from entry start.
  18. ;FNPARS    DS    1        ; YES if filenames are in form fn.typ.
  19.                 ; NO  if filenames are in form fn------typ.
  20. ;FNSORT    DS    1        ; YES to sort before beginning.
  21.                 ; NO  to leave in existing order.
  22. ;FNSELD DS    1        ; Count of files selected.
  23. ;FNMULT    DS    16        ; fn numbers (if multiple selected).
  24. ;HEDRTN DS    2        ; Routine to print screen header.
  25. ;
  26. ; By making these values parameters, it becomes easy to use the same
  27. ; code for choosing a file, an LBR member, or an ARC member.
  28. ;
  29. ; Returned values:
  30. ; HL will point to the start of the [first] entry selected.
  31. ; A will hold the number of that entry.
  32. ; B will hold the count of files selected, or 255 for "all".
  33. ; Z flag is set iff an exit char was pressed.
  34. ; C flag is set iff an unrecognizable char was pressed (so caller can process).
  35. ;   This allows us to handle (E)xtract/(V)iew toggling. 
  36. ; 
  37. ; On successive calls to QFC when a multi-selection is active,
  38. ; QFC loads the appropriate values and returns, without redisplaying the screen.
  39. ;
  40. ; The subroutine LOOKUP, which is used by QFC, is also available to
  41. ; the rest of the program.  It takes the entry number in C and returns
  42. ; HL to point to the filename within the entry.
  43. ;
  44. ; Note that for LBR, ARC, or other 'collection' processing, some information
  45. ; bearing on how to find the member ought to be saved along with the entry.
  46. ; For LBR, this is part of the directory entry; for ARC, we store the sector
  47. ; and offset along with the header.
  48. ;=============================================================================
  49. ;...
  50. ; QFC equates
  51.  
  52. QFCBLKSIZ    EQU    26    ; Length of QFC param block
  53. FNCNT        EQU    0    ; Positions of variables within block
  54. FNTBL        EQU    1
  55. ENTLEN        EQU    3
  56. FNOFFS        EQU    4
  57. FNPARS        EQU    5
  58. FNSORT        EQU    6
  59. FNSELD        EQU    7
  60. FNMULT        EQU    8
  61. HEDRTN        EQU    24
  62.  
  63. ;
  64. ; Main entry point.
  65. ;
  66. ; Decide whether to parse and/or sort.
  67.  
  68. QFC:    LD    A,(IX+FNPARS)    ; Should we parse?
  69.     OR    A
  70.     JR    Z,NOPARS
  71.  
  72.     LD    C,1
  73.     CALL    LOOKUP        ; Point to first fn
  74.     LD    E,(IX+ENTLEN)
  75.     LD    D,0        ; DE = entry length
  76.     LD    B,(IX+FNCNT)    ; B = entry count
  77. PARSLP:    CALL    PARSFN        ; Parse next fn
  78.     ADD    HL,DE        ; Point to next
  79.     DJNZ    PARSLP        ; Loop
  80.     LD    (IX+FNPARS),0    ; Reset "must parse" flag
  81.  
  82. NOPARS:    LD    A,(IX+FNSORT)    ; Should we sort?
  83.     OR    A
  84.     JR    Z,SWEEP
  85.  
  86.     LD    H,(IX+FNOFFS)    ; H = sort key start
  87.     LD    L,11        ; L = sort key length
  88.     CALL    SORT        ; Do it
  89.  
  90.     LD    (IX+FNSORT),0    ; Reset "must sort" flag
  91.  
  92. ; See if multi is active.
  93. ;
  94. SWEEP:    LD    A,(IX+FNSELD)    ; Count of files last selected
  95.     OR    A        ; Zero - multi is through.
  96.     JR    Z,SWEEP0
  97.     CP    255        ; 255 - multi is ALL.
  98.     JR    Z,SWPALL
  99.     CP    1        ; One - not multi.
  100.     JR    Z,SWEEP0    ; Otherwise SOME.
  101.  
  102. ; Active multi is SOME.
  103. SWPSOM:    DEC    A        ; One less
  104.     LD    (IX+FNSELD),A
  105.     PUSH    IX        ; Move to HL
  106.     POP    HL
  107.     LD    DE,FNMULT+15    ; Point to end of FNMULT area
  108.     ADD    HL,DE
  109.     LD    BC,0+15*256    ; C=0; B=15
  110. MOVLP:    LD    A,(HL)        ; Get this byte
  111.     LD    (HL),C        ; Save last byte
  112.     LD    C,A        ; Move this to last
  113.     DEC    HL        ; Back up one byte
  114.     DJNZ    MOVLP        ; Loop
  115.                 ; When done, A = first in string
  116.     LD    (HL),A        ; Save it
  117.     JP    GOODFIL        ; Process it
  118.  
  119. ; Active multi is ALL.
  120. SWPALL: LD    A,(IX+FNMULT)    ; Last file processed
  121.     CP    (IX+FNCNT)    ; Was that the last file?
  122.     JR    Z,SWEEP0    ; yes, select something new
  123.  
  124.     INC    A        ; Select next file
  125.     LD    (IX+FNMULT),A    ; Save for next round
  126.     JP    GOODFIL        ; Process this one
  127.  
  128. ; Ready to choose next file to view.
  129. ;
  130. SWEEP0:    XOR    A        ;
  131.     LD    (SCRNUM),A    ; Init "screen#" to zero (goes, 0,72,144..)
  132.     LD    (IX+FNSELD),A    ; Clear multi options    
  133.     JP    NSCR        ; Skip over help msg
  134.  
  135. ;...............................;
  136. ; Help message for QFC.
  137. ;
  138. QFCHLP:    CALL    CLEARSCREEN
  139.     CALL    MSG
  140.     DB    CR,LF,'File selection help:'
  141.     DB    CR,LF
  142.     DB    CR,LF,' ##',TAB,'Select numbered file'
  143.     DB    CR,LF,' <ret>',TAB,'Display next page of files'
  144.     DB    CR,LF,' S',TAB,'Re-sort files starting at nth position'
  145.     DB    CR,LF,TAB,'  (e.g. 8 to sort by extension)'
  146.     DB    CR,LF,' ^C',TAB,'Abort to CP/M'
  147.     DB    CR,LF,' Q',TAB,'Abort to previous level'
  148.     DB    CR,LF
  149.     DB    LF,' *',TAB,'Select ALL files'
  150.     DB    CR,LF,' (#,#)',TAB,'Select SOME files'
  151.     DB    CR,LF
  152.     DB    LF,'Press any key to redisplay files',0
  153. WAITCH:    LD    C,DIRIO        ; wait for a char
  154.     LD    E,0FFH
  155.     CALL    BDOSC1
  156.     OR    A    
  157.     JR    Z,WAITCH    ; Loop until kbhit
  158.     CP    CR        ; Trap CR separately
  159.     JR    Z,NSCR
  160.     CALL    CHEXIT        ; Process 'exit' chars
  161.     JP    Z,QFCEXIT    ; Fall through if no exit
  162. ;...............................;
  163. NSCR:    CALL    HEADER        ; Display proper header:
  164.                 ;   'Files Matching: DU <afn>'
  165.                 ;   'Members of: DU <fn>'
  166.     LD    A,(IX+FNCNT)    ; Count of files
  167.     LD    (HIPG),A    ; Set hipg so can deduce when enuf
  168.     INC    A        ; Count +1
  169.     LD    D,A        ; Max #of files +1 goes into D
  170.  
  171.     LD    E,1        ; E is line#, (init to 1)
  172.  
  173. ;................................
  174.                 ;
  175. LINLP:    LD    B,4        ; Outer loop for NL lines
  176.     LD    A,(SCRNUM)    ;
  177.     ADD    A,E        ; 1st file# in each line = line# + scrn#
  178.     LD    C,A        ;
  179. ;................................
  180.                 ; Inner loop, 4/line
  181. LP4:    LD    A,C        ; File#
  182.     CP    D        ; Compare to max
  183.     JR    NC,OUT4        ; If greater, done w/ this line
  184.     CALL    LOOKUP        ; Convert file # in c to pointer to name in HL
  185.     CALL    PRNUMFN        ; Print xxx:filename.typ
  186.     LD    A,C        ;
  187.     ADD    A,NL        ; Next file, if any, is prev# plus NL
  188.     LD    C,A        ;
  189.     DJNZ    LP4        ;
  190. ;...............................;
  191.  
  192. OUT4:    CALL    CRLF        ;
  193.     LD    A,E        ; Advance to next line
  194.     INC    A        ;
  195.     LD    E,A        ;
  196.     CP    NL+1        ;
  197.     JR    C,LINLP        ;
  198. ;...............................;
  199.  
  200. ; V4.1 all screens now have same msg.
  201.     CALL    MSG
  202.     DB    CR,LF,'File #, cmd, or / for help: ',0
  203.  
  204. BADNUM:
  205.     XOR    A
  206.     LD    (JUMPTO),A    ; Clear jumpto
  207.     CALL    GETCHNUM    ; Get user response
  208.     CALL    UCASE        ; Force upper case
  209.     LD    C,A        ; save char response
  210.     LD    A,(JUMPTO)    ; Did he enter a #?
  211.     OR    A
  212.     JP    NZ,CHKFIL    ; Check it
  213.  
  214.     LD    A,C        ; Get back char
  215.     CP    '/'        ; Asked for help?
  216.     JP    Z,QFCHLP
  217.     CP    '?'
  218.     JP    Z,QFCHLP
  219.     CP    CR        ; Page?
  220.     JR    Z,NXTSCR
  221.     CP    TAB        ; Tab also means page
  222.     JR    Z,NXTSCR
  223.     CP    'S'        ; Sort again?
  224.     JR    Z,RESORT
  225.     CP    '*'        ; All files?
  226.     JR    Z,SELALL
  227.     CP    '('        ; Some files?
  228.     JR    Z,SELSOM
  229. NOCMD:    CALL    CHEXIT        ; ^C, ^K straight to CP/M
  230.     JP    Z,QFCEXIT    ; other exit chars return
  231.     SCF            ; If unrecognized, flag it
  232.     RET            ; and let caller handle it
  233.  
  234. ; Display next screen.
  235. ; Wrap to first screen if at end.
  236. ;
  237. NXTSCR:    LD    A,(SCRNUM)    ; Current "screen #"
  238.     ADD    A,72        ; Plus one screenfull
  239.     JR    C,SCROVF    ; If >255, certainly too big
  240.     CP    (IX+FNCNT)    ; Past end?
  241.     JR    C,NSCROVF    ; If not past end, use this
  242. SCROVF:    SUB    A        ; Point back to beginning
  243. NSCROVF:
  244.     LD    (SCRNUM),A    ; Save new screen#
  245.     JP    NSCR        ; Display it
  246. ;...............................;
  247. ; Re-sort the files.
  248. ; Ask user which char in filename to begin with.
  249. ; This allows sorting by type, name, or any subset thereof.
  250. ;
  251. RESORT:    CALL    MSG
  252.     DB    'Sort files starting at: ',0
  253.     LD    A,10
  254.     LD    (HIPG),A    ; Set hipg
  255.     SUB    A
  256.     LD    (JUMPTO),A    ; Clr jumpto
  257.     CALL    GETCHNUM    ; Get user response
  258.     LD    A,(JUMPTO)
  259.     CP    11        ; Too big?
  260.     JP    NC,NSCR        ; Yep, ignore
  261.     LD    C,A        ; Save
  262.     LD    A,(IX+FNOFFS)    ; Get offset to fn in entry
  263.     ADD    A,C        ; Index into entry
  264.     LD    H,A        ; move to H
  265.     LD    A,11        ; Compute length of sort key
  266.     SUB    C
  267.     LD    L,A        ; Put in L
  268.     CALL    SORT        ; Do the sort
  269.     JP    NSCR        ; Redisplay
  270. ;...............................;
  271. ; Select all files.
  272. ; Set up return variables and return.
  273. SELALL:    CALL    PUTC        ; Print asterisk
  274.     LD    A,255        ; mark for 'ALL'
  275.     LD    (IX+FNSELD),A
  276.     LD    A,1        ; Index to first file
  277.     LD    (IX+FNMULT),A
  278.     LD    L,(IX+FNTBL)
  279.     LD    H,(IX+FNTBL+1)    ; Pointer to first entry
  280.     OR    A        ; Reset Z,C flags
  281.     RET            ; All done
  282. ;...............................;
  283. ; Select 'some' files.
  284. ; Triggered when user types a '('.
  285. ; Get successive file #s until 15 have been chosen,
  286. ; or ')' (or CR) is typed.
  287. SELSOM:    CALL    PUTC        ; Print the (
  288.     LD    B,0        ; Count the files
  289.     LD    HL,FNMULT    ; Place to put them
  290.     PUSH    IX
  291.     POP    DE
  292.     ADD    HL,DE
  293.  
  294. SSLP:    SUB    A        ; Clr JUMPTO
  295.     LD    (JUMPTO),A
  296.     PUSH    BC        ; Save vitals
  297.     PUSH    HL
  298.     CALL    GETCHNUM    ; Get next selection
  299.     POP    HL        ; Restore vitals
  300.     POP    BC
  301.     LD    C,A        ; Save char
  302.     LD    A,(JUMPTO)    ; Get response
  303.     OR    A        ; Zero?
  304.     JR    NZ,SSCHK    ; Check it out if not
  305.     LD    A,C        ; Restore char
  306.     CP    ')'        ; Closed parens?
  307.     JR    Z,SSDON        ; Yes, finish up
  308.     CP    CR        ; <cr> also finishes list
  309.     JR    Z,SSDON        ;
  310.     JR    SSLP        ; Others are ignored
  311.  
  312. SSCHK:    CP    (IX+FNCNT)    ; File # out of range?
  313.     JR    C,SSGOOD    ; <max is ok
  314.     JR    Z,SSGOOD    ; =max is ok
  315.     CALL    UNBDEC        ; Erase from screen
  316.     JR    SSLP        ; Try again
  317.  
  318. SSGOOD:    LD    (HL),A        ; Save it here
  319.     INC    HL        ; bump save ptr
  320.     INC    B        ; Count it here
  321.     LD    A,','        ; delimit char
  322.     CALL    PUTC
  323.     LD    A,B        ; Full yet?
  324.     CP    16
  325.     JR    NZ,SSLP        ; Nope, loop
  326.  
  327. SSDON:    CALL    BACKSP        ; Erase last comma
  328.     LD    A,')'        ; Close paren
  329.     CALL    PUTC
  330.     LD    (HL),0        ; End the sequence
  331.      LD    A,B        ; Load count
  332.     OR    A
  333.     JP    Z,NSCR        ; Redisplay if none selected
  334.     LD    (IX+FNSELD),A    ; Save here
  335.     LD    A,(IX+FNMULT)    ; index to first
  336.     LD    C,A
  337.     CALL    CALC        ; Make ptr to entry start
  338.     OR    A        ; Reset Z,C flags
  339.     RET
  340. ;................................
  341. ; Check entry for single selection
  342.  
  343. CHKFIL:    LD    C,A
  344.     LD    A,(IX+FNCNT)
  345.     CP    C
  346.     LD    A,C
  347.     JR    NC,GOOD
  348.     CALL    UNBDEC    
  349.     JP    BADNUM
  350.  
  351. GOOD:    LD    (IX+FNMULT),A    ; Save file #
  352.     LD    (IX+FNMULT+1),0    ;
  353.     LD    B,1        ; One file selected
  354.     LD    (IX+FNSELD),B    ; Save it
  355. GOODFIL:
  356.     CALL    CALC        ; Point to entry
  357.     OR    A        ; Reset Z,C flags
  358.     RET            ; Return
  359. ;...............................;
  360. ; Exit routine
  361. ; When user hits an 'exit key'
  362.  
  363. QFCEXIT:
  364.     LD    HL,0        ; Point nowhere
  365.     LD    A,L        ; File # = 0
  366.     LD    B,0        ; Files selected=0
  367.     LD    (IX+FNSELD),A    ; No files selected
  368.     LD    (IX+FNMULT),A    ; Index = 0
  369.     OR    A        ; Reset C flag, set Z flag    
  370.     RET            ; With Z flag set
  371. ;...............................;
  372. ; Various subroutines
  373. ;
  374. UNBDEC:    CALL    BELL        ; Beep!
  375.     CP    100        ; 3 digits?
  376.     CALL    NC,BACKSP    ; erase hundreds
  377.     CP    10        ; 2 digits?
  378.     CALL    NC,BACKSP    ; erase tens
  379.                 ; fall through to erase ones
  380. BACKSP:    PUSH    AF
  381.     PUSH    HL
  382.     CALL    MSG
  383.     DB    8,' ',8,0
  384.     POP    HL
  385.     POP    AF
  386.     RET
  387.  
  388. BELL:    PUSH    AF
  389.     LD    A,BEL        ; Beep!
  390.     CALL    PUTC
  391.     POP    AF
  392.     RET
  393.  
  394. HEADER:    PUSH    IX        ; Save IX reg
  395.     LD    HL,HEADRET    ; New return address
  396.     PUSH    HL
  397.     LD    L,(IX+HEDRTN)    ; Load ptr to header routine
  398.     LD    H,(IX+HEDRTN+1)    ;
  399.     JP    (HL)
  400. HEADRET:
  401.     POP    IX        ; Restore IX reg
  402.     RET
  403.  
  404. HEADJP:    JP    (HL)
  405. ;...............................;
  406. ; Lookup fcn
  407. ; Converts C, entry #, into ptr
  408. ; to fn within entry (HL)
  409. ; None destroyed
  410.  
  411. LOOKUP:    PUSH    AF
  412.     PUSH    DE
  413.     LD    A,C
  414.     CALL    CALC
  415.     LD    E,(IX+FNOFFS)
  416.     LD    D,0
  417.     ADD    HL,DE
  418.     POP    DE
  419.     POP    AF
  420.     RET
  421. ;...............................;
  422. ; Calc fcn
  423. ; Converts A, entry #, into ptr
  424. ; to start of entry (HL)
  425. ; None destroyed
  426.  
  427. CALC:    PUSH    DE
  428.     PUSH    AF
  429.     LD    L,(IX+FNTBL)
  430.     LD    H,(IX+FNTBL+1)
  431.     LD    E,(IX+ENTLEN)
  432.     LD    D,0
  433.     DEC    A
  434. CALC0:    SRL    A
  435.     JR    NC,CALC1
  436.     ADD    HL,DE
  437. CALC1:    EX    DE,HL
  438.     ADD    HL,HL
  439.     EX    DE,HL
  440.     OR    A
  441.     JR    NZ,CALC0
  442.     POP    AF
  443.     POP    DE
  444.     RET
  445. ;...............................
  446. ; Parse fcn
  447. ; Takes fn.typ at (HL) and converts
  448. ; to fn------typ at (HL)
  449. ; None destroyed
  450.  
  451. PARSFN:    PUSH    AF        ; Save all
  452.     PUSH    BC
  453.     PUSH    DE
  454.     PUSH    HL
  455.  
  456.     LD    DE,FCB3+1    ; Temporary place to put result
  457.     LD    BC,8        ; 8 chars in first segment
  458. PFN0:    LD    A,(HL)        ; Get next char
  459.     AND    127        ; ASCII mask (no file attributes!)
  460.     JR    Z,PFN1        ; If zero, was end of string char
  461.     CP    '.'        ; Dot yet?
  462.     JR    Z,PFN1
  463.     LDI            ; Transfer char
  464.     JP    PE,PFN0        ; Loop if not done
  465. ; if we get here, the filename may be too long.  We ignore bytes until we find
  466. ; a dot or null.
  467. PFNSKP:    LD    A,(HL)
  468.     OR    A        ; Null?
  469.     JR    Z,PFN2
  470.     CP    '.'        ; Dot?
  471.     JR    Z,PFN2
  472.     INC    HL        ; Test next char
  473.     JR    PFNSKP
  474.  
  475. PFN1:    LD    A,' '        ; Fill remaining part of first segment
  476.     LD    (DE),A        ; With spaces
  477.     INC    DE
  478.     DEC    C
  479.     JR    NZ,PFN1
  480. PFN2:    INC    HL        ; Bump past dot
  481.     LD    BC,3        ; Three more chars
  482.  
  483. PFN2B:    LD    A,(HL)        ; Get char
  484.     OR    A        ; Null means we fill with space
  485.     JR    NZ,PFN4
  486.     LD    A,' '        ; Fill with space
  487. PFN3:    LD    (DE),A
  488.     INC    DE
  489.     DEC    C
  490.     JR    NZ,PFN3
  491.     JR    PFNDON
  492.  
  493. PFN4:    LDI            ; Transfer char
  494.     JP    PE,PFN2B    ; Loop
  495.  
  496. PFNDON:    POP    DE        ; original source again
  497.     PUSH    DE        ; BAck on stack
  498.     LD    HL,FCB3+1    ; Temp area
  499.     LD    BC,11        ; bytes to move
  500.     LDIR
  501.     POP    HL        ; Restore all
  502.     POP    DE
  503.     POP    BC
  504.     POP    AF
  505.     RET
  506. ;..............................................................................
  507. ;
  508. ; Bubble sort all the entries.  Key starts at H and has length L.
  509. ;
  510. SORT:    LD    (80H),HL    ; Save sort key info here (re-use space) 
  511.     LD    A,(IX+FNCNT)    ; #of entries to be sorted
  512.     DEC    A        ; minus 1
  513.     RET    Z        ; Can't sort 1 entry!
  514.     LD    C,A        ; Init outer loop counter
  515.  
  516. ;................................
  517.                 ;
  518. OUTRLP:    LD    B,C        ; Init inner loop counter
  519.     LD    E,(IX+FNTBL)    ; Get table base
  520.     LD    D,(IX+FNTBL+1)    ; (DE) = first entry
  521.     LD    L,(IX+ENTLEN)    ; Get entry length
  522.     LD    H,0        ;
  523.     ADD    HL,DE        ; (HL) = 2nd entry
  524. ;...............................;
  525.                 ;
  526. INRLP:    PUSH    BC        ; Save loop counters
  527.     CALL    COMP        ; Compare two entries
  528.     CALL    C,SWAP        ; Swap if necessary
  529.     LD    C,(IX+ENTLEN)    ; Bump ptrs
  530.     LD    B,0        ;
  531.     ADD    HL,BC        ;
  532.     EX    DE,HL        ;
  533.     ADD    HL,BC        ;
  534.     EX    DE,HL        ;
  535.     POP    BC        ; Restore loop counters
  536.     DJNZ    INRLP        ; End inner loop
  537. ;...............................;
  538.  
  539.     DEC    C        ; End outer loop
  540.     JR    NZ,OUTRLP    ; Loop till done
  541.  
  542.     RET            ;
  543.  
  544. ;..............................................................................
  545. ;
  546. ; Compare the entries at (HL) and (DE) [ Used by SORT above]
  547. ;
  548. COMP:    PUSH    DE        ;
  549.     PUSH    HL        ;
  550.     LD    A,(81h)        ; Retrieve sort key offset
  551.     LD    C,A
  552.     LD    B,0        ;
  553.     ADD    HL,BC        ;
  554.     EX    DE,HL        ; DE -> jth key
  555.     ADD    HL,BC        ; HL -> j+1th key
  556.     LD    A,(80h)        ; Retrieve sort key length
  557.     LD    B,A
  558.  
  559. COMPLP:    LD    A,(DE)        ;
  560.     CP    (HL)        ;
  561.     JR    NZ,CMPRTN    ; If not equal, rtn with appropriate carry stat
  562.     INC    HL        ;
  563.     INC    DE        ;
  564.     DJNZ    COMPLP        ; Compare entire key
  565.     OR    A        ; Clr for equal avoids unecessary equal swaps
  566.  
  567. CMPRTN:    POP    HL        ;
  568.     POP    DE        ;
  569.     RET            ;
  570.  
  571. ;..............................................................................
  572.  
  573. ; Exchange the entries at (HL) and (DE). [ Used by SORT above]
  574. ;
  575. SWAP:    PUSH    DE        ;
  576.     PUSH    HL        ;
  577.  
  578.     LD    B,(IX+ENTLEN)    ; Get entry size
  579. SWAPLP:    LD    A,(DE)        ; Get a corresponding byte from each
  580.     LD    C,(HL)        ;
  581.     EX    DE,HL        ; Exchange the pointers
  582.     LD    (DE),A        ; And re-store the pair of bytes
  583.     LD    (HL),C        ;
  584.     INC    HL        ;
  585.     INC    DE        ;
  586.     DJNZ    SWAPLP        ; Loop; (note- another ex DE,HL not needed)
  587.  
  588.     POP    HL        ;
  589.     POP    DE        ;
  590.     RET            ;
  591.