home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib19b.dsk / MAIN.VERSION.1.bas < prev    next >
Encoding:
BASIC Source File  |  1990-01-01  |  1.0 KB  |  37 lines
  1. 10  REM  ---MAIN PROGRAM
  2. 20  TEXT : HOME : PRINT "** COPYRIGHT 1984 BY MICROSPARC, INC. **": PRINT : DIM D%(100)
  3. 30  PRINT "READING DATA.."
  4. 40  GOSUB 200: REM  GOSUB THE READ ROUTINE
  5. 50  PRINT "SORTING DATA.."
  6. 60  GOSUB 300: REM  GOSUB THE SORT ROUTINE
  7. 70  PRINT "PRINTING DATA.."
  8. 80  GOSUB 400: REM  GOSUB THE OUTPUT ROUTINE
  9. 90  PRINT "NO ERRORS. NORMAL TERMINATION."
  10. 100  END 
  11. 200  REM  ---READ DATA INTO D%()
  12. 210 N = 0: RESTORE 
  13. 220  READ T
  14. 230  IF T <0  THEN  RETURN 
  15. 240 N = N +1
  16. 250 D%(N) = T
  17. 260  GOTO 220
  18. 300  REM  ---SORT N ITEMS OF DATA IN D%()
  19. 310  IF N <2  THEN  RETURN : REM  THE LIST IS TOO SMALL TO SORT
  20. 320  FOR I = 2 TO N
  21. 330  FOR J = 1 TO I
  22. 340  IF D%(J) < = D%(I)  THEN 360
  23. 350 T = D%(I):D%(I) = D%(J):D%(J) = T
  24. 360  NEXT J
  25. 370  NEXT I
  26. 380  RETURN 
  27. 400  REM  ---PRINT OUT DATA IN D%()
  28. 410  IF N >0  THEN 430
  29. 420  PRINT "NO DATA WAS READ OR SORTED.": RETURN 
  30. 430  FOR I = 1 TO N
  31. 440  PRINT D%(I)
  32. 450  NEXT I
  33. 460  RETURN 
  34. 500  REM  ---DATA TO SORT
  35. 510  DATA  11,2345,45,234,6,68,556,56,75,345
  36. 520  DATA  234,233,3978,7768,678,79,6,56,7
  37. 530  DATA  -1