home *** CD-ROM | disk | FTP | other *** search
/ Go64! / Go64_1998-10_1998_CSW_Side_A.d64 / cmd-uhr.t-rd (.txt) < prev    next >
Commodore BASIC  |  2023-02-26  |  2KB  |  74 lines
  1. 10 rem ********************************
  2. 11 rem ** cmd-uhren von ramlink, hd  **
  3. 12 rem ** oder fd auslesen und in    **
  4. 13 rem ** basic weiterverarbeiten    **
  5. 14 rem ********************************
  6. 15 rem ** geschrieben 1998 von       **
  7. 16 rem ** matthias "honk man" heymann**
  8. 17 rem ********************************
  9. 18 rem ** das benutzen dieser routi- **
  10. 19 rem ** nen in eigenen programmen  **
  11. 20 rem ** ist erlaubt!               **
  12. 21 rem ********************************
  13. 22 rem **       "t-rd"-version       **
  14. 23 rem ********************************
  15. 24 :
  16. 40 input"[147]geraete-nr des cmd-geraetes mit uhr";lf
  17. 45 :
  18. 46 rem **********************
  19. 47 rem ***cmd-uhr auslesen***
  20. 48 rem **********************
  21. 49 :
  22. 60 open15,lf,15,"t-rd"
  23. 70 fori=0to7:get#15,c$:c(i)=asc(c$+chr$(0)):next
  24. 80 close15
  25. 95 :
  26. 96 rem **********************
  27. 97 rem **daten konvertieren**
  28. 98 rem **********************
  29. 99 :
  30. 100 wochentag=c(0):rem 0=so,1=mo,2=di..
  31. 110 jahr     =c(1)
  32. 120 mo       =c(2):rem monat
  33. 130 tag      =c(3)
  34. 140 s        =c(4):rem stunden
  35. 150 minuten  =c(5)
  36. 160 sekunden =c(6)
  37. 170 ap       =-(c(7)<>0):rem 0=am, 1=pm
  38. 179 :
  39. 180 for i=0 to 6:read t$(i):next
  40. 181 data sonntag, montag, dienstag, mittwoch, donnerstag, freitag, samstag
  41. 182 tag$=t$(wochentag)
  42. 194 :
  43. 195 rem**********************
  44. 196 rem*****stunden ins******
  45. 197 rem**24-stunden-format***
  46. 198 rem**********************
  47. 199 :
  48. 200 s2=s+12*(ap+(s=12))
  49. 295 :
  50. 296 rem**********************
  51. 297 rem*****ti$ setzen*******
  52. 298 rem**********************
  53. 299 :
  54. 300 h=s2*216000+mi*3600+se*60
  55. 310 t1=int(h/65536):h=h-65536*t1
  56. 320 t2=int(h/256):t3=h-256*t2
  57. 330 poke162,0:poke160,t1:poke161,t2:poke162,t3
  58. 395 :
  59. 396 rem**********************
  60. 397 rem****daten ausgeben****
  61. 398 rem**********************
  62. 399 :
  63. 400 print"wo =";wo
  64. 410 print"ja =";ja
  65. 420 print"mo =";mo
  66. 430 print"ta =";ta
  67. 440 print"s  =";s
  68. 450 print"mi =";mi
  69. 460 print"se =";se
  70. 470 print"ap =";ap:print
  71. 480 print"ta$=";ta$:print
  72. 490 print"s2 =";s2:print
  73. 500 print"ti$=";ti$
  74.