home *** CD-ROM | disk | FTP | other *** search
/ Amiga ACS 1998 #6 / amigaacscoverdisc1998-061998.iso / games / descent / source / texmap / tmapfade.asm < prev    next >
Assembly Source File  |  1998-06-08  |  4KB  |  154 lines
  1. ;THE COMPUTER CODE CONTAINED HEREIN IS THE SOLE PROPERTY OF PARALLAX
  2. ;SOFTWARE CORPORATION ("PARALLAX").  PARALLAX, IN DISTRIBUTING THE CODE TO
  3. ;END-USERS, AND SUBJECT TO ALL OF THE TERMS AND CONDITIONS HEREIN, GRANTS A
  4. ;ROYALTY-FREE, PERPETUAL LICENSE TO SUCH END-USERS FOR USE BY SUCH END-USERS
  5. ;IN USING, DISPLAYING,  AND CREATING DERIVATIVE WORKS THEREOF, SO LONG AS
  6. ;SUCH USE, DISPLAY OR CREATION IS FOR NON-COMMERCIAL, ROYALTY OR REVENUE
  7. ;FREE PURPOSES.  IN NO EVENT SHALL THE END-USER USE THE COMPUTER CODE
  8. ;CONTAINED HEREIN FOR REVENUE-BEARING PURPOSES.  THE END-USER UNDERSTANDS
  9. ;AND AGREES TO THE TERMS HEREIN AND ACCEPTS THE SAME BY USE OF THIS FILE.  
  10. ;COPYRIGHT 1993-1998 PARALLAX SOFTWARE CORPORATION.  ALL RIGHTS RESERVED.
  11. ;
  12. ; $Source: f:/miner/source/texmap/rcs/tmapfade.asm $
  13. ; $Revision: 1.6 $
  14. ; $Author: john $
  15. ; $Date: 1995/02/20 18:23:01 $
  16. ; 
  17. ; .
  18. ; 
  19. ; $Log: tmapfade.asm $
  20. ; Revision 1.6  1995/02/20  18:23:01  john
  21. ; Put all the externs in the assembly modules into tmap_inc.asm.
  22. ; Also, moved all the C versions of the inner loops into a new module, 
  23. ; scanline.c.
  24. ; 
  25. ; Revision 1.5  1995/02/20  17:09:15  john
  26. ; Added code so that you can build the tmapper with no assembly!
  27. ; 
  28. ; Revision 1.4  1994/12/02  23:29:36  mike
  29. ; change jb/ja to jl/jg.
  30. ; 
  31. ; Revision 1.3  1994/11/30  00:57:36  mike
  32. ; *** empty log message ***
  33. ; 
  34. ; Revision 1.2  1994/10/06  18:38:49  john
  35. ; Added the ability to fade a scanline by calling gr_upoly_tmap
  36. ; with Gr_scanline_darkening_level with a value < MAX_FADE_LEVELS.
  37. ; 
  38. ; Revision 1.1  1994/10/06  18:04:42  john
  39. ; Initial revision
  40. ; 
  41. ; 
  42.     .386
  43.  
  44.     public    asm_tmap_scanline_shaded_
  45.  
  46.     include    tmap_inc.asm
  47.  
  48. _DATA    SEGMENT DWORD PUBLIC USE32 'DATA'
  49.         
  50. _loop_count        dd    0
  51.  
  52. _DATA    ENDS
  53.  
  54. DGROUP    GROUP    _DATA
  55.  
  56. _TEXT   SEGMENT PARA PUBLIC USE32 'CODE'
  57.  
  58.     ASSUME    DS:_DATA
  59.     ASSUME    CS:_TEXT
  60.  
  61. ; --------------------------------------------------------------------------------------------------
  62. ; Enter:
  63. ;    _xleft    fixed point left x coordinate
  64. ;    _xright    fixed point right x coordinate
  65. ;    _y    fixed point y coordinate
  66. ;**;    _pixptr    address of source pixel map
  67.  
  68. ;   for (x = (int) xleft; x <= (int) xright; x++) {
  69. ;      _setcolor(read_pixel_from_tmap(srcb,((int) (u/z)) & 63,((int) (v/z)) & 63));
  70. ;      _setpixel(x,y);
  71. ;
  72. ;      z += dz_dx;
  73. ;   }
  74.  
  75. asm_tmap_scanline_shaded_:
  76.     push fs
  77.     pusha
  78.  
  79.     mov    fs, _gr_fade_table_selector
  80.  
  81. ; Setup for loop:    _loop_count  iterations = (int) xright - (int) xleft
  82. ;    edi    initial row pointer = y*320+x
  83.  
  84. ; set edi = address of first pixel to modify
  85.     mov    edi,_fx_y
  86.  cmp edi,_window_bottom
  87.  jae _none_to_do
  88.  
  89.     imul    edi,_bytes_per_row
  90.     mov    eax,_fx_xleft
  91.     test    eax,eax
  92.     jns    eax_ok
  93.     sub    eax,eax
  94. eax_ok:
  95.     add    edi,eax
  96.     add    edi,write_buffer
  97.  
  98. ; set _loop_count = # of iterations
  99.     mov    eax,_fx_xright
  100.  
  101.     cmp    eax,_window_right
  102.     jl    eax_ok1
  103.     mov    eax,_window_right
  104. eax_ok1:    cmp    eax,_window_left
  105.     jg    eax_ok2
  106.     mov    eax,_window_left
  107. eax_ok2:
  108.     mov    ebx,_fx_xleft
  109.     sub    eax,ebx
  110.     js    _none_to_do
  111.     cmp    eax,_window_width
  112.     jbe    _ok_to_do
  113.     mov    eax,_window_width
  114. _ok_to_do:
  115.     mov    _loop_count, eax
  116.  
  117.     mov    ecx, 0
  118.     mov    ch,_tmap_flat_shade_value
  119.     and    ch, 31
  120.     
  121. _size = (_end1 - _start1)/num_iters
  122.     mov    eax,num_iters-1
  123.     sub    eax,_loop_count
  124.     jns    j_eax_ok1
  125.     inc    eax    ; sort of a hack, but we can get -1 here and want to be graceful
  126.     jns    j_eax_ok1    ; if we jump, we had -1, which is kind of ok, if not, we int 3
  127.     int    3    ; oops, going to jump behind _start1, very bad...
  128.     sub    eax,eax    ; ok to continue
  129. j_eax_ok1:    imul    eax,eax,dword ptr _size
  130.     add    eax,offset _start1
  131.     jmp    eax
  132.  
  133.     align    4
  134. _start1:
  135.  
  136. rept num_iters
  137. local l1
  138.     mov    cl, [edi]        ; get pixel
  139.     mov    al, fs:[ecx]        ; darken pixel
  140.     mov    [edi], al        ; write pixel
  141.     inc    edi            ; goto next pixel
  142. endm
  143. _end1:
  144.  
  145. _none_to_do:    popa
  146.         pop    fs
  147.     ret
  148.  
  149.  
  150. _TEXT    ends
  151.  
  152.     end
  153. 
  154.