home *** CD-ROM | disk | FTP | other *** search
/ Between Heaven & Hell 2 / BetweenHeavenHell.cdr / 100 / 8 / laserq.bas < prev    next >
BASIC Source File  |  1985-09-15  |  23KB  |  338 lines
  1. 1 REM IF YOU ARE STUMPED ABOUT THIS GAME LOOK FOR PROFESSOR FALKEN
  2. 2 REM ON MY FAVORITE BBS !!!KRACKLINE!!! (612)-484-5925 (300 BAUD)-----PROFESSOR FALKEN CREATOR & DESIGNER 
  3. 3 DEF SEG= &H40
  4. 4 POKE(&H17),PEEK(&H17) OR &H20  ' set Num Lock
  5. 5 POKE (&H17),PEEK(&H17) OR &H40 ' set Caps Lock
  6. 6 DEF SEG
  7. 10 CLEAR:CLS:DEFINT A-Z:GOTO 31
  8. 20 Z9=0:FOR R=1 TO 50:IF V1$=N$(R) AND (N(R)=LO OR N(R)=-1) THEN Z9=1:RETURN
  9. 30 NEXT:PRINT"THAT ITEM IS NOT HERE.":Z9=2:RETURN
  10. 31 CLS:KEY OFF:COLOR 7,0,0:LOCATE 25,60:PRINT"9/03/85"
  11. 32 LOCATE 15,1:PRINT"You are encouraged to copy and share this game with other users,on the" 
  12. 33 LOCATE 16,1:PRINT"conditions that the program is not distributed in modified form and this notice is not removed."  
  13. 34 FOR T=1 TO 7500:NEXT T 
  14. 35 CLS:COLOR 10,0,0:LOCATE 1,1:PRINT"Another program from the man who brought you SATAN'S REALM Now..."
  15. 36 FOR T=1 TO 4200:NEXT T
  16. 37 CLS:KEY OFF:COLOR 10,0,0:LOCATE 1,27:PRINT"Secret Agent In..."
  17. 38 COLOR 12,0,0:LOCATE 10,5:PRINT"             /              __   ___    /\"
  18. 39 COLOR 12,0,0:LOCATE 11,5:PRINT"            /       /\     /    /      /__\
  19. 40 LOCATE 12,5:PRINT"           /       /==\    \   /====  /  \
  20. 41 LOCATE 13,5:PRINT"          /_______/____\____\_/______/____\__________________ 
  21. 42 COLOR 1,0,0:LOCATE 14,5:PRINT"                            /                         I
  22. 43 LOCATE 15,5:PRINT"                       ____/__                        I
  23. 44 LOCATE 16,5:PRINT"                       I  /  I         ____   _____   I 
  24. 45 LOCATE 17,5:PRINT"                       I /   I  I   I  I___I  I____   I
  25. 46 LOCATE 18,5:PRINT"                       I/____I  I___I  I____  _____I  I 
  26. 47 LOCATE 19,5:PRINT"                       /
  27. 48 LOCATE 20,5:PRINT"                      /
  28. 49 COLOR 12,0,0:LOCATE 21,5:PRINT"                     *
  29. 50 FOR T=1 TO 7000:NEXT T:CLS:KEY OFF:COLOR 7,0,0
  30. 51 DIM N1$(50),N$(50),N(50),V$(18),LO(30,4),LO$(30):FL=1:DR=0:DG=-1:T=0:EL=0:BU=0:DO=0:CA=0:BA=0:TE=0:GL=0
  31. 60 PA=0:RO=0:FOR R=1 TO 5:R1=INT(9*RND(9)):CO$=CO$+STR$(R1):NEXT:LO=1:A9$=">"+STRING$(62,"-")+"<"
  32. 70 R=LEN(CO$):CO$=RIGHT$(CO$,R-1)
  33. 80 FOR R=1 TO 50:READ N1$(R),N$(R),N(R):NEXT
  34. 90 FOR R=1 TO 30:READ LO$(R),LO(R,1),LO(R,2),LO(R,3),LO(R,4):NEXT
  35. 100 FOR R=1 TO 18:READ V$(R):NEXT
  36. 110 REM
  37. 120 PRINT"YOU ARE ";LO$(LO);"."
  38. 130 FOR R=1 TO 46:IF N(R)=LO THEN PRINT"YOU SEE ";N1$(R);"."
  39. 140 NEXT:B=0:FOR R=1 TO 4:IF LO(LO,R)>0 THEN B=1
  40. 150 NEXT:IF B=0 THEN 200
  41. 160 PRINT"YOU COULD EASILY GO: ";:IF LO(LO,1)>0 THEN PRINT"NORTH  ";
  42. 170 IF LO(LO,2)>0 THEN PRINT"SOUTH  ";
  43. 180 IF LO(LO,3)>0 THEN PRINT"EAST  ";
  44. 190 IF LO(LO,4)>0 THEN PRINT"WEST  ";
  45. 200 PRINT:PRINT A9$
  46. 210 T=T+1:IF DG>0 THEN DG=DG-1
  47. 220 IF T=1 THEN INPUT"ENTER SECRET CODE ";NA$
  48. 230 GOTO 1760
  49. 240 N=0:FOR R=1 TO 46:IF N(R)=-1 THEN N=N+1
  50. 250 NEXT
  51. 260 COLOR 7,0,0:PRINT:INPUT">";A$
  52. 270 GOSUB 1890:V$=LEFT$(A$,3):GOSUB 1950:FOR R=1 TO 18:IF V$=V$(R) THEN 300 ELSE NEXT
  53. 280 IF V$="ORD" THEN 2210
  54. 290 PRINT"YOU DON'T KNOW HOW TO DO THAT.":GOTO 260
  55. 300 IF V$="QUI" THEN 1650
  56. 310 V=R:FOR R=1 TO LEN(A$):IF MID$(A$,R,1)=" " THEN 360 ELSE NEXT
  57. 320 IF V$="LOO" THEN 110
  58. 330 IF V$="BON" THEN 1670
  59. 340 IF V$="INV" THEN 1690
  60. 350 PRINT"PLEASE USE 2 WORD COMMANDS ":GOTO 260
  61. 360 V1$=MID$(A$,R+1,3):FOR R=1 TO 49:IF V1$=N$(R) THEN 390 ELSE NEXT
  62. 370 IF V1$="NOR" OR V1$="SOU" OR V1$="EAS" OR V1$="WES" THEN 390
  63. 380 PRINT"CANNOT UNDERSTAND.":GOTO 260
  64. 390 ON V GOTO 400,530,620,680,800,840,1040,1140,1300,1320,1360,1450,1490,1540,1600,1650,1670,1690
  65. 400 IF V1$="NOR" AND LO(LO,1)>0 THEN LO=LO(LO,1):GOTO 110
  66. 410 IF V1$="SOU" AND LO(LO,2)>0 THEN LO=LO(LO,2):GOTO 110
  67. 420 IF V1$="EAS" AND LO(LO,3)>0 THEN LO=LO(LO,3):GOTO 110
  68. 430 IF V1$="WES" AND LO(LO,4)>0 THEN LO=LO(LO,4):GOTO 110
  69. 440 IF V1$="NOR" OR V1$="SOU" OR V1$="EAS" OR V1$="WES" THEN 520
  70. 450 GOSUB 20:IF Z9=2 THEN 210
  71. 460 IF R=8 THEN LO=5:GOTO 110
  72. 470 IF R=37 AND RO=1 AND LO=20 THEN LO=21:GOTO 110
  73. 480 IF R=10 THEN LO=11:GOTO 110
  74. 490 IF R=14 THEN LO=13:GOTO 110
  75. 500 IF R=33 THEN LO=3:GOTO 110
  76. 510 IF R=34 AND DO=1 THEN LO=9:GOTO 110
  77. 520 PRINT"YOU CAN'T GO THAT WAY AT THE MOMENT.":GOTO 210
  78. 530 GOSUB 20:IF Z9=2 THEN 210
  79. 540 IF R=2 OR R=3 OR R=4 OR R=6 OR R=15 OR R=16 OR R=20 OR R=21 OR R=22 OR R=23 OR R=25 OR R=26 OR R=27 OR R=28 OR R=30 OR R=31 OR R=37 OR R=39 OR R=40 OR R=42 OR R=44 OR R=45 OR R=46 THEN 560
  80. 550 PRINT"YOU CAN'T CARRY THAT!":GOTO 210
  81. 560 IF N(R)=-1 THEN PRINT"YOU ALREADY HAVE IT.":GOTO 210
  82. 570 IF N>=5 THEN PRINT"YOU CAN'T CARRY ANYMORE.":GOTO 210
  83. 580 PRINT"O.K.":N(R)=-1
  84. 590 IF V1$="PAI" AND PA=0 THEN PRINT"SOMETHING FELL FROM THE FRAME !":N(31)=LO:PA=1
  85. 600 IF V1$="TEL" THEN TE=0
  86. 610 GOTO 210
  87. 620 FOR R=1 TO 46:IF V1$=N$(R) AND N(R)=-1 THEN 640 ELSE NEXT
  88. 630 PRINT"YOU DON'T SEEM TO BE CARRYING IT.":GOTO 210
  89. 640 IF R=30 THEN PRINT"YOU DROPPED THE CUP BUT IT BROKE INTO SMALL PEICES.":PRINT"THE COFFEE SOAKED INTO THE GROUND.":N(30)=0:DR=0:GOTO 210
  90. 650 IF R=45 THEN GL=0
  91. 660 IF R=31 AND N(30)=-1 THEN PRINT"O.K. YOU DROPPED IT.":PRINT"BUT IT FELL IN THE COFFEE!":N(31)=0:DR=1:GOTO 210
  92. 670 PRINT"O.K. YOU DROPPED IT.":N(R)=LO:GOTO 210
  93. 680 IF V1$="BUT" AND LO=3 AND DO=0 THEN PRINT"THE ELECTRO-DOORS OPEN WITH A WHOOSH!":DO=1:GOTO 210
  94. 690 IF N(46)=-1 AND V1$="BUT" THEN PRINT"YOU PUSH THE BUTTON ON THE BOX AND":GOTO 770
  95. 700 GOSUB 20
  96. 710 IF Z9=2 THEN 210
  97. 720 IF R=17 AND GL<>1 THEN PRINT"THERE'S ELECTRICITY COURSING THRU THE SQUARE!":PRINT"YOU'RE BEING ELECTROCUTED!":GOTO 2330
  98. 730 IF R=35 AND BU=0 THEN PRINT"THE BUTTON ON THE WALL GOES IN":PRINT"SOMETHING SEEMS DIFFERENT NOW."FOR T=1 TO 1000:NEXT T:GOTO 770
  99. 740 IF R=47 AND FL<>1 THEN LO(9,1)=3:FL=1:GOTO 790
  100. 750 IF R=48 AND FL<>2 THEN LO(9,1)=8:FL=2:GOTO 790
  101. 760 IF R=49 AND FL<>3 THEN LO(9,1)=10:FL=3:GOTO 790
  102. 770 IF N(46)=-1 AND (LO=6 OR LO=29)THEN PRINT"THERE IS A BLINDING FLASH....":FOR R=1 TO 3000:NEXT:LO=1:FL=1:LO(9,1)=3:GOTO 110
  103. 780 PRINT"NOTHING HAPPENS.":GOTO 210
  104. 790 PRINT"THE ELECTRO-DOORS CLOSE AND YOU FEEL AS IF THE ROOM IS MOVING.":PRINT"SUDDENLY THE ELECTRO-DOORS OPEN AGAIN.":FOR R=1 TO 5000:NEXT:GOTO 110
  105. 800 GOSUB 20:IF Z9=2 THEN 210
  106. 810 IF R=18 AND GL<>1 THEN PRINT"THE LEVER HAS ELECTRICITY COURSING THRU IT!":PRINT"YOUR BEING ELECTROCUTED SECRET AGENT!!!!":GOTO 2330
  107. 820 IF R=18 AND EL=0 THEN PRINT"THE LEVER GOES ALL THE WAY UP AND CLICKS.":PRINT"SOMETHING SEEMS DIFFERENT NOW.":EL=1:GOTO 210
  108. 830 PRINT"NOTHING HAPPENS.":GOTO 210
  109. 840 REM
  110. 850 IF V1$="DRA" AND LO=5 THEN PRINT"IT LOOKS FRAGILE.":GOTO 210
  111. 860 GOSUB 20:IF Z9=2 THEN 210
  112. 870 IF R=1 AND BA<>1 THEN PRINT"THERE'S NO POWER FOR IT.":GOTO 210
  113. 880 IF R=1 AND TE<>1 THEN PRINT"THERE'S NO TELEVISION TO WATCH IT ON.":GOTO 210
  114. 890 IF R=6 THEN PRINT"IT LOOKS HEAVY.":GOTO 210
  115. 900 IF R=7 THEN PRINT"IT'S LOCKED.":GOTO 210
  116. 910 IF R=13 THEN PRINT"IT'S A VERY STRONG BAG.":GOTO 210
  117. 920 IF R=19 THEN PRINT"YOU CAN SEE A LOCKED DRAWER IN IT.":GOTO 210
  118. 930 IF R=22 OR R=27 THEN PRINT"THERE'S WRITING ON IT.":GOTO 210
  119. 940 IF R=34 AND DO=1 THEN PRINT"THE ELECTRO-DOORS ARE OPEN.":GOTO 210
  120. 950 IF R=24 THEN PRINT"YOU CAN SEE A LASER CORE IN IT.":GOTO 210
  121. 960 IF R=9 THEN PRINT"THERE IS A SMALL SLIT NEAR THE ELECTRO-DOOR.":GOTO 210
  122. 970 IF R=34 THEN PRINT"THERE'S A BUTTON NEAR THE ELECTRO-DOOR.":GOTO 210
  123. 980 IF R=41 AND BU=1 THEN PRINT"THE TELEVISION IS DARK.":GOTO 210
  124. 990 IF R=41 THEN PRINT"YOU SEE AN ENGINE REACTOR CORE HUNDREDS OF FEET DEEP ON ONE MONITOR.":PRINT"ON THE OTHER SIDE OF THE CORE,I SEE A LARGE HOOK.":GOTO 210
  125. 1000 IF R=43 AND BU=1 THEN PRINT"THE TELEVISION IS DARK.":GOTO 210
  126. 1010 IF R=43 THEN PRINT"YOU SEE A ROOM WITH A SECURITY CASE ON A PEDESTAL IN IT.":GOTO 210
  127. 1020 IF R=44 THEN PRINT"YOU SEE A PICTURE OF A DRACONIAN STARPILOT.":GOTO 210
  128. 1030 PRINT"YOU SEE NOTHING OF INTEREST.":GOTO 210
  129. 1040 GOSUB 20:IF Z9=2 THEN 210
  130. 1050 IF R<>3 AND R<>2 AND R<>4 AND R<>28 THEN PRINT"YOU CAN'T INSERT THAT!":GOTO 210
  131. 1060 INPUT"TELL ME, IN ONE WORD, INTO WHAT";A3$:A3$=LEFT$(A3$,3)
  132. 1070 R1=R:V1$=A3$:GOSUB 20:IF Z9=2 THEN 210
  133. 1080 IF R1=3 AND R=1 THEN PRINT"O.K.":BA=1:N(3)=0:BA=1:GOTO 210
  134. 1090 IF R1=4 AND R=50 AND DG<=0 THEN PRINT"THE DRACONIAN GUARD WON'T LET YOU!":GOTO 210
  135. 1100 IF R1=2 AND R=1 THEN PRINT"O.K. THE TAPE IS IN THE RECORDER.":N(2)=0:TA=1:GOTO 210
  136. 1110 IF R1=4 AND R=50 THEN PRINT"POP! A SECTION OF THE WALL OPENS.....":PRINT"REVEALING SOMETHING VERY INTERESTING.":N(4)=0:N(5)=LO:GOTO 210
  137. 1120 IF R1=28 AND R=29 THEN PRINT"POP! A CUP OF COFFEE COMES OUT OF THE MACHINE.":N(28)=0:N(30)=LO:GOTO 210
  138. 1130 PRINT"NOTHING HAPPENED.":GOTO 210
  139. 1140 REM
  140. 1150 IF V1$="DRA" AND LO=5 AND N(23)=0 THEN PRINT"IT'S STUCK.":GOTO 210
  141. 1160 GOSUB 20:IF Z9=2 THEN 210
  142. 1170 IF R=7 OR R=9 OR R=13 OR R=15 OR R=23 OR R=32 OR R=5 THEN 1190
  143. 1180 PRINT"YOU CAN'T OPEN THAT!":GOTO 210
  144. 1190 IF R=7 AND N(16)=-1 THEN PRINT"O.K. YOU OPENED THE DOOR.":N(7)=0:N(8)=4:GOTO 210
  145. 1200 IF R=9 THEN PRINT"YOU CAN'T. IT DOESN'T WORK.":GOTO 210
  146. 1210 IF R=13 AND N(16)=-1 THEN PRINT"O.K. THE CLOSET IS OPENED.":N(13)=0:N(14)=14:GOTO 210
  147. 1220 IF R=15 THEN PRINT"YOU CAN'T. IT'S TOO STRONG.":GOTO 210
  148. 1230 IF R=23 THEN PRINT"IT'S STUCK.":GOTO 210
  149. 1240 IF R=32 AND N(28)=0 AND N(4)=0 AND SC=1 THEN PRINT "YOU OPEN THE SCULPTURE.":PRINT"SOMETHING FALLS OUT.":N(28)=LO:N(4)=LO:GOTO 210
  150. 1250 IF R<>5 THEN 1290
  151. 1260 INPUT"WHAT'S THE COMBINATION";C$
  152. 1270 IF C$=CO$ THEN PRINT"THE DOOR IS SLOWLY OPENING.":N(5)=0:N(9)=0:N(10)=10:GOTO 210
  153. 1280 PRINT"YOU MUST HAVE THE WRONG COMBINATION OR YOU ARE NOT":PRINT"SAYING IT RIGHT.":GOTO 210
  154. 1290 PRINT"YOU CAN'T DO THAT...YET!":GOTO 210
  155. 1300 IF V1$="GLO" AND N(45)=-1 THEN PRINT"O.K. YOUR NOW WEARING THE GLOVES.":GL=1:GOTO 210
  156. 1310 PRINT"YOU CAN'T WEAR THAT!":GOTO 210
  157. 1320 IF V1$<>"SIG" AND V1$<>"NOT" THEN PRINT"YOU CAN'T READ THAT.":GOTO 210
  158. 1330 GOSUB 20:IF Z9=2 THEN 210
  159. 1340 IF R=22 THEN PRINT"IT SAYS:":PRINT NA$;",":PRINT"SECRET AGENT WE HAVE FOUND A DRACONIAN SECRET WORD,":PRINT"IT IS: BONK .USE IT IN A -TASTEFUL- SITUATION":GOTO 210
  160. 1350 IF R=27 THEN PRINT"IT SAYS: WARNING!!HAZARDOUS!!!!":GOTO 210
  161. 1360 IF V1$<>"REC" THEN PRINT"YOU CAN'T START THAT.":GOTO 210
  162. 1370 GOSUB 20:IF Z9=2 THEN 210
  163. 1380 IF BA<>1 OR TE<>1 OR TA<>1 THEN 1440
  164. 1390 PRINT"THE RECORDER STARTS UP AND PRESENTS A SHORT MESSAGE:"
  165. 1400 PRINT"^^^^^^^^^^^^^^^^TOP^^^^SECRET^^^^^^^^^^^^^^^^^^^^^^ "
  166. 1405 PRINT"THIS IS EARTH FEDERATION..."
  167. 1408 PRINT"SECRET AGENT I'M GLAD YOU FOUND THIS TAPE." 
  168. 1409 PRINT"HERE IS SOME INFORMATION THAT MAY BE OF HELP."
  169. 1410 PRINT"WE HAVE UNCOVERED A COMBINATION NUMBER THAT MAY HELP YOU."
  170. 1420 PRINT"THAT NUMBER IS:";CO$;". PLEASE WATCH OUT FOR HIDDEN TRAPS."
  171. 1430 PRINT"ALSO, THERE IS SOMETHING IN THE SCULPTURE.PLEASE OPEN IT.":SC=1:GOTO 210
  172. 1440 PRINT"NOTHING HAPPENED.":GOTO 210
  173. 1450 IF V1$<>"DRA" THEN PRINT"YOU'RE TRYING TO BREAK IT, BUT YOU CAN'T.":GOTO 210
  174. 1460 IF N(6)<>-1 THEN PRINT"YOU CAN'T DO THAT YET.":GOTO 210
  175. 1470 IF LO=5 THEN PRINT"IT'S HARD....BUT YOU GOT IT. TWO THINGS FELL OUT.":N(3)=LO:N(22)=LO:N(23)=LO:GOTO 210
  176. 1480 PRINT"NOTHING HAPPENS.":GOTO 210
  177. 1490 GOSUB 20:IF Z9=2 THEN 210
  178. 1500 IF R<>15 AND R<>24 THEN PRINT"YOUR TRYING. IT DOESN'T WORK.":GOTO 210
  179. 1510 IF N(25)<>-1 THEN PRINT"YOU CAN'T DO THAT YET.":GOTO 210
  180. 1520 IF R=15 THEN PRINT"RIP!! THE BAG GOES TO PIECES, AND SOMETHING FALLS OUT!":N(15)=0:N(2)=LO:GOTO 210
  181. 1530 IF R=24 THEN PRINT"YOU CUT THE CASE AND REACH IN TO PULL SOMETHING OUT.":N(26)=-1:GOTO 210
  182. 1540 IF V1$<>"ROP" THEN PRINT"YOU CAN'T THROW THAT.":GOTO 210
  183. 1550 IF N(37)<>-1 THEN PRINT"YOU CAN'T DO THAT YET.":GOTO 210
  184. 1560 INPUT"IN ONE WORD AT WHAT ?";A3$:A3$=LEFT$(A3$,3)
  185. 1570 IF A3$<>"HOO" THEN PRINT"O.K. YOU THREW IT.":N(37)=LO:GOTO 210
  186. 1580 IF LO<>20 THEN PRINT"YOU CAN'T DO THAT YET.":GOTO 210
  187. 1590 PRINT"YOU THREW THE ROPE AND IT SNAGGED ON THE HOOK.":RO=1:N(37)=LO:GOTO 210
  188. 1600 IF V1$<>"TEL" THEN PRINT"YOU CAN'T CONNECT THAT.":GOTO 210
  189. 1610 IF N(40)<>LO THEN PRINT"YOU DON'T SEE A TELEVISION HERE.":GOTO 210
  190. 1620 IF TE=1 THEN PRINT"YOU DID THAT ALREADY.":GOTO 210
  191. 1630 IF LO<>2 THEN PRINT"YOU CAN'T DO THAT....YET!":GOTO 210
  192. 1640 PRINT"O.K. THE TELEVISION IS CONNECTED.":TE=1:GOTO 210
  193. 1650 PRINT"WHAT ? YOU WOULD LEAVE HERE WITHOUT THE LASER-CORE ?"
  194. 1660 PRINT"JUST FOR THAT I'M GOING TO DESTROY THE GAME.":PRINT:PRINT:PRINT:PRINT"BOOOOOOOOOOOOM!":FOR R=1 TO 5000:NEXT:GOTO 2370
  195. 1670 IF LO=14 THEN PRINT"AHHHHH! A TRAP DOOR OPENED UNDERNEATH YOU AND":PRINT"YOU FIND YOURSELF FALLING.":FOR R=1 TO 4000:NEXT:LO=17:GOTO 2370
  196. 1680 PRINT"NOTHING HAPPENED.":GOTO 210
  197. 1690 Z8=0:PRINT"YOU ARE PRESENTLY CARRYING:":FOR R=1 TO 46
  198. 1700 IF N(R)<>-1 THEN 1730
  199. 1710 PRINT N1$(R);:IF R=45 AND GL=1 THEN PRINT". WHICH YOUR WEARING."ELSE PRINT" "
  200. 1720 Z8=1
  201. 1730 NEXT
  202. 1740 IF Z8=0 THEN PRINT"NOTHING"
  203. 1750 GOTO 210
  204. 1760 IF LO=3 AND N(39)=-1 THEN PRINT"THE DRACONIAN GUARD LOOKS AT YOUR BADGE AND THEN THROWS YOU OUT.":FOR R=1 TO 5000:NEXT:LO=1:GOTO 110
  205. 1770 IF LO=10 AND N(42)<>-1 THEN PRINT"THE GUARD LOOKS AT YOU SUSPICIOUSLY, THEN THROWS YOU BACK.":FOR R=1 TO 4000:NEXT:LO=9:GOTO 110
  206. 1780 IF LO=6 AND BU<>1 THEN PRINT"SIRENS GO OFF ALL AROUND YOU!":PRINT"DRACONIAN GUARDS RUN IN AND BLAST YOU TO DEATH!":GOTO 2330
  207. 1790 IF LO=11 AND EL<>1 THEN PRINT"THE FLOOR IS WIRED WITH ELECTRICITY!":PRINT"YOUR BEING ELECTROCUTED!":GOTO 2330
  208. 1800 IF LO=10 AND N(30)=-1 AND DR=1 THEN PRINT"THE DRACONIAN GUARD TAKES YOUR COFFEE":PRINT"AND IS KNOCKED OUT RIGHT AWAY.":DG=5+INT(10*RND(10)):N(11)=0:N(12)=10:DR=0:N(30)=0:GOTO 240
  209. 1810 IF DG=0 THEN PRINT"YOU HEAR A NOISE LIKE SOMEONE IS YAWNING.":N(11)=10:N(12)=0:GU=-2:DG=-1:GOTO 240
  210. 1820 IF LO=1 AND N(26)=-1 THEN PRINT"YOU'VE RECOVERED THE LASER CORE SECRET AGENT!!!!"BEEP:BEEP:BEEP:BEEP:BEEP:BEEP:BEEP:BEEP:BEEP:BEEP:PRINT"MESSAGE COMING FROM EARTH FEDERATION":PRINT"--AUTOMATICALLY TURNING ON SHORTWAVE DESCRAMBLER " GOTO 4000 
  211. 1830 IF T>375 THEN PRINT"I THINK THEY ARE ON TO YOU....YOU HEAR NOISES."
  212. 1840 IF T=400 THEN PRINT"OH NO! THEY CAUGHT UP TO YOU!! THEY'RE PULLING OUT LASER-GUNS!":GOTO 2330
  213. 1850 IF T=1 THEN PRINT"WRITING ON THE BATTLESHIP SAYS:":PRINT"IF YOU WANT INSTRUCTIONS TYPE:ORDERS PLEASE"
  214. 1860 IF LO=6 AND LO(6,2)<>0 THEN PRINT"A LASER-DOOR SLAMS DOWN BEHIND YOU!":LO(6,2)=0:GOTO 240
  215. 1870 IF LO=10 AND GU=-2 THEN PRINT"THE DRACONIAN GUARD DRAWS HIS GUN AND SHOOTS YOU!":GOTO 2330
  216. 1880 GOTO 240
  217. 1890 IF A$="N" THEN A$="GO NORTH":RETURN
  218. 1900 IF A$="S" THEN A$="GO SOUTH":RETURN
  219. 1910 IF A$="E" THEN A$="GO EAST":RETURN
  220. 1920 IF A$="W" THEN A$="GO WEST":RETURN
  221. 1930 IF A$="I" THEN A$="INV":RETURN
  222. 1940 RETURN
  223. 1950 IF V$="WAL" OR V$="RUN" THEN V$="GO ":RETURN
  224. 1960 IF V$="TAK" OR V$="CAR" THEN V$="GET":RETURN
  225. 1970 IF V$="LEA" THEN V$="DRO":RETURN
  226. 1980 IF V$="PRE" THEN V$="PUS":RETURN
  227. 1990 IF V$="EXA" THEN V$="LOO":RETURN
  228. 2000 IF V$="PUT" THEN V$="INS":RETURN
  229. 2010 IF V$="UNL" THEN V$="OPE":RETURN
  230. 2020 IF V$="PLA" THEN V$="STA":RETURN
  231. 2030 IF V$="SMA" THEN V$="BRE":RETURN
  232. 2040 IF V$="ATT" THEN V$="CON":RETURN
  233. 2050 IF V$="LIS" THEN V$="INV":RETURN
  234. 2060 RETURN
  235. 2070 DATA A RECORDER,REC,2,A VIDEO TAPE,TAP,0,A LARGE BATTERY,BAT,0,AN EARTH CREDIT CARD,CAR,0,AN ELECTRONIC LOCK,LOC,0,AN ELABORATE PAPER WEIGHT,WEI,5,A LOCKED LASER DOOR,DOO,4,AN OPEN LASER DOOR,DOO,0,A SOLID LOOKING DOOR,DOO,10
  236. 2080 DATA AN OPEN DOOR,DOO,0,AN ALERT DRACONIAN GUARD,GUA,10,A SLEEPING DRACONIAN GUARD,GUA,0,A LOCKED MAINTENANCE CLOSET,CLO,14,A MAINTENANCE CLOSET,CLO,0,A PLASTIC BAG,BAG,13,AN ELECTRONIC KEY,KEY,9,A SMALL METAL SQUARE ON THE WALL,SQU,16
  237. 2090 DATA A LEVER ON THE SQUARE,LEV,16,A QUALLFIL DESK,DES,5,A BROOM,BRO,13,A DUSTPAN,DUS,13,A ELECTRONIC NOTEBOOK,NOT,0,A QUALLFIL DRAWER,DRA,0,A GLASS CASE ON A PEDESTAL,CAS,6,A RAZOR BLADE,BLA,27,A LASER CORE,COR,0,A SIGN ON THE SQUARE
  238. 2100 DATA SIG,16,A QUARTER,QUA,0,A COFFEE MACHINE,MAC,8,A CUP OF STEAMING HOT COFFEE,CUP,0,A SMALL CAPSULE,CAP,0,A LARGE SCULPTURE,SCU,3,A DRACONIAN BATTLESHIP,BAT,1,A PAIR OF ELECTRO-DOORS,DOO,3,A LARGE BUTTON ON THE WALL
  239. 2110 DATA BUT,29,A PANEL OF BUTTONS NUMBERED ONE THRU THREE,PAN,9,A STRONG LASER-LIGHT ROPE,ROP,17,A LARGE HOOK WITH A LASER-LIGHT ROPE HANGING FROM IT,HOO,21,AN EARTH FEDERATION I.D. BADGE,BAD,-1,A PORTABLE TELEVISION,TEL,7
  240. 2120 DATA A BANK OF MONITORS,MON,7,A DRACONIAN I.D. CARD
  241. 2130 DATA IDD,30,A BANK OF MONITORS,MON,19,A SMALL PAINTING,PAI,23,A PAIR OF RUBBER GLOVES,GLO,13,A BOX WITH A BUTTON ON IT,BOX,24,ONE,ONE,9,TWO,TWO,9,THREE,THR,9,SLIT,SLI,10,ON A DRACONIAN LANDING PAD,0,0,0,0,IN A SURVEILLANCE ROOM,0,0,3,0
  242. 2140 DATA IN THE HALLWAY OF THE BATTLESHIP,1,0,4,2,IN A RECORDS KEEPING ROOM,0,0,0,3
  243. 2150 DATA IN THE BATTLESHIP'S COMMANDERS OFFICE,0,0,0,4,IN A SMALL SOUND PROOFED CUBICLE,0,12,0,0,IN A SECURITY ROOM,0,0,8,0,IN A SMALL HALLWAY,0,14,9,7,IN A SMALL ROOM,3,0,0,0,IN A SHORT CORRIDOR,0,15,0,9,IN A HALLWAY MADE OF METAL,0,0,12,10
  244. 2160 DATA IN A SMALL PLAIN ROOM,6,0,0,11
  245. 2170 DATA IN A MAINTENANCE CLOSET,0,0,14,0,IN A CAFETERIA,8,0,0,0,IN A SIDE CORRIDOR,10,0,16,0,IN A POWER GENERATOR ROOM,0,0,0,15,IN A SUB-BASEMENT BELOW THE CHUTE,0,0,18,0,IN THE ENTRANCE TO THE SECRET COMPLEX,0,20,19,17
  246. 2180 DATA IN A SECRET MONITORING ROOM,0,0,0,18,ON A LEDGE IN FRONT OF A METAL PIT HUNDREDS OF FEET DEEP,18,0,0,0,ON THE OTHER SIDE OF THE PIT,0,0,22,0,IN A LONG CORRIDOR,0,25,23,21,IN A LARGE ROOM,0,26,0,22,IN A SECRET LABORATORY,0,0,25,0
  247. 2190 DATA IN A NARROW CROSS CORRIDOR,22,0,0,24,IN A CROSS EXAMINATION ROOM,23,28,0,0,IN A SMALL BATHROOM,0,0,28,0,IN THE OFFICE OF THE CHIEF OF DRACONIAN DIPLOMAT,26,30,0,27,IN THE DRACONIAN CONTROL ROOM,0,0,30,0,NEAR THE END OF THE COMPLEX,28,0,0,29
  248. 2200 DATA "GO ",GET,DRO,PUS,PUL,LOO,INS,OPE,WEA,REA,STA,BRE,CUT,THR,CON,QUI,BON,INV
  249. 2210 COLOR 7,0,0:PRINT"YOUR MISSION,";NA$;",IS TO RECOVER A LASER-CORE THAT IS BEING"
  250. 2220 PRINT"USED TO BLACKMALE EARTH FEDERATION TO GIVE UP THE PLANET."
  251. 2230 PRINT"IF EARTH FEDERATION CANNOT GET THE LASER-CORE BACK,"
  252. 2240 PRINT"THE DRACONIAN'S WILL USE IT'S IMMENSE POWER TO DESTROY"
  253. 2250 PRINT"EARTH.WE SUSPECT THEY HAVE HIDDEN IT SOMEWHERE IN "  
  254. 2260 PRINT"THEIR BATTLESHIP.HURRY BEFORE THEY USE IT!!!!"
  255. 2310 PRINT"REMEMBER YOU ARE IN ENEMY TERRITORY BE **CAREFUL**"
  256. 2311 PRINT"YOU HAVE JUST BEEN TRANSPORTED TO THE DRACONIAN LANDING"
  257. 2312 PRINT"PAD ON PLANET DRACONIA."
  258. 2320 GOTO 240
  259. 2330 COLOR 12,0,0:FOR R=1 TO 5000:NEXT:PRINT"                        ________________ " 
  260. 2331 PRINT"                       / I\  ~I~  I___I \
  261. 2332 PRINT"                      /  I/   I   I      \
  262. 2333 PRINT"      ____           /   I\o _I_o I o     \
  263. 2334 PRINT"      I***I          I                    I
  264. 2335 PRINT"      I***I          I   Secret Agent     I
  265. 2336 PRINT"      _~I~           I    19??-2034       I
  266. 2337 PRINT"     / \I __         I                    I
  267. 2338 PRINT"        I/  \        I   Killed on E.F.   I
  268. 2339 PRINT"        I            I___Secret_Mission___I
  269. 2340 PRINT"        I  "
  270. 2350 INPUT"PLAY AGAIN ";Z$
  271. 2360 IF Z$="Y" THEN 1 IF Z$="N" CLS:SYSTEM 
  272. 2365 END
  273. 2370 COLOR 15,0,0:PRINT"_______________            ____________" 
  274. 2380 PRINT"   \    \  /  \\          // \/ \  /   "
  275. 2390 PRINT"    \  /~\/    \\        //      \/    "
  276. 2400 PRINT"     \/         ~        ~             "
  277. 2410 PRINT"                                       "
  278. 2420 COLOR 1,0,0:PRINT"                   \0/                 "
  279. 2430 PRINT"                    H                  "
  280. 2440 PRINT"                   / \                 "
  281. 2450 PRINT"                                       "
  282. 2450 PRINT"                                       "
  283. 2460 COLOR 15,0,0:PRINT"                             /\        "
  284. 2470 PRINT"\    /\     /\            /\/  \       "
  285. 2480 PRINT"_\__/__\___/__\__/\______/__\___\__/\__"
  286. 2485 FOR T=1 TO 7000:NEXT T
  287. 2490 GOTO 110
  288. 4000 FOR T=1 TO 8000:NEXT T
  289. 4010 CLS:KEY OFF:COLOR 15,0,0:PRINT"SECRET AGENT,OUR SENSORS SHOW YOU HAVE LASER-CORE..."
  290. 4020 PRINT"GET READY FOR TRANSPORTATION..." 
  291. 4030 FOR T=1 TO 12000:NEXT T
  292. 4032 LOCATE 5,20:PRINT"3"
  293. 4035 FOR T=1 TO 1500:NEXT
  294. 4040 LOCATE 5,20:PRINT"2"
  295. 4050 FOR T=1 TO 1500:NEXT T
  296. 4060 LOCATE 5,20:PRINT"1"
  297. 4070 FOR T=1 TO 1500:NEXT T
  298. 4080 LOCATE 5,16:PRINT"ENERGIZE..."
  299. 4090 FOR T=1 TO 2500:NEXT T
  300. 5000 CLS:KEY OFF:COLOR 0,7,0:PRINT"                                                                  "
  301. 5001 PRINT"                                                                       "
  302. 5002 PRINT"                                                                       "
  303. 5003 PRINT"                                                                       "
  304. 5004 PRINT"                                                                       "
  305. 5005 PRINT"                                                                       "
  306. 5006 PRINT"                                                                       "
  307. 5007 PRINT"                                                                       "
  308. 5008 PRINT"                                                                       "
  309. 5009 PRINT"                                                                       "
  310. 5010 PRINT"                                                                       "
  311. 5011 PRINT"                                                                       "
  312. 5012 PRINT"                                                                       "
  313. 5013 PRINT"                                                                       "
  314. 5014 PRINT"                                                                       "
  315. 5015 PRINT"                                                                       "
  316. 5016 PRINT"                                                                       "
  317. 5017 PRINT"                                                                       "
  318. 5018 PRINT"                                                                       "
  319. 5019 PRINT"                                                                       "
  320. 5020 PRINT"                                                                       "
  321. 5021 PRINT"                                                                       "
  322. 5022 PRINT"                                                                       "
  323. 5023 PRINT"                                                                       "
  324. 5028 FOR T=1 TO 7500:NEXT T
  325. 5029 CLS:KEY OFF:COLOR 7,0,0:PRINT"YOU ARE BACK ON EARTH.":PRINT"YOU ARE GREETED BY DOUG THE MISSION SPECIALIST & JOHN THE SYSTEM MONITOR."  
  326. 5030 PRINT"THEY BOTH WALK UP TO YOU AND SAY CONGRATULATIONS SECRET AGENT!!":PRINT"WE ARE GLAD YOU'RE BACK.":PRINT"BY THE WAY WE MUST TALK TO YOU ABOUT THE BARBERA GALAXY IT SEEMS THAT..." 
  327. 5040 FOR T=1 TO 22000:NEXT T
  328. 5050 CLS:KEY OFF:COLOR 10,0,0:PRINT"...And the story goes on."
  329. 5060 FOR T=1 TO 5000:NEXT T
  330. 5070 CLS:SYSTEM 
  331.  
  332.  
  333.  
  334.  
  335.  
  336.  
  337.