home *** CD-ROM | disk | FTP | other *** search
/ Go64! / Go64_1998-10_1998_CSW_Side_A.d64 / cmd-uhr.t-ra (.txt) < prev    next >
Commodore BASIC  |  2023-02-26  |  2KB  |  71 lines
  1. 10 rem ********************************
  2. 11 rem ** cmd-uhren von ramlink, hd  **
  3. 12 rem ** oder fd auslesen und in    **
  4. 13 rem ** basic weiterverarbeiten    **
  5. 14 rem ********************************
  6. 15 rem ** geschrieben 1998 von       **
  7. 16 rem ** matthias "honk man" heymann**
  8. 17 rem ********************************
  9. 18 rem ** das benutzen dieser routi- **
  10. 19 rem ** nen in eigenen programmen  **
  11. 20 rem ** ist erlaubt!               **
  12. 21 rem ********************************
  13. 22 rem **       "t-ra"-version       **
  14. 23 rem ********************************
  15. 24 :
  16. 40 input"[147]geraete-nr des cmd-geraetes mit uhr";lf
  17. 45 :
  18. 46 rem **********************
  19. 47 rem ***cmd-uhr auslesen***
  20. 48 rem **********************
  21. 49 :
  22. 50 open15,lf,15,"t-ra"
  23. 60 a$=""
  24. 70 get#15,c$:a$=a$+c$:ifst<>64then70
  25. 80 close15
  26. 95 :
  27. 96 rem **********************
  28. 97 rem **daten konvertieren**
  29. 98 rem **********************
  30. 99 :
  31. 100 wochentag$=left$(a$,4)
  32. 110 mo$       =mid$(a$,6,2) :rem monat
  33. 120 tag$      =mid$(a$,9,2)
  34. 130 jahr$     =mid$(a$,12,2)
  35. 140 stunden$  =mid$(a$,15,2)
  36. 150 minuten$  =mid$(a$,18,2)
  37. 160 sekunden$ =mid$(a$,21,2)
  38. 170 ap$       =mid$(a$,24,2):rem am/pm
  39. 194 :
  40. 195 rem**********************
  41. 196 rem*****stunden ins******
  42. 197 rem**24-stunden-format***
  43. 198 rem**********************
  44. 199 :
  45. 200 ap=-(ap$="pm"):h=val(st$)
  46. 210 s2$=right$(str$(h+12*(ap+(h=12))),2)
  47. 220 ifval(s2$)<10thens2$="0"+right$(s2$,1)
  48. 230 rem neue 24-stunden-variable: s2$
  49. 295 :
  50. 296 rem**********************
  51. 297 rem*****ti$ setzen*******
  52. 298 rem**********************
  53. 299 :
  54. 300 ti$=s2$+mi$+se$
  55. 395 :
  56. 396 rem**********************
  57. 397 rem****daten ausgeben****
  58. 398 rem**********************
  59. 399 :
  60. 400 print"a$ =";a$
  61. 410 print"wo$=";wo$
  62. 420 print"ta$=";ta$
  63. 430 print"mo$=";mo$
  64. 440 print"ja$=";ja$
  65. 450 print"st$=";st$
  66. 460 print"mi$=";mi$
  67. 470 print"se$=";se$
  68. 480 print"ap$=";ap$:print
  69. 490 print"s2$=";s2$:print
  70. 500 print"ti$=";ti$
  71.