home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib19b.dsk / LOWRITE.bas < prev    next >
BASIC Source File  |  2023-02-26  |  2KB  |  54 lines
  1. 1  REM  **********************
  2. 2  REM  *       LOWRITE      *
  3. 3  REM  * BY  DAVID MEREDITH *
  4. 4  REM  * COPYRIGHT (C) 1984 *
  5. 5  REM  * BY MICROSPARC, INC *
  6. 6  REM  * LINCOLN, MA. 01773 *
  7. 7  REM  **********************
  8. 10  HIMEM: 36864
  9. 20  HOME : PRINT "** COPYRIGHT 1984 BY MICROSPARC, INC. **": PRINT 
  10. 30  PRINT "            LOWRITE"
  11. 40  PRINT "    "
  12. 50  PRINT "READS THE TEXT FILE YOU NAME"
  13. 60  PRINT "(FORMAT: N<CR>LINE1<CR>LINE2<CR>.."
  14. 70  PRINT "..LINEN<CR>), CONVERTS TO LOWER-"
  15. 80  PRINT "CASE WHERE APPROPRIATE, AND"
  16. 90  PRINT "SENDS THE TRANSLATED FILE TO"
  17. 100  PRINT "THE PRINTER"
  18. 110  PRINT : PRINT "HIT ANY KEY WHEN READY ";: GET I$
  19. 120  PRINT :D$ =  CHR$(4)
  20. 130  DIM A$(1000)
  21. 140  PRINT D$;"BLOAD AUTOCAP.OBJ0"
  22. 150  HOME : INPUT "INPUT FILE NAME PLEASE ";F$
  23. 160  PRINT "POET'S SWITCH ON (Y OR N)? ": GET I$: PRINT 
  24. 170  IF I$ = "Y"  THEN  POKE 38107,1: GOTO 190
  25. 180  POKE 38107,0
  26. 190  PRINT D$;"OPEN ";F$
  27. 200  PRINT D$;"READ ";F$
  28. 210  INPUT C
  29. 220  FOR X = 1 TO C
  30. 230 A$(X) = ""
  31. 240  GET I$
  32. 250  IF I$ =  CHR$(13) GOTO 340
  33. 260  POKE 235, ASC(I$)
  34. 270  CALL 38109
  35. 280  IF  PEEK(237) = 2 GOTO 320
  36. 290  IF  PEEK(237) = 0 GOTO 240
  37. 300 A$(X) = A$(X) + CHR$( PEEK(235))
  38. 310  GOTO 240
  39. 320 A$(X) = A$(X) + CHR$( PEEK(235)) + CHR$( PEEK(236))
  40. 330  GOTO 240
  41. 340  POKE 235, ASC(I$)
  42. 350  CALL 38109
  43. 360  IF  PEEK(237) = 2 GOTO 380
  44. 370  GOTO 390
  45. 380 A$(X) = A$(X) + CHR$( PEEK(235))
  46. 390  PRINT  CHR$(1);A$(X)
  47. 400  NEXT X
  48. 410  PRINT D$;"CLOSE ";F$: PRINT "DO YOU WANT A PRINTOUT? (Y/N)";: GET A$: PRINT : IF A$ = "N"  THEN 470
  49. 420  PRINT D$;"PR#1"
  50. 430  FOR X = 1 TO C
  51. 440  PRINT A$(X)
  52. 450  NEXT X
  53. 460  PRINT D$;"PR#0"
  54. 470  HOME : PRINT "DONE": END