10 REM LAGERVERWALTUNG=========64
20 REM (P) COMMODORE WELT      ==
30 REM ==========================
40 REM (C) BY                  ==
50 REM     DIETMAR SCHORR      ==
60 REM                         ==
70 REM VERSION 2.0   40Z./ASCII==
80 REM  C-64  FLOPPY/DATASETTE ==
90 REM ==========================
95 GOSUB 60000
100 DIMPK$(1000,8)
110 PRINTCL$;
120 PRINT"              "RN$"LAGERVERWALTUNG"
130 PRINTC4$C4$"                   MENUE"
140 PRINT"                   -----"
150 PRINTC4$"         "RN$"1"RF$" PRODUKTE EINGEBEN!"
160 PRINTC4$"         "RN$"2"RF$" PRODUKTE EINZEL AUSGEBEN"
170 PRINTC4$"         "RN$"3"RF$" PRODUKTE: GESAMTAUSGABE"
180 PRINTC4$"         "RN$"4"RF$" FINANZEN AUSGEBEN"
190 PRINTC4$"         "RN$"5"RF$" VERKAUFEN"
200 PRINTC4$"         "RN$"6"RF$" EINKAUFEN"
210 PRINTC4$"         "RN$"7"RF$" SPEICHERN"
220 PRINTC4$"         "RN$"8"RF$" LADEN"
230 PRINTC4$"         "RN$"9"RF$" ENDE"
240 GETA$:IFA$=""THEN240
250 IFVAL(A$)<1ORVAL(A$)>9THEN240
260 ONVAL(A$)GOTO440,770,950,1320,1370,1620,610,280,270
270 PRINTCL$:END
280 PRINTCL$LEFT$(QD$,5)TAB(9)RN$"F"RF$"LOPPY ODER "RN$"D"RF$"ATASETTE"
290 GETA$:IFA$<>"F"ANDA$<>"D"THEN290
300 IFA$="D"THENGA=1:GOTO350
310 GA=8:OPEN1,8,0:CLOSE1:IFST<>-128THEN350
320 PRINTLEFT$(QD$,6)TAB(9)RN$" DEVICE NOT PRESENT "
330 GETA$:IFA$=""THEN330
340 GOTO110
350 N$="":PRINTLEFT$(QD$,5)"FILENAME:";:INPUTN$
360 OPEN1,GA,0,N$:B=0
370 FORA=0TO7
380 INPUT#1,PK$(B,A)
390 NEXTA
400 B=B+1
410 IFST=0THEN370
420 CLOSE1
430 GOTO110
440 PRINTCL$"                PRODUKT"
450 INPUT"              ";PK$(B,0)
460 PRINTHE$LEFT$(QD$,6)"  E-PREIS     V-PREIS     STUECKZAHL "
470 PRINTHE$LEFT$(QD$,10)"  GEWICHT     A-NUMMER    E-DATUM"
480 PRINTHE$LEFT$(QD$,14)"            LIEFERANT"
490 PRINTHE$LEFT$(QD$,7);:INPUTPK$(B,1)
500 PRINTHE$LEFT$(QD$,7)LEFT$(QR$,12);:INPUTPK$(B,2)
510 PRINTHE$LEFT$(QD$,7)LEFT$(QR$,24);:INPUTPK$(B,3)
520 PRINTHE$LEFT$(QD$,11);:INPUTPK$(B,4)
530 PRINTHE$LEFT$(QD$,11)LEFT$(QR$,12);:INPUTPK$(B,5)
540 PRINTHE$LEFT$(QD$,11)LEFT$(QR$,24);:INPUTPK$(B,6)
550 PRINTHE$LEFT$(QD$,15)LEFT$(QR$,10);:INPUTPK$(B,7)
560 B=B+1
570 PRINTC4$C4$C4$"           "RN$"P"RF$"RODUKT    "RN$"E"RF$"NDE"C4$
580 GETA$:IFA$<>"P"ANDA$<>"E"THEN580
590 IFA$="E"THEN110
600 GOTO440
610 PRINTCL$LEFT$(QD$,5)TAB(9)RN$"F"RF$"LOPPY ODER "RN$"D"RF$"ATASETTE"
620 GETA$:IFA$<>"F"ANDA$<>"D"THEN620
630 IFA$="D"THENGA=1:GOTO680
640 GA=8:OPEN1,8,0:CLOSE1:IFST<>-128THEN680
650 PRINTLEFT$(QD$,6)TAB(9)RN$" DEVICE NOT PRESENT "
660 GETA$:IFA$=""THEN660
670 GOTO110
680 N$="":PRINTLEFT$(QD$,5)"FILENAME:";:INPUTN$
690 OPEN1,GA,1,N$
700 FORQ=0TOB-1
710 FORX=0TO7
720 PRINT#1,PK$(Q,X)
730 NEXTX
740 NEXTQ
750 CLOSE1
760 GOTO110
770 PRINTCL$LEFT$(QD$,6)"WELCHES PRODUKT";:INPUTA$
780 X=0
790 IFVAL(PK$(X,3))=0THEN810
800 IFA$=PK$(X,0)THEN840
810 IFPK$(X,0)=""THEN110
820 X=X+1
830 GOTO790
840 PRINTCL$"                PRODUKT"
850 PRINT,LEFT$(QR$,6)PK$(X,0)
860 PRINTHE$LEFT$(QD$,6)"  E-PREIS     V-PREIS     STUECKZAHL "
870 PRINTTAB(2);PK$(X,1):PRINTC2$;TAB(14);PK$(X,2):PRINTC2$;TAB(26);PK$(X,3)
880 PRINTC4$C4$C4$"  GEWICHT     A-NUMMER    E-DATUM"
890 PRINTTAB(2);PK$(X,4):PRINTC2$;TAB(14);PK$(X,5):PRINTC2$;TAB(26);PK$(X,6)
900 PRINTC4$C4$C4$"              LIEFERANT"
910 PRINT,C4$LEFT$(QR$,4)PK$(X,7)
920 PRINTC4$C4$"             "RN$"FERTIG"
930 GETA$:IFA$<>" "THEN930
940 GOTO110
950 IFB=0THEN110
960 PRINTCL$
970 FORI=0TOB-1
980 FORJ=I+1TOB
990 IFPK$(I,0)>PK$(J,0)THEN1020
1000 GOTO1110
1010 H$=PK$(I,0):PK$(I,0)=PK$(J,0):PK$(J,0)=H$
1020 FORO=0TO7
1030 H$(O)=PK$(I,O)
1040 NEXTO
1050 FORO=0TO7
1060 PK$(I,O)=PK$(J,O)
1070 NEXTO
1080 FORO=0TO7
1090 PK$(J,O)=H$(O)
1100 NEXTO
1110 NEXTJ:NEXTI
1120 FORQ=0TOB-1
1130 FORW=0TO7
1140 PK$(Q,W)=PK$(Q+1,W)
1150 NEXTW,Q:PK$(Q,0)=""
1160 GOTO1750
1170 X=0
1180 IFVAL(PK$(X,3))=0THENX=X+1:GOTO1300
1190 PRINTCL$"                PRODUKT"
1200 PRINT,LEFT$(QR$,6)PK$(X,0)
1210 PRINTHE$LEFT$(QD$,6)"  E-PREIS     V-PREIS     STUECKZAHL "
1220 PRINTTAB(2);PK$(X,1):PRINTC2$;TAB(14);PK$(X,2):PRINTC2$;TAB(26);PK$(X,3)
1230 PRINTC4$C4$C4$"  GEWICHT     A-NUMMER    E-DATUM"
1240 PRINTTAB(2);PK$(X,4):PRINTC2$;TAB(14);PK$(X,5):PRINTC2$;TAB(26);PK$(X,6)
1250 PRINTC4$C4$C4$"              LIEFERANT"
1260 PRINT,C4$LEFT$(QR$,4)PK$(X,7)
1270 PRINTC4$C4$"             "RN$"FERTIG"
1280 X=X+1
1290 GETA$:IFA$<>" "THEN1290
1300 IFPK$(X,0)<>""THEN1180
1310 GOTO110
1320 HA$="GEWINN":IFABS(G)<>GTHENHA$="VERLUST"
1330 G=INT(100*G+.5)/100
1340 PRINTCL$LEFT$(QD$,10)"DER "HA$" BETRAEGT"ABS(G)"DM."
1350 GETA$:IFA$<>" "THEN1350
1360 GOTO110
1370 PRINTCL$C4$C4$C4$"WAS WOLLEN SIE VERKAUFEN";:INPUTA$
1380 X=0
1390 IFVAL(PK$(X,3))=0THEN1410
1400 IFPK$(X,0)=A$THEN1440
1410 IFPK$(X,0)=""THEN110
1420 X=X+1
1430 GOTO1390
1440 PRINTC4$"EINKAUFSPREIS "PK$(X,1)" DM"
1450 PRINTC4$"VERKAUFSPREIS "PK$(X,2)" DM"
1460 K=VAL(PK$(X,2))+(14*VAL(PK$(X,2)))/100
1470 PRINTC4$"VERKAUFSPREIS MIT MWST. "K"DM"
1480 PRINTC4$C4$"-----------------------------"
1490 K=K-VAL(PK$(X,1))
1500 K=INT(100*K+.5)/100
1510 HA$="GEWINN":IFABS(K)<>KTHENHA$="VERLUST"
1520 PRINTC4$HA$" :    "ABS(K)"DM"
1530 G=G+K
1540 PK=VAL(PK$(X,3))
1550 PK=PK-1
1560 PK$(X,3)=STR$(PK)
1570 IFPK>2THEN1600
1580 GETA$:IFA$<>" "THEN1580
1590 PRINTCL$C4$C4$C4$"SIE MUESSEN "PK$(X,0)" EINKAUFEN."
1600 GETA$:IFA$<>" "THEN1600
1610 GOTO110
1620 X=0
1630 PRINTCL$LEFT$(QD$,7)"WELCHES PRODUKT";:INPUTA$
1640 IFA$=PK$(X,0)THEN1680
1650 IFPK$(X,0)=""THEN110
1660 X=X+1
1670 GOTO1640
1680 PRINTC4$C4$C4$"WIEVIELE";:INPUTA
1690 K=VAL(PK$(X,3))
1700 K=K+A
1710 PK$(X,3)=STR$(K)
1720 PRINTLEFT$(QD$,4)"                 "RN$"FERTIG"
1730 GETA$:IFA$<>" "THEN1730
1740 GOTO110
1750 PRINTCL$LEFT$(QD$,5)C3$C3$"AUSGABE AUF "RN$"B"RF$"ILDSCHIRM ODER ";
1755 PRINTRN$"D"RF$"RUCKER ?"
1760 GETA$:IFA$<>"B"ANDA$<>"D"THEN1760
1770 IFA$="B"THEN1170
1780 OPEN1,4,0:CLOSE1:IFST=-128THEN320
1790 OPEN1,4
1800 X=0
1810 IFVAL(PK$(X,3))=0THENX=X+1:GOTO1940
1820 PRINT#1,"PRODUKT:"
1830 PRINT#1,TAB(9)PK$(X,0)
1840 PRINT#1:PRINT#1
1850 PRINT#1,"E-PREIS:   "PK$(X,1)
1860 PRINT#1,"V-PREIS:   "PK$(X,2)
1870 PRINT#1,"STUECKZAHL:"PK$(X,3)
1880 PRINT#1,"GEWICHT:   "PK$(X,4)
1890 PRINT#1,"A-NUMMER:  "PK$(X,5)
1900 PRINT#1,"E-DATUM:   "PK$(X,6)
1910 PRINT#1,"LIEFERANT: "PK$(X,7)
1920 PRINT#1,"----------------------------------------"
1930 X=X+1
1940 IFPK$(X,0)<>""THEN1810
1950 PRINT#1
1960 CLOSE1:GOTO110
60000 REM NACHSPANN ===============
60010 REM * FARBCODES/STEUERCODES *
60020 C4$=CHR$(017):RN$=CHR$(018)
60030 HE$=CHR$(019):C3$=CHR$(029)
60040 C2$=CHR$(145):RF$=CHR$(146)
60050 CL$=CHR$(147)
60060 REM ********* ZEICHENFOLGEN *
60070 FOR Q=1 TO 40
60080 QD$=QD$+C4$:QR$=QR$+C3$
60090 NEXT Q
60100 RETURN:REM LISTINGENDE