home *** CD-ROM | disk | FTP | other *** search
/ Amiga ACS 1998 #6 / amigaacscoverdisc1998-061998.iso / games / descent / source / texmap / tmapdith.asm < prev    next >
Assembly Source File  |  1998-06-08  |  22KB  |  998 lines
  1. ;THE COMPUTER CODE CONTAINED HEREIN IS THE SOLE PROPERTY OF PARALLAX
  2. ;SOFTWARE CORPORATION ("PARALLAX").  PARALLAX, IN DISTRIBUTING THE CODE TO
  3. ;END-USERS, AND SUBJECT TO ALL OF THE TERMS AND CONDITIONS HEREIN, GRANTS A
  4. ;ROYALTY-FREE, PERPETUAL LICENSE TO SUCH END-USERS FOR USE BY SUCH END-USERS
  5. ;IN USING, DISPLAYING,  AND CREATING DERIVATIVE WORKS THEREOF, SO LONG AS
  6. ;SUCH USE, DISPLAY OR CREATION IS FOR NON-COMMERCIAL, ROYALTY OR REVENUE
  7. ;FREE PURPOSES.  IN NO EVENT SHALL THE END-USER USE THE COMPUTER CODE
  8. ;CONTAINED HEREIN FOR REVENUE-BEARING PURPOSES.  THE END-USER UNDERSTANDS
  9. ;AND AGREES TO THE TERMS HEREIN AND ACCEPTS THE SAME BY USE OF THIS FILE.  
  10. ;COPYRIGHT 1993-1998 PARALLAX SOFTWARE CORPORATION.  ALL RIGHTS RESERVED.
  11. ;
  12. ; $Source: f:/miner/source/texmap/rcs/tmap_per.asm $
  13. ; $Revision: 1.18 $
  14. ; $Author: mike $
  15. ; $Date: 1994/05/03 11:08:32 $
  16. ;
  17. ; Perspective texture mapper inner loop.
  18. ;
  19. ; $Log: tmap_per.asm $
  20. ; Revision 1.18  1994/05/03  11:08:32  mike
  21. ; Trap divide overflows.
  22. ; 
  23. ; Revision 1.17  1994/04/21  15:03:41  mike
  24. ; make faster.
  25. ; 
  26. ; Revision 1.16  1994/04/08  16:46:57  john
  27. ; Made 32 fade levels. Hacked.
  28. ; 
  29. ; Revision 1.15  1994/03/31  08:35:18  mike
  30. ; Fix quantized-by-4 bug in inner loop.
  31. ; 
  32. ; Revision 1.14  1994/03/14  17:41:14  mike
  33. ; Fix bug in unlighted version.
  34. ; 
  35. ; Revision 1.13  1994/03/14  15:45:14  mike
  36. ; streamline code.
  37. ; 
  38. ; Revision 1.12  1994/01/14  14:01:58  mike
  39. ; *** empty log message ***
  40. ; 
  41. ; Revision 1.11  1993/12/18  14:43:44  john
  42. ; Messed around with doing 1/z, the u*(1/z) and v*(1/z)
  43. ; (Went from 23 fps to 21 fps... not good! )
  44. ;
  45. ; Revision 1.10  1993/12/17  16:14:17  john
  46. ; Split lighted/nonlighted, so there is no cmp lighting
  47. ; in the inner loop. 
  48. ; 
  49. ; Revision 1.9  1993/12/17  12:34:29  john
  50. ; Made leftover bytes use linear approx instead of correct...
  51. ; should save about 8 divides per scanline on average.
  52. ; Also, took out anti-aliasing code and rearranged to
  53. ; order of some instructions to help on 486 pipelining.
  54. ; (The anti-aliasing code did *not* look good, so I
  55. ; figure there was no reason to keep it in. )
  56. ; 
  57. ; Revision 1.8  1993/12/16  18:37:52  mike
  58. ; Align some stuff on 4 byte boundaries.
  59. ; 
  60. ; Revision 1.7  1993/11/30  08:44:18  john
  61. ; Made selector set check for < 64*64 bitmaps.
  62. ; 
  63. ; Revision 1.6  1993/11/23  17:25:26  john
  64. ; Added safety "and eax, 0fffh" in lighting lookup.
  65. ; 
  66. ; Revision 1.5  1993/11/23  15:08:52  mike
  67. ; Fixed lighting bug. 
  68. ; 
  69. ; Revision 1.4  1993/11/23  14:38:50  john
  70. ; optimized NORMAL code by switching EBX and ESI, so BH can be used in
  71. ; the lighting process.
  72. ; 
  73. ; Revision 1.3  1993/11/23  14:30:53  john
  74. ; Made the perspective tmapper do 1/8 divides; added lighting.
  75. ; 
  76. ; Revision 1.2  1993/11/22  10:24:59  mike
  77. ; *** empty log message ***
  78. ; 
  79. ; Revision 1.1  1993/09/08  17:29:53  mike
  80. ; Initial revision
  81. ; 
  82. ;
  83. ;
  84.  
  85.     .386
  86.  
  87.     public    _fx_u,_fx_v,_fx_z,_fx_du_dx,_fx_dv_dx,_fx_dz_dx,_fx_y,_fx_xleft,_fx_xright
  88.     public    _pixptr
  89.     public    asm_tmap_scanline_per_
  90.  
  91.     include    tmap_inc.asm
  92.  
  93.  public _max_ecx,_min_ecx
  94.  
  95.     extern    _fx_l:dword
  96.     extern     _fx_dl_dx:dword
  97.     extern    _dither_intensity_lighting:dword
  98.     extern    _Lighting_on:dword
  99.     extern    _pixel_data_selector:word, _gr_fade_table_selector:word, _transparency_on:dword
  100.  
  101. _DATA    SEGMENT DWORD PUBLIC USE32 'DATA'
  102.     align    4
  103. ;**_v_window_left    dd    _window_left
  104. ;**_v_window_right    dd    _window_right
  105. ;**_v_window_top    dd    _window_top
  106. ;**_v_window_bottom    dd    _window_bottom
  107.  
  108. ; ---------- These are passed in by the C caller ----------
  109. _fx_u    dd    ?    
  110. _fx_v    dd    ?
  111. _fx_z    dd    ?
  112. _fx_du_dx    dd    ?
  113. _fx_dv_dx    dd    ?
  114. _fx_dz_dx    dd    ?
  115.  
  116. _fx_y    dd    ?
  117. _fx_xleft    dd    ?
  118. _fx_xright    dd    ?
  119.  
  120. _pixptr    dd    ?
  121. ; ----------^^ These are passed in by the C caller ^^----------
  122.  
  123.     public    _x,_loop_count
  124.     align    4
  125. _x    dd    ?
  126. _loop_count    dd    ?
  127.  
  128. _max_ecx    dd    0
  129. _min_ecx    dd    55555555h
  130.  
  131.     public    _per2_flag
  132. _per2_flag    dd    1
  133.  
  134.     public    _scan_doubling_flag, _linear_if_far_flag
  135.  
  136. _scan_doubling_flag    dd 0
  137. _linear_if_far_flag    dd 0
  138.  
  139. ;---------- local variables
  140.     align    4
  141. req_base    dd    ?
  142. req_size    dd    ?
  143. U0    dd    ?
  144. U1    dd    ?
  145. V0    dd    ?
  146. V1    dd    ?
  147. num_left_over    dd    ?
  148. DU1    dd    ?
  149. DV1    dd    ?
  150. DZ1    dd    ?
  151. ;*NO_DITHER _fx_dl_dx1    dd    ?
  152. ;*NO_DITHER _fx_dl_dx2    dd    ?
  153.  
  154. _DATA    ENDS
  155.  
  156. DGROUP    GROUP    _DATA
  157.  
  158.  
  159. _TEXT   SEGMENT DWORD PUBLIC USE32 'CODE'
  160.     ASSUME    DS:_DATA
  161.     ASSUME    CS:_TEXT
  162.  
  163. ; --------------------------------------------------------------------------------------------------
  164. ; Enter:
  165. ;    _xleft    fixed point left x coordinate
  166. ;    _xright    fixed point right x coordinate
  167. ;    _y    fixed point y coordinate
  168. ;    _pixptr    address of source pixel map
  169. ;    _u    fixed point initial u coordinate
  170. ;    _v    fixed point initial v coordinate
  171. ;    _z    fixed point initial z coordinate
  172. ;    _du_dx    fixed point du/dx
  173. ;    _dv_dx    fixed point dv/dx
  174. ;    _dz_dx    fixed point dz/dx
  175.  
  176. ;   for (x = (int) xleft; x <= (int) xright; x++) {
  177. ;      _setcolor(read_pixel_from_tmap(srcb,((int) (u/z)) & 63,((int) (v/z)) & 63));
  178. ;      _setpixel(x,y);
  179. ;
  180. ;      u += du_dx;
  181. ;      v += dv_dx;
  182. ;      z += dz_dx;
  183. ;   }
  184.  
  185.  
  186. asm_tmap_scanline_per_:
  187.     push    es
  188.     push    fs
  189.     pusha
  190.     
  191. ;---------------------------- setup for loop ---------------------------------
  192. ; Setup for loop:    _loop_count  iterations = (int) xright - (int) xleft
  193. ;    esi    source pixel pointer = pixptr
  194. ;    edi    initial row pointer = y*320+x
  195.  
  196. ; set esi = pointer to start of texture map data
  197.     mov    es,_pixel_data_selector    ; selector[0*2]
  198.     mov    fs,_gr_fade_table_selector    ; selector[1*2]    ; fs = bmd_fade_table
  199.  
  200. ; set edi = address of first pixel to modify
  201.     mov    edi,_fx_y
  202.     cmp    edi,_window_bottom
  203.     jae    _none_to_do
  204.  
  205.     imul    edi,_bytes_per_row
  206.     mov    eax,_fx_xleft
  207.     sar    eax,16
  208.     jns    eax_ok
  209.     sub    eax,eax
  210. eax_ok:
  211.     add    edi,eax
  212.     add    edi,write_buffer
  213.  
  214. ; set _loop_count = # of iterations
  215.     mov    eax,_fx_xright
  216.     sar    eax,16
  217.     cmp    eax,_window_right
  218.     jb    eax_ok1
  219.     mov    eax,_window_right
  220. eax_ok1:    cmp    eax,_window_left
  221.     ja    eax_ok2
  222.     mov    eax,_window_left
  223. eax_ok2:
  224.  
  225.     mov    ebx,_fx_xleft
  226.     sar    ebx,16
  227.     sub    eax,ebx
  228.     js    _none_to_do
  229.     cmp    eax,_window_width
  230.     jbe    _ok_to_do
  231.     mov    eax,_window_width
  232. _ok_to_do:
  233.     mov    _loop_count,eax
  234.  
  235. ; lighting values are passed in fixed point, but need to be in 8 bit integer, 8 bit fraction so we can easily
  236. ; get the integer by reading %bh
  237.     sar    _fx_l, 8
  238.     sar    _fx_dl_dx,8
  239.     jns    dl_dx_ok
  240.     inc    _fx_dl_dx    ; round towards 0 for negative deltas
  241. dl_dx_ok:
  242.  
  243. ;*NO_DITHER ;-------------------------- setup for dithering -----------------------------
  244. ;*NO_DITHER ; do dithering, use lighting values which are .5 less than and .5 more than actual value
  245. ;*NO_DITHER     mov    ebx,40h    ; assume dithering on
  246. ;*NO_DITHER     mov    eax,_fx_dl_dx
  247. ;*NO_DITHER     add    eax,ebx    ; add 1/2
  248. ;*NO_DITHER     mov    _fx_dl_dx1,eax
  249. ;*NO_DITHER     mov    eax,_fx_dl_dx
  250. ;*NO_DITHER     sub    eax,ebx
  251. ;*NO_DITHER     mov    _fx_dl_dx2,eax
  252. ;*NO_DITHER     mov    ebx,_fx_xleft
  253. ;*NO_DITHER     shr    ebx,16
  254. ;*NO_DITHER     xor    ebx,_fx_y
  255. ;*NO_DITHER     and    ebx,1
  256. ;*NO_DITHER     jne    dith_1
  257. ;*NO_DITHER     xchg    eax,_fx_dl_dx1
  258. ;*NO_DITHER dith_1:    mov    _fx_dl_dx2,eax
  259.  
  260. ; set initial values
  261.     mov    ebx,_fx_u
  262.     mov    ebp,_fx_v
  263.     mov    ecx,_fx_z
  264.  
  265.     test    _per2_flag,-1
  266.     je    tmap_loop
  267.  
  268.     cmp    _Lighting_on, 0
  269.     je    tmap_loop_fast_nolight
  270.     jmp    tmap_loop_fast
  271.  
  272. ;================ PERSPECTIVE TEXTURE MAP INNER LOOPS ========================
  273. ;
  274. ; Usage in loop:    eax    division, pixel value
  275. ;    ebx    u
  276. ;    ecx    z
  277. ;    edx    division
  278. ;    ebp    v
  279. ;    esi    source pixel pointer
  280. ;    edi    destination pixel pointer
  281.  
  282. ;-------------------- NORMAL PERSPECTIVE TEXTURE MAP LOOP -----------------
  283.     align    4
  284. tmap_loop:
  285.     xchg    ebx, esi
  286.  
  287. ; compute v coordinate
  288.     mov    eax,ebp    ; get v
  289.     cdq
  290.     idiv    ecx    ; eax = (v/z)
  291.  
  292.     and    eax,3fh    ; mask with height-1
  293.     mov    ebx,eax
  294.  
  295. ; compute u coordinate
  296.     mov    eax,esi    ; get u
  297.     cdq
  298.     idiv    ecx    ; eax = (u/z)
  299.  
  300.     shl     eax,26
  301.     shld     ebx,eax,6    ; esi = v*64+u
  302.  
  303. ; read 1  pixel
  304.     movzx    eax,byte ptr es:[ebx]    ; get pixel from source bitmap
  305.  
  306.     cmp    _Lighting_on, 0
  307.     je    NoLight1
  308.  
  309. ; LIGHTING CODE
  310.     mov    ebx, _fx_l    ; get temp copy of lighting value
  311.     mov    ah, bh        ; get lighting level
  312.     add    ebx, _fx_dl_dx    ; update lighting value
  313.  
  314. ;*NO_DITHER     add    ebx, _fx_dl_dx1    ; update lighting value
  315. ;*NO_DITHER    and    eax, (32*256)-1
  316. ;*NO_DITHER     push    eax            ; dithering
  317. ;*NO_DITHER     mov    eax, _fx_dl_dx2
  318. ;*NO_DITHER     xchg    _fx_dl_dx1, eax
  319. ;*NO_DITHER     mov    _fx_dl_dx2, eax
  320. ;*NO_DITHER     pop    eax
  321.  
  322.     mov    al, fs:[eax]    ; xlat pixel thru lighting tables
  323.     mov    _fx_l, ebx    ; save temp copy of lighting value
  324.  
  325. ; transparency check
  326. NoLight1:    cmp    al,255
  327.     je    skip1
  328.  
  329.     mov    [edi],al
  330. skip1:    inc    edi
  331.     
  332. ; update deltas
  333.     add    ebp,_fx_dv_dx
  334.     add    esi,_fx_du_dx
  335.     add    ecx,_fx_dz_dx
  336.     je    _div_0_abort    ; would be dividing by 0, so abort
  337.  
  338.     xchg    esi, ebx
  339.  
  340.     dec    _loop_count
  341.     jns    tmap_loop
  342.  
  343. _none_to_do:    
  344.     popa
  345.     pop    fs
  346.     pop    es
  347.     ret
  348.  
  349. ; We detected a z=0 condition, which seems pretty bogus, don't you think?
  350. ; So, we abort, but maybe we want to know about it.
  351. _div_0_abort:
  352. ;**    int    3
  353.     jmp    _none_to_do
  354.  
  355. ;-------------------------- PER/4 TMAPPER ----------------
  356. ; 
  357. ;    x = x1
  358. ;    U0 = u/w; V0 = v/w;
  359. ;    while ( 1 )
  360. ;        u += du_dx*4; v+= dv_dx*4
  361. ;        U1 = u/w; V1 = v/w;
  362. ;        DUDX = (U1-U0)/4; DVDX = (V1-V0)/4;
  363. ;
  364. ;    ; Pixel 0
  365. ;        pixels = texmap[V0*64+U0];
  366. ;        U0 += DUDX; V0 += DVDX
  367. ;    ; Pixel 1
  368. ;        pixels = (pixels<<8)+texmap[V0*64+U0];
  369. ;        U0 += DUDX; V0 += DVDX
  370. ;    ; Pixel 2
  371. ;        pixels = (pixels<<8)+texmap[V0*64+U0];
  372. ;        U0 += DUDX; V0 += DVDX
  373. ;    ; Pixel 3
  374. ;        pixels = (pixels<<8)+texmap[V0*64+U0];
  375. ;
  376. ;        screen[x] = pixel
  377. ;        x += 4;
  378. ;        U0 = U1; V0 = V1 
  379.  
  380. NBITS = 3
  381. ZSHIFT = 3
  382.  
  383.  
  384. PDIV MACRO
  385. ; Returns EAX/ECX in 16.16 format in EAX. Trashes EDX
  386. ;          sig bits   6.3
  387. ;--old--    cdq
  388. ;--old--    shld    edx,eax, ZSHIFT
  389. ;--old--    lea    eax, [eax*8]
  390. ;--old--    idiv    ecx    ; eax = (v/z)
  391. ;--old--    shl    eax, 16-ZSHIFT
  392.  
  393.     mov    edx,eax
  394.     shl    eax,ZSHIFT
  395.     sar    edx,32-ZSHIFT
  396.     idiv    ecx    ; eax = (v/z)
  397.     shl    eax, 16-ZSHIFT
  398.  
  399. ENDM
  400.  
  401. wr_onepix    macro    num
  402.     local    skip
  403.     cmp    cl,255
  404.     je    skip
  405.     mov    num[edi],cl
  406.     ror    ecx,8
  407. skip:
  408.     endm
  409.  
  410. public tmap_loop_fast
  411.  
  412. ; -------------------------------------- Start of Getting Dword Aligned ----------------------------------------------
  413. ;    ebx    fx_u
  414.  
  415. tmap_loop_fast:
  416.     mov    esi,ebx
  417.  
  418.     align    4
  419. NotDwordAligned1:
  420.     test    edi, 11b
  421.     jz    DwordAligned1
  422.  
  423. ; compute v coordinate
  424.     mov    eax,ebp    ; get v
  425.     cdq
  426.     idiv    ecx    ; eax = (v/z)
  427.  
  428.     and    eax,3fh    ; mask with height-1
  429.     mov    ebx,eax
  430.  
  431. ; compute u coordinate
  432.     mov    eax,esi    ; get u
  433.     cdq
  434.     idiv    ecx    ; eax = (u/z)
  435.  
  436.     shl     eax,26
  437.     shld     ebx,eax,6    ; esi = v*64+u
  438.  
  439. ; read 1  pixel
  440.     movzx    eax,byte ptr es:[ebx]    ; get pixel from source bitmap
  441.  
  442. ; lighting code
  443.     mov    ebx, _fx_l    ; get temp copy of lighting value
  444.     mov    ah, bh    ; get lighting level
  445.     add    ebx, _fx_dl_dx    ; update lighting value
  446.     mov    _fx_l, ebx    ; save temp copy of lighting value
  447.  
  448. ; transparency check
  449.     cmp    al,255
  450.     je    skip2    ; this pixel is transparent, so don't write it (or light it)
  451.  
  452.     mov    al, fs:[eax]    ; xlat pixel thru lighting tables
  453.                     
  454. ; write 1 pixel
  455.     mov    [edi],al
  456. skip2:    inc    edi
  457.     
  458. ; update deltas
  459.     add    ebp,_fx_dv_dx
  460.     add    esi,_fx_du_dx
  461.     add    ecx,_fx_dz_dx
  462.     je    _div_0_abort    ; would be dividing by 0, so abort
  463.  
  464.     dec    _loop_count
  465.     jns    NotDwordAligned1
  466.     jmp    _none_to_do
  467.  
  468. ; -------------------------------------- End of Getting Dword Aligned ----------------------------------------------
  469.  
  470. DwordAligned1:
  471.     mov    ebx,esi    ; get fx_u
  472.  
  473.     mov    eax, _loop_count
  474.     inc    eax
  475.     mov    num_left_over, eax
  476.     shr    eax, NBITS
  477.  
  478.     cmp    eax, 0        
  479.     je    tmap_loop
  480.     
  481.     mov     _loop_count, eax    ; _loop_count = pixels / NPIXS
  482.     shl    eax, 3
  483.     sub    num_left_over, eax    ; num_left_over = obvious
  484.         
  485. ; compute initial v coordinate
  486.     mov    eax,ebp    ; get v
  487.     mov    edx,ebp
  488.     shl    eax,ZSHIFT
  489.     sar    edx,32-ZSHIFT
  490.     idiv    ecx    ; eax = (v/z)
  491.     shl    eax, 16-ZSHIFT
  492.     mov    V0, eax
  493.  
  494. ; compute initial u coordinate
  495.     mov    eax,ebx    ; get u
  496.     mov    edx,ebx
  497.     shl    eax,ZSHIFT
  498.     sar    edx,32-ZSHIFT
  499.     idiv    ecx    ; eax = (v/z)
  500.     shl    eax, 16-ZSHIFT
  501.     mov    U0, eax
  502.  
  503. ; Set deltas to NPIXS pixel increments
  504.     mov    eax, _fx_du_dx
  505.     shl    eax, 3
  506.     mov    DU1, eax
  507.     mov    eax, _fx_dv_dx
  508.     shl    eax, 3
  509.     mov    DV1, eax
  510.     mov    eax, _fx_dz_dx
  511.     shl    eax, 3
  512.     mov    DZ1, eax
  513.  
  514.     align    4
  515. TopOfLoop4:
  516.     add    ebx, DU1
  517.     add    ebp, DV1
  518.     add    ecx, DZ1
  519.     je    _div_0_abort    ; would be dividing by 0, so abort
  520.  
  521. ; Done with ebx, ebp, ecx until next iteration
  522.     push    ebx
  523.     push    ecx
  524.     push    ebp
  525.     push    edi
  526.     
  527. ; Find fixed U1        
  528.     mov    eax, ebx
  529.     mov    edx,ebx
  530.     shl    eax,ZSHIFT
  531.     sar    edx,32-ZSHIFT
  532.     idiv    ecx    ; eax = (v/z)
  533.     shl    eax, 16-ZSHIFT
  534.     mov    ebx, eax    ; ebx = U1 until pop's
  535.  
  536. ; Find fixed V1        
  537.     mov    eax, ebp
  538.     mov    edx, ebp
  539.     shl    eax,ZSHIFT
  540.     sar    edx,32-ZSHIFT
  541.     idiv    ecx    ; eax = (v/z)
  542.  
  543.     mov    ecx, U0    ; ecx = U0 until pop's
  544.     mov    edi, V0    ; edi = V0 until pop's
  545.  
  546.     shl    eax, 16-ZSHIFT
  547.     mov    ebp, eax    ; ebp = V1 until pop's
  548.  
  549. ; Make ESI =  V0:U0 in 6:10,6:10 format
  550.     mov    eax, ecx
  551.     shr    eax, 6
  552.     mov    esi, edi
  553.     shl    esi, 10
  554.     mov    si, ax
  555.         
  556. ; Make EDX = DV:DU in 6:10,6:10 format
  557.     mov    eax, ebx
  558.     sub    eax, ecx
  559.     sar    eax, NBITS+6
  560.     mov    edx, ebp
  561.     sub    edx, edi
  562.     shl    edx, 10-NBITS    ; EDX = V1-V0/ 4 in 6:10 int:frac
  563.     mov    dx, ax    ; put delta u in low word
  564.  
  565. ; Save the U1 and V1 so we don't have to divide on the next iteration
  566.     mov    U0, ebx
  567.     mov    V0, ebp
  568.  
  569.     pop    edi    ; Restore EDI before using it
  570.         
  571. ; LIGHTING CODE
  572.     mov    ebx, _fx_l
  573.     mov    ebp, _fx_dl_dx
  574.  
  575.     test    _transparency_on,-1
  576.     je    no_trans1
  577.  
  578.     REPT (1 SHL (NBITS-2))
  579.     local    skip3,no_trans1
  580.         REPT 2
  581.     local    skipa1,skipa2
  582.  
  583.     mov    eax, esi    ; get u,v
  584.     shr    eax, 26    ; shift out all but int(v)
  585.     shld    ax,si,6    ; shift in u, shifting up v
  586.     add    esi, edx    ; inc u,v
  587.     mov     al, es:[eax]    ; get pixel from source bitmap
  588.     cmp    al,255
  589.     je    skipa1
  590.     mov    ah, bh    ; form lighting table lookup value
  591.     add    ebx, ebp    ; update lighting value
  592.     mov    al, fs:[eax]    ; xlat thru lighting table into dest buffer
  593.     mov    [edi],al
  594. skipa1:
  595.     inc    edi
  596.  
  597. ; Do odd pixel
  598.     mov    eax, esi    ; get u,v
  599.     shr    eax, 26    ; shift out all but int(v)
  600.     shld    ax,si,6    ; shift in u, shifting up v
  601.     add    esi, edx    ; inc u,v
  602.     mov     al, es:[eax]    ; get pixel from source bitmap
  603.     cmp    al,255
  604.     je    skipa2
  605.     mov    ah, bh    ; form lighting table lookup value
  606.     add    ebx, ebp    ; update lighting value
  607.     mov    al, fs:[eax]    ; xlat thru lighting table into dest buffer
  608.     mov    [edi],al
  609. skipa2:
  610.     inc    edi
  611.  
  612.         ENDM
  613.  
  614.     ENDM
  615.     jmp    cont1
  616.  
  617. ; -------------------------------------------------------
  618. no_trans1:
  619.     REPT (1 SHL (NBITS-2))
  620.     local    skip3
  621.         REPT 2
  622.  
  623.     mov    eax, esi    ; get u,v
  624.     shr    eax, 26    ; shift out all but int(v)
  625.     shld    ax,si,6    ; shift in u, shifting up v
  626.     add    esi, edx    ; inc u,v
  627.     mov     al, es:[eax]    ; get pixel from source bitmap
  628.     mov    ah, bh    ; form lighting table lookup value
  629.     add    ebx, ebp    ; update lighting value
  630.     mov    cl, fs:[eax]    ; xlat thru lighting table into dest buffer
  631.  
  632. ; Do odd pixel
  633.     mov    eax, esi    ; get u,v
  634.     shr    eax, 26    ; shift out all but int(v)
  635.     shld    ax,si,6    ; shift in u, shifting up v
  636.     add    esi, edx    ; inc u,v
  637.     mov     al, es:[eax]    ; get pixel from source bitmap
  638.     mov    ah, bh    ; form lighting table lookup value
  639.     add    ebx, ebp    ; update lighting value
  640.     mov    ch, fs:[eax]    ; xlat thru lighting table into dest buffer
  641.  
  642.     ror    ecx, 16    ; move to next double dest pixel position
  643.  
  644.         ENDM
  645.     mov     [edi],ecx    ; Draw 4 pixels to display
  646. skip3:    add     edi,4
  647.  
  648.     ENDM
  649.  
  650. cont1:
  651.  
  652. ; -------------------------------------------------------
  653.  
  654. ; LIGHTING CODE
  655.     mov    _fx_l, ebx
  656.     pop    ebp
  657.     pop    ecx
  658.     pop    ebx
  659.     dec    _loop_count
  660.     jnz    TopOfLoop4
  661.  
  662. EndOfLoop4:
  663.     cmp    num_left_over, 0
  664.     je    _none_to_do
  665.  
  666. ; ----------------------------------------- Start of LeftOver Pixels ------------------------------------------
  667. DoEndPixels:
  668.     add    ebx, DU1
  669.     add    ebp, DV1
  670.     add    ecx, DZ1
  671.     je    _div_0_abort
  672.  
  673.     push    edi    ; use edi as a temporary variable
  674.  
  675.     cmp    ecx,10
  676.     jg    ecx_ok
  677.     mov    ecx,10
  678. ecx_ok:
  679.  
  680. ; Find fixed U1        
  681.     mov    eax, ebx
  682.     PDIV
  683.     mov    ebx, eax    ; ebx = U1 until pop's
  684.  
  685. ; Find fixed V1        
  686.     mov    eax, ebp
  687.     PDIV
  688.     mov    ebp, eax    ; ebp = V1 until pop's
  689.  
  690.     mov    ecx, U0    ; ecx = U0 until pop's
  691.     mov    edi, V0    ; edi = V0 until pop's
  692.  
  693. ; Make ESI =  V0:U0 in 6:10,6:10 format
  694.     mov    eax, ecx
  695.     shr    eax, 6
  696.     mov    esi, edi
  697.     shl    esi, 10
  698.     mov    si, ax
  699.         
  700. ; Make EDX = DV:DU in 6:10,6:10 format
  701.     mov    eax, ebx
  702.     sub    eax, ecx
  703.     sar    eax, NBITS+6
  704.     mov    edx, ebp
  705.     sub    edx, edi
  706.     shl    edx, 10-NBITS    ; EDX = V1-V0/ 4 in 6:10 int:frac
  707.     mov    dx, ax    ; put delta u in low word
  708.  
  709.     pop    edi    ; Restore EDI before using it
  710.         
  711.     mov    ecx, num_left_over
  712.  
  713. ; LIGHTING CODE
  714.     mov    ebx, _fx_l
  715.     mov    ebp, _fx_dl_dx
  716.  
  717.     ITERATION = 0
  718.     REPT (1 SHL (NBITS-1))
  719.     local    skip4, skip5
  720. ; Do even pixel
  721.     mov    eax, esi    ; get u,v
  722.     shr    eax, 26    ; shift out all but int(v)
  723.     shld    ax,si,6    ; shift in u, shifting up v
  724.     mov     al, es:[eax]    ; get pixel from source bitmap
  725.     add    esi, edx    ; inc u,v
  726.     mov    ah, bh    ; form lighting table lookup value
  727.     ;SAFETYand    ah,0fh
  728.     add    ebx, ebp    ; update lighting value
  729.     cmp    al,255
  730.     je    skip4
  731.     mov    al, fs:[eax]    ; xlat thru lighting table into dest buffer
  732.     mov    [edi+ITERATION], al    ; write pixel
  733. skip4:    dec    ecx
  734.     jz    _none_to_do
  735.     ITERATION = ITERATION + 1
  736.  
  737. ; Do odd pixel
  738.     mov    eax, esi    ; get u,v
  739.     shr    eax, 26    ; shift out all but int(v)
  740.     shld    ax,si,6    ; shift in u, shifting up v
  741.     mov     al, es:[eax]    ; get pixel from source bitmap
  742.     add    esi, edx    ; inc u,v
  743.     mov    ah, bh    ; form lighting table lookup value
  744.     add    ebx, _fx_dl_dx    ; update lighting value
  745.     cmp    al,255
  746.     je    skip5
  747.     ;SAFETYand    ah,0fh
  748.     mov    al, fs:[eax]    ; xlat thru lighting table into dest buffer
  749.     mov    [edi+ITERATION], al    ; write pixel
  750. skip5:    dec    ecx
  751.     jz    _none_to_do
  752.     ITERATION = ITERATION + 1
  753.     ENDM
  754.  
  755. ; ----------------------------------------- End of LeftOver Pixels ------------------------------------------
  756.  
  757. ; Should never get here!!!!
  758.     int    3
  759.     jmp    _none_to_do
  760.  
  761. ; ==================================================== No Lighting Code ======================================================
  762. public tmap_loop_fast_nolight
  763. tmap_loop_fast_nolight:
  764.     mov    esi,ebx
  765.  
  766.     align    4
  767. NotDwordAligned1_nolight:
  768.     test    edi, 11b
  769.     jz    DwordAligned1_nolight
  770.  
  771. ; compute v coordinate
  772.     mov    eax,ebp    ; get v
  773.     cdq
  774.     idiv    ecx    ; eax = (v/z)
  775.  
  776.     and    eax,3fh    ; mask with height-1
  777.     mov    ebx,eax
  778.  
  779. ; compute u coordinate
  780.     mov    eax,esi    ; get u
  781.     cdq
  782.     idiv    ecx    ; eax = (u/z)
  783.  
  784.     shl     eax,26
  785.     shld     ebx,eax,6    ; esi = v*64+u
  786.  
  787. ; read 1  pixel
  788.     mov    al,es:[ebx]    ; get pixel from source bitmap
  789.  
  790. ; write 1 pixel
  791.     cmp    al,255
  792.     je    skip6
  793.     mov    [edi],al
  794. skip6:    inc    edi
  795.     
  796. ; update deltas
  797.     add    ebp,_fx_dv_dx
  798.     add    esi,_fx_du_dx
  799.     add    ecx,_fx_dz_dx
  800.     je    _div_0_abort    ; would be dividing by 0, so abort
  801.  
  802.     dec    _loop_count
  803.     jns    NotDwordAligned1_nolight
  804.     jmp    _none_to_do
  805.  
  806. DwordAligned1_nolight:
  807.     mov    ebx,esi
  808.  
  809.     mov    eax, _loop_count
  810.     inc    eax
  811.     mov    num_left_over, eax
  812.     shr    eax, NBITS
  813.  
  814.     cmp    eax, 0        
  815.     je    tmap_loop
  816.     
  817.     mov     _loop_count, eax    ; _loop_count = pixels / NPIXS
  818.     shl    eax, NBITS
  819.     sub    num_left_over, eax    ; num_left_over = obvious
  820.         
  821. ; compute initial v coordinate
  822.     mov    eax,ebp    ; get v
  823.     PDIV
  824.     mov    V0, eax
  825.  
  826. ; compute initial u coordinate
  827.     mov    eax,ebx    ; get u
  828.     PDIV    
  829.     mov    U0, eax
  830.  
  831. ; Set deltas to NPIXS pixel increments
  832.     mov    eax, _fx_du_dx
  833.     shl    eax, NBITS
  834.     mov    DU1, eax
  835.     mov    eax, _fx_dv_dx
  836.     shl    eax, NBITS
  837.     mov    DV1, eax
  838.     mov    eax, _fx_dz_dx
  839.     shl    eax, NBITS
  840.     mov    DZ1, eax
  841.  
  842.     align    4
  843. TopOfLoop4_nolight:
  844.     add    ebx, DU1
  845.     add    ebp, DV1
  846.     add    ecx, DZ1
  847.     je    _div_0_abort
  848.  
  849. ; Done with ebx, ebp, ecx until next iteration
  850.     push    ebx
  851.     push    ecx
  852.     push    ebp
  853.     push    edi
  854.     
  855. ; Find fixed U1        
  856.     mov    eax, ebx
  857.     PDIV
  858.     mov    ebx, eax    ; ebx = U1 until pop's
  859.  
  860. ; Find fixed V1        
  861.     mov    eax, ebp
  862.     PDIV
  863.     mov    ebp, eax    ; ebp = V1 until pop's
  864.  
  865.     mov    ecx, U0    ; ecx = U0 until pop's
  866.     mov    edi, V0    ; edi = V0 until pop's
  867.  
  868. ; Make ESI =  V0:U0 in 6:10,6:10 format
  869.     mov    eax, ecx
  870.     shr    eax, 6
  871.     mov    esi, edi
  872.     shl    esi, 10
  873.     mov    si, ax
  874.         
  875. ; Make EDX = DV:DU in 6:10,6:10 format
  876.     mov    eax, ebx
  877.     sub    eax, ecx
  878.     sar    eax, NBITS+6
  879.     mov    edx, ebp
  880.     sub    edx, edi
  881.     shl    edx, 10-NBITS    ; EDX = V1-V0/ 4 in 6:10 int:frac
  882.     mov    dx, ax    ; put delta u in low word
  883.  
  884. ; Save the U1 and V1 so we don't have to divide on the next iteration
  885.     mov    U0, ebx
  886.     mov    V0, ebp
  887.  
  888.     pop    edi    ; Restore EDI before using it
  889.         
  890.     REPT (1 SHL (NBITS-2))
  891.     local    skip7, no_trans2
  892.         REPT 4    
  893. ; Do 1 pixel 
  894.     mov    eax, esi    ; get u,v
  895.     shr    eax, 26    ; shift out all but int(v)
  896.     shld    ax,si,6    ; shift in u, shifting up v
  897.     mov    cl, es:[eax]    ; load into buffer register
  898.     add    esi, edx    ; inc u,v
  899.     ror    ecx, 8    ; move to next dest pixel
  900.  
  901.         ENDM
  902.         
  903.     test    _transparency_on,-1
  904.     je    no_trans2
  905.     cmp    ecx,-1
  906.     je    skip7
  907.  
  908.     wr_onepix    0
  909.     wr_onepix    1
  910.     wr_onepix    2
  911.     wr_onepix    3
  912.     jmp    skip7
  913. no_trans2:
  914.     mov     [edi],ecx    ; Draw 4 pixels to display
  915. skip7:    add     edi,4
  916.  
  917.     ENDM
  918.  
  919.     pop    ebp
  920.     pop    ecx
  921.     pop    ebx
  922.     dec    _loop_count
  923.     jnz    TopOfLoop4_nolight
  924.  
  925. EndOfLoop4_nolight:
  926.  
  927.     cmp    num_left_over, 0
  928.     je    _none_to_do
  929.  
  930. DoEndPixels_nolight:
  931.     add    ebx, DU1
  932.     add    ebp, DV1
  933.     add    ecx, DZ1
  934.     je    _div_0_abort
  935.     push    edi    ; use edi as a temporary variable
  936.  
  937. ; Find fixed U1        
  938.     mov    eax, ebx
  939.     PDIV
  940.     mov    ebx, eax    ; ebx = U1 until pop's
  941.  
  942. ; Find fixed V1        
  943.     mov    eax, ebp
  944.     PDIV
  945.     mov    ebp, eax    ; ebp = V1 until pop's
  946.  
  947.     mov    ecx, U0    ; ecx = U0 until pop's
  948.     mov    edi, V0    ; edi = V0 until pop's
  949.  
  950. ; Make ESI =  V0:U0 in 6:10,6:10 format
  951.     mov    eax, ecx
  952.     shr    eax, 6
  953.     mov    esi, edi
  954.     shl    esi, 10
  955.     mov    si, ax
  956.         
  957. ; Make EDX = DV:DU in 6:10,6:10 format
  958.     mov    eax, ebx
  959.     sub    eax, ecx
  960.     sar    eax, NBITS+6
  961.     mov    edx, ebp
  962.     sub    edx, edi
  963.     shl    edx, 10-NBITS    ; EDX = V1-V0/ 4 in 6:10 int:frac
  964.     mov    dx, ax    ; put delta u in low word
  965.  
  966.     pop    edi    ; Restore EDI before using it
  967.         
  968.     mov    ecx, num_left_over
  969.  
  970.     ITERATION = 0
  971.     REPT (1 SHL NBITS)
  972.     local    skip8
  973. ; Do 1 pixel 
  974.     mov    eax, esi    ; get u,v
  975.     shr    eax, 26    ; shift out all but int(v)
  976.     shld    ax,si,6    ; shift in u, shifting up v
  977.     mov    al, es:[eax]    ; load into buffer register
  978.     add    esi, edx    ; inc u,v
  979.     cmp    al,255
  980.     je    skip8
  981.     mov    [edi+ITERATION], al    ; write pixel
  982. skip8:    dec    ecx
  983.     jz    _none_to_do
  984.     ITERATION = ITERATION + 1
  985.     ENDM
  986.  
  987. ; Should never get here!!!!!
  988.     int    3
  989.     jmp    _none_to_do
  990.  
  991.     
  992.  
  993. _TEXT    ends
  994.  
  995.     end
  996.  
  997. 
  998.