home *** CD-ROM | disk | FTP | other *** search
/ Profi Club / Profi_Club_2_1992_-_de.d64 / lagerverwaltung (.txt) < prev    next >
Commodore BASIC  |  2023-02-26  |  5KB  |  210 lines

  1. 10 rem lagerverwaltung=========64
  2. 20 rem (p) commodore welt      ==
  3. 30 rem ==========================
  4. 40 rem (c) by                  ==
  5. 50 rem     dietmar schorr      ==
  6. 60 rem                         ==
  7. 70 rem version 2.0   40z./ascii==
  8. 80 rem  c-64  floppy/datasette ==
  9. 90 rem ==========================
  10. 95 gosub 60000
  11. 100 dimpk$(1000,8)
  12. 110 printcl$;
  13. 120 print"              "rn$"lagerverwaltung"
  14. 130 printc4$c4$"                   menue"
  15. 140 print"                   -----"
  16. 150 printc4$"         "rn$"1"rf$" produkte eingeben!"
  17. 160 printc4$"         "rn$"2"rf$" produkte einzel ausgeben"
  18. 170 printc4$"         "rn$"3"rf$" produkte: gesamtausgabe"
  19. 180 printc4$"         "rn$"4"rf$" finanzen ausgeben"
  20. 190 printc4$"         "rn$"5"rf$" verkaufen"
  21. 200 printc4$"         "rn$"6"rf$" einkaufen"
  22. 210 printc4$"         "rn$"7"rf$" speichern"
  23. 220 printc4$"         "rn$"8"rf$" laden"
  24. 230 printc4$"         "rn$"9"rf$" ende"
  25. 240 geta$:ifa$=""then240
  26. 250 ifval(a$)<1orval(a$)>9then240
  27. 260 onval(a$)goto440,770,950,1320,1370,1620,610,280,270
  28. 270 printcl$:end
  29. 280 printcl$left$(qd$,5)tab(9)rn$"f"rf$"loppy oder "rn$"d"rf$"atasette"
  30. 290 geta$:ifa$<>"f"anda$<>"d"then290
  31. 300 ifa$="d"thenga=1:goto350
  32. 310 ga=8:open1,8,0:close1:ifst<>-128then350
  33. 320 printleft$(qd$,6)tab(9)rn$" device not present "
  34. 330 geta$:ifa$=""then330
  35. 340 goto110
  36. 350 n$="":printleft$(qd$,5)"filename:";:inputn$
  37. 360 open1,ga,0,n$:b=0
  38. 370 fora=0to7
  39. 380 input#1,pk$(b,a)
  40. 390 nexta
  41. 400 b=b+1
  42. 410 ifst=0then370
  43. 420 close1
  44. 430 goto110
  45. 440 printcl$"                produkt"
  46. 450 input"              ";pk$(b,0)
  47. 460 printhe$left$(qd$,6)"  e-preis     v-preis     stueckzahl "
  48. 470 printhe$left$(qd$,10)"  gewicht     a-nummer    e-datum"
  49. 480 printhe$left$(qd$,14)"            lieferant"
  50. 490 printhe$left$(qd$,7);:inputpk$(b,1)
  51. 500 printhe$left$(qd$,7)left$(qr$,12);:inputpk$(b,2)
  52. 510 printhe$left$(qd$,7)left$(qr$,24);:inputpk$(b,3)
  53. 520 printhe$left$(qd$,11);:inputpk$(b,4)
  54. 530 printhe$left$(qd$,11)left$(qr$,12);:inputpk$(b,5)
  55. 540 printhe$left$(qd$,11)left$(qr$,24);:inputpk$(b,6)
  56. 550 printhe$left$(qd$,15)left$(qr$,10);:inputpk$(b,7)
  57. 560 b=b+1
  58. 570 printc4$c4$c4$"           "rn$"p"rf$"rodukt    "rn$"e"rf$"nde"c4$
  59. 580 geta$:ifa$<>"p"anda$<>"e"then580
  60. 590 ifa$="e"then110
  61. 600 goto440
  62. 610 printcl$left$(qd$,5)tab(9)rn$"f"rf$"loppy oder "rn$"d"rf$"atasette"
  63. 620 geta$:ifa$<>"f"anda$<>"d"then620
  64. 630 ifa$="d"thenga=1:goto680
  65. 640 ga=8:open1,8,0:close1:ifst<>-128then680
  66. 650 printleft$(qd$,6)tab(9)rn$" device not present "
  67. 660 geta$:ifa$=""then660
  68. 670 goto110
  69. 680 n$="":printleft$(qd$,5)"filename:";:inputn$
  70. 690 open1,ga,1,n$
  71. 700 forq=0tob-1
  72. 710 forx=0to7
  73. 720 print#1,pk$(q,x)
  74. 730 nextx
  75. 740 nextq
  76. 750 close1
  77. 760 goto110
  78. 770 printcl$left$(qd$,6)"welches produkt";:inputa$
  79. 780 x=0
  80. 790 ifval(pk$(x,3))=0then810
  81. 800 ifa$=pk$(x,0)then840
  82. 810 ifpk$(x,0)=""then110
  83. 820 x=x+1
  84. 830 goto790
  85. 840 printcl$"                produkt"
  86. 850 print,left$(qr$,6)pk$(x,0)
  87. 860 printhe$left$(qd$,6)"  e-preis     v-preis     stueckzahl "
  88. 870 printtab(2);pk$(x,1):printc2$;tab(14);pk$(x,2):printc2$;tab(26);pk$(x,3)
  89. 880 printc4$c4$c4$"  gewicht     a-nummer    e-datum"
  90. 890 printtab(2);pk$(x,4):printc2$;tab(14);pk$(x,5):printc2$;tab(26);pk$(x,6)
  91. 900 printc4$c4$c4$"              lieferant"
  92. 910 print,c4$left$(qr$,4)pk$(x,7)
  93. 920 printc4$c4$"             "rn$"fertig"
  94. 930 geta$:ifa$<>" "then930
  95. 940 goto110
  96. 950 ifb=0then110
  97. 960 printcl$
  98. 970 fori=0tob-1
  99. 980 forj=i+1tob
  100. 990 ifpk$(i,0)>pk$(j,0)then1020
  101. 1000 goto1110
  102. 1010 h$=pk$(i,0):pk$(i,0)=pk$(j,0):pk$(j,0)=h$
  103. 1020 foro=0to7
  104. 1030 h$(o)=pk$(i,o)
  105. 1040 nexto
  106. 1050 foro=0to7
  107. 1060 pk$(i,o)=pk$(j,o)
  108. 1070 nexto
  109. 1080 foro=0to7
  110. 1090 pk$(j,o)=h$(o)
  111. 1100 nexto
  112. 1110 nextj:nexti
  113. 1120 forq=0tob-1
  114. 1130 forw=0to7
  115. 1140 pk$(q,w)=pk$(q+1,w)
  116. 1150 nextw,q:pk$(q,0)=""
  117. 1160 goto1750
  118. 1170 x=0
  119. 1180 ifval(pk$(x,3))=0thenx=x+1:goto1300
  120. 1190 printcl$"                produkt"
  121. 1200 print,left$(qr$,6)pk$(x,0)
  122. 1210 printhe$left$(qd$,6)"  e-preis     v-preis     stueckzahl "
  123. 1220 printtab(2);pk$(x,1):printc2$;tab(14);pk$(x,2):printc2$;tab(26);pk$(x,3)
  124. 1230 printc4$c4$c4$"  gewicht     a-nummer    e-datum"
  125. 1240 printtab(2);pk$(x,4):printc2$;tab(14);pk$(x,5):printc2$;tab(26);pk$(x,6)
  126. 1250 printc4$c4$c4$"              lieferant"
  127. 1260 print,c4$left$(qr$,4)pk$(x,7)
  128. 1270 printc4$c4$"             "rn$"fertig"
  129. 1280 x=x+1
  130. 1290 geta$:ifa$<>" "then1290
  131. 1300 ifpk$(x,0)<>""then1180
  132. 1310 goto110
  133. 1320 ha$="gewinn":ifabs(g)<>gthenha$="verlust"
  134. 1330 g=int(100*g+.5)/100
  135. 1340 printcl$left$(qd$,10)"der "ha$" betraegt"abs(g)"dm."
  136. 1350 geta$:ifa$<>" "then1350
  137. 1360 goto110
  138. 1370 printcl$c4$c4$c4$"was wollen sie verkaufen";:inputa$
  139. 1380 x=0
  140. 1390 ifval(pk$(x,3))=0then1410
  141. 1400 ifpk$(x,0)=a$then1440
  142. 1410 ifpk$(x,0)=""then110
  143. 1420 x=x+1
  144. 1430 goto1390
  145. 1440 printc4$"einkaufspreis "pk$(x,1)" dm"
  146. 1450 printc4$"verkaufspreis "pk$(x,2)" dm"
  147. 1460 k=val(pk$(x,2))+(14*val(pk$(x,2)))/100
  148. 1470 printc4$"verkaufspreis mit mwst. "k"dm"
  149. 1480 printc4$c4$"-----------------------------"
  150. 1490 k=k-val(pk$(x,1))
  151. 1500 k=int(100*k+.5)/100
  152. 1510 ha$="gewinn":ifabs(k)<>kthenha$="verlust"
  153. 1520 printc4$ha$" :    "abs(k)"dm"
  154. 1530 g=g+k
  155. 1540 pk=val(pk$(x,3))
  156. 1550 pk=pk-1
  157. 1560 pk$(x,3)=str$(pk)
  158. 1570 ifpk>2then1600
  159. 1580 geta$:ifa$<>" "then1580
  160. 1590 printcl$c4$c4$c4$"sie muessen "pk$(x,0)" einkaufen."
  161. 1600 geta$:ifa$<>" "then1600
  162. 1610 goto110
  163. 1620 x=0
  164. 1630 printcl$left$(qd$,7)"welches produkt";:inputa$
  165. 1640 ifa$=pk$(x,0)then1680
  166. 1650 ifpk$(x,0)=""then110
  167. 1660 x=x+1
  168. 1670 goto1640
  169. 1680 printc4$c4$c4$"wieviele";:inputa
  170. 1690 k=val(pk$(x,3))
  171. 1700 k=k+a
  172. 1710 pk$(x,3)=str$(k)
  173. 1720 printleft$(qd$,4)"                 "rn$"fertig"
  174. 1730 geta$:ifa$<>" "then1730
  175. 1740 goto110
  176. 1750 printcl$left$(qd$,5)c3$c3$"ausgabe auf "rn$"b"rf$"ildschirm oder ";
  177. 1755 printrn$"d"rf$"rucker ?"
  178. 1760 geta$:ifa$<>"b"anda$<>"d"then1760
  179. 1770 ifa$="b"then1170
  180. 1780 open1,4,0:close1:ifst=-128then320
  181. 1790 open1,4
  182. 1800 x=0
  183. 1810 ifval(pk$(x,3))=0thenx=x+1:goto1940
  184. 1820 print#1,"produkt:"
  185. 1830 print#1,tab(9)pk$(x,0)
  186. 1840 print#1:print#1
  187. 1850 print#1,"e-preis:   "pk$(x,1)
  188. 1860 print#1,"v-preis:   "pk$(x,2)
  189. 1870 print#1,"stueckzahl:"pk$(x,3)
  190. 1880 print#1,"gewicht:   "pk$(x,4)
  191. 1890 print#1,"a-nummer:  "pk$(x,5)
  192. 1900 print#1,"e-datum:   "pk$(x,6)
  193. 1910 print#1,"lieferant: "pk$(x,7)
  194. 1920 print#1,"----------------------------------------"
  195. 1930 x=x+1
  196. 1940 ifpk$(x,0)<>""then1810
  197. 1950 print#1
  198. 1960 close1:goto110
  199. 60000 rem nachspann ===============
  200. 60010 rem * farbcodes/steuercodes *
  201. 60020 c4$=chr$(017):rn$=chr$(018)
  202. 60030 he$=chr$(019):c3$=chr$(029)
  203. 60040 c2$=chr$(145):rf$=chr$(146)
  204. 60050 cl$=chr$(147)
  205. 60060 rem ********* zeichenfolgen *
  206. 60070 for q=1 to 40
  207. 60080 qd$=qd$+c4$:qr$=qr$+c3$
  208. 60090 next q
  209. 60100 return:rem listingende
  210.