home *** CD-ROM | disk | FTP | other *** search
/ Amiga ACS 1998 #6 / amigaacscoverdisc1998-061998.iso / games / descent / source / texmap / tmap_ll.asm < prev    next >
Assembly Source File  |  1998-06-08  |  12KB  |  487 lines
  1. ;THE COMPUTER CODE CONTAINED HEREIN IS THE SOLE PROPERTY OF PARALLAX
  2. ;SOFTWARE CORPORATION ("PARALLAX").  PARALLAX, IN DISTRIBUTING THE CODE TO
  3. ;END-USERS, AND SUBJECT TO ALL OF THE TERMS AND CONDITIONS HEREIN, GRANTS A
  4. ;ROYALTY-FREE, PERPETUAL LICENSE TO SUCH END-USERS FOR USE BY SUCH END-USERS
  5. ;IN USING, DISPLAYING,  AND CREATING DERIVATIVE WORKS THEREOF, SO LONG AS
  6. ;SUCH USE, DISPLAY OR CREATION IS FOR NON-COMMERCIAL, ROYALTY OR REVENUE
  7. ;FREE PURPOSES.  IN NO EVENT SHALL THE END-USER USE THE COMPUTER CODE
  8. ;CONTAINED HEREIN FOR REVENUE-BEARING PURPOSES.  THE END-USER UNDERSTANDS
  9. ;AND AGREES TO THE TERMS HEREIN AND ACCEPTS THE SAME BY USE OF THIS FILE.  
  10. ;COPYRIGHT 1993-1998 PARALLAX SOFTWARE CORPORATION.  ALL RIGHTS RESERVED.
  11. ;
  12. ; $Source: f:/miner/source/texmap/rcs/tmap_ll.asm $
  13. ; $Revision: 1.10 $
  14. ; $Author: john $
  15. ; $Date: 1995/02/20 18:22:54 $
  16. ;
  17. ; Linear, lighted texture mapper inner loop.
  18. ;
  19. ; $Log: tmap_ll.asm $
  20. ; Revision 1.10  1995/02/20  18:22:54  john
  21. ; Put all the externs in the assembly modules into tmap_inc.asm.
  22. ; Also, moved all the C versions of the inner loops into a new module, 
  23. ; scanline.c.
  24. ; 
  25. ; Revision 1.9  1995/02/20  17:09:06  john
  26. ; Added code so that you can build the tmapper with no assembly!
  27. ; 
  28. ; Revision 1.8  1994/11/19  23:52:56  mike
  29. ; rip out big unrolled loop to save 25K....remember when we cared more about speed?
  30. ; 
  31. ; Revision 1.7  1994/11/12  16:39:41  mike
  32. ; jae to ja.
  33. ; 
  34. ; Revision 1.6  1994/03/14  15:45:08  mike
  35. ; streamline code.
  36. ; 
  37. ; Revision 1.5  1994/01/24  13:13:12  mike
  38. ; dithering.
  39. ; 
  40. ; Revision 1.4  1994/01/14  14:02:47  mike
  41. ; *** empty log message ***
  42. ; 
  43. ; Revision 1.3  1993/12/17  20:00:16  mike
  44. ; Change default setting of dither_intensity_lighting from 1 to 0
  45. ; 
  46. ; Revision 1.2  1993/11/22  10:24:50  mike
  47. ; *** empty log message ***
  48. ; 
  49. ; Revision 1.1  1993/09/08  17:29:52  mike
  50. ; Initial revision
  51. ; 
  52. ;
  53. ;
  54.  
  55.     .386
  56.  
  57.     public    asm_tmap_scanline_lin_lighted_
  58.  
  59.     include    tmap_inc.asm
  60.  
  61. _DATA    SEGMENT DWORD PUBLIC USE32 'DATA'
  62.  
  63. ALLOW_DITHERING    equ    1
  64.  
  65. _fx_dl_dx1    dd    ?
  66. _fx_dl_dx2    dd    ?
  67.  
  68. _loop_count    dd    ?
  69.  
  70. _DATA    ENDS
  71.  
  72. DGROUP    GROUP    _DATA
  73.  
  74. _TEXT   SEGMENT DWORD PUBLIC USE32 'CODE'
  75.  
  76.     ASSUME    DS:_DATA
  77.     ASSUME    CS:_TEXT
  78.  
  79. ; --------------------------------------------------------------------------------------------------
  80. ; Enter:
  81. ;    _xleft    fixed point left x coordinate
  82. ;    _xright    fixed point right x coordinate
  83. ;    _y    fixed point y coordinate
  84. ;    _pixptr    address of source pixel map
  85. ;    _u    fixed point initial u coordinate
  86. ;    _v    fixed point initial v coordinate
  87. ;    _du_dx    fixed point du/dx
  88. ;    _dv_dx    fixed point dv/dx
  89.  
  90. ;   for (x = (int) xleft; x <= (int) xright; x++) {
  91. ;      _setcolor(read_pixel_from_tmap(srcb,((int) (u/z)) & 63,((int) (v/z)) & 63));
  92. ;      _setpixel(x,y);
  93. ;
  94. ;      u += du_dx;
  95. ;      v += dv_dx;
  96. ;      z += dz_dx;
  97. ;   }
  98.  
  99.     align    4
  100. asm_tmap_scanline_lin_lighted_:
  101.     push    es
  102.     push    fs
  103.     pusha
  104.  
  105.     mov    es,_pixel_data_selector    ; selector[0*2]
  106.     mov    fs,_gr_fade_table_selector    ; selector[1*2]    ; fs = bmd_fade_table
  107.  
  108. ; Setup for loop:    _loop_count  iterations = (int) xright - (int) xleft
  109. ;   esi    source pixel pointer = pixptr
  110. ;   edi    initial row pointer = y*320+x
  111.  
  112. ; set esi = pointer to start of texture map data
  113.     mov    esi,_pixptr
  114.  
  115. ; set edi = address of first pixel to modify
  116.     mov    edi,_fx_y    ; this is actually an int
  117.     cmp    edi,_window_bottom
  118.     ja    all_done
  119.  
  120.     imul    edi,_bytes_per_row
  121.     mov    ebx,_fx_xleft
  122.     test    ebx,ebx
  123.     jns    ebx_ok
  124.     sub    ebx,ebx
  125. ebx_ok:
  126.     add    edi,ebx
  127.     add    edi,write_buffer
  128.  
  129. ; set _loop_count = # of iterations
  130.     mov    eax,_fx_xright
  131.     cmp    eax,_window_right
  132.     jl    eax_ok1
  133.     mov    eax,_window_right
  134. eax_ok1:    cmp    eax,_window_left
  135.     jg    eax_ok2
  136.     mov    eax,_window_left
  137. eax_ok2:
  138.  
  139.     sub    eax,ebx
  140.     js    all_done
  141.     cmp    eax,_window_width
  142.     jbe    _ok_to_do
  143.     mov    eax,_window_width
  144. _ok_to_do:
  145.     mov    _loop_count,eax
  146.  
  147. ;    edi    destination pixel pointer
  148.  
  149.  
  150.     mov    ecx,offset _lighting_tables
  151.     mov    eax,_fx_u    ; get 32 bit u coordinate
  152.     shr    eax,6    ; get 6:10 int:frac u coordinate into low word
  153.     mov    ebp,_fx_v    ; get 32 bit v coordinate
  154.     shl    ebp,10    ; put 6:10 int:frac into high word
  155.     mov    bp,ax    ; put u coordinate in low word
  156.  
  157.     mov    eax,_fx_du_dx    ; get 32 bit delta u
  158.     shr    eax,6    ; get 6:10 int:frac delta u into low word
  159.     mov    edx,_fx_dv_dx    ; get 32 bit delta v
  160.     shl    edx,10    ; put 6:10 int:frac into high word
  161.     mov    dx,ax    ; put delta u in low word
  162.  
  163.     sar    dword ptr _fx_dl_dx,8
  164.     jns    dl_dx_ok
  165.     inc    _fx_dl_dx    ; round towards 0 for negative deltas
  166. dl_dx_ok:
  167.  
  168.   if ALLOW_DITHERING
  169. ; do dithering, use lighting values which are .5 less than and .5 more than actual value
  170.     mov    ebx,80h    ; assume dithering on
  171.     test    _dither_intensity_lighting,-1
  172.     jne    do_dither
  173.     sub    ebx,ebx    ; no dithering
  174. do_dither:
  175.     mov    eax,_fx_dl_dx
  176.     add    eax,ebx    ; add 1/2
  177.     mov    _fx_dl_dx1,eax
  178.     sub    eax,ebx
  179.     sub    eax,ebx
  180.     mov    _fx_dl_dx2,eax
  181.     mov    ebx,_fx_xleft
  182.     xor    ebx,_fx_y
  183.     and    ebx,1
  184.     jne    dith_1
  185.     xchg    eax,_fx_dl_dx1
  186. dith_1:    mov    _fx_dl_dx2,eax
  187.   endif
  188.  
  189.     mov    ebx,_fx_l
  190.  
  191. ; lighting values are passed in fixed point, but need to be in 8 bit integer, 8 bit fraction so we can easily
  192. ; get the integer by reading %bh
  193.     sar    ebx,8
  194.  
  195.     test    _transparency_on,-1
  196.     jne    do_transparency_ll
  197.  
  198. ;; esi, ecx should be free
  199. loop_test = 1    ; set to 1 to run as loop for better profiling
  200.  if loop_test
  201.     mov    esi,_fx_dl_dx
  202.  
  203.     mov    ecx,_loop_count
  204.     inc    ecx
  205.     shr    ecx,1
  206.     je    one_more_pix
  207.     pushf
  208.  
  209.     align    4
  210.  
  211. loop1:
  212.     mov    eax,ebp    ; get u, v
  213.     shr    eax,26    ; shift out all but int(v)
  214.     shld    ax,bp,6    ; shift in u, shifting up v
  215.  
  216.     add    ebp,edx    ; u += du, v += dv
  217.  
  218.     mov    al,es:[eax]    ; get pixel from source bitmap
  219.     mov    ah,bh    ; get lighting table
  220.     add    ebx,esi    ; _fx_dl_dx    ; update lighting value
  221.     mov    al,fs:[eax]    ; xlat pixel through lighting tables
  222.     mov    [edi],al    ; write pixel...
  223.     inc    edi    ; ...and advance
  224.  
  225. ; --- ---
  226.  
  227.     mov    eax,ebp    ; get u, v
  228.     shr    eax,26    ; shift out all but int(v)
  229.     shld    ax,bp,6    ; shift in u, shifting up v
  230.  
  231.     add    ebp,edx    ; u += du, v += dv
  232.  
  233.     mov    al,es:[eax]    ; get pixel from source bitmap
  234.     mov    ah,bh    ; get lighting table
  235.     add    ebx,esi    ; _fx_dl_dx    ; update lighting value
  236.     mov    al,fs:[eax]    ; xlat pixel through lighting tables
  237.     mov    [edi],al    ; write pixel...
  238.     inc    edi    ; ...and advance
  239.  
  240.     dec    ecx    ; _loop_count
  241.     jne    loop1
  242.  
  243.     popf
  244.     jnc    all_done
  245.  
  246. one_more_pix:    mov    eax,ebp    ; get u, v
  247.     shr    eax,26    ; shift out all but int(v)
  248.     shld    ax,bp,6    ; shift in u, shifting up v
  249.  
  250.     mov    al,es:[eax]    ; get pixel from source bitmap
  251.     mov    ah,bh    ; get lighting table
  252.     mov    al,fs:[eax]    ; xlat pixel through lighting tables
  253.     mov    [edi],al    ; write pixel...
  254.  
  255. all_done:    popa
  256.     pop    fs
  257.     pop    es
  258.     ret
  259.  
  260.  
  261.   else
  262.  
  263. ; usage:
  264. ;    eax    work
  265. ;    ebx    lighting value
  266. ;    ecx    _lighting_tables
  267. ;    edx    du, dv 6:10:6:10
  268. ;    ebp    u, v coordinates 6:10:6:10
  269. ;    esi    pointer to source bitmap
  270. ;    edi    write address
  271.  
  272. _size = (_end1 - _start1)/num_iters
  273. ;  note: if eax is odd, you will not be writing the last pixel, you must clean up at the end
  274.   if ALLOW_DITHERING
  275.     mov eax,_loop_count
  276.     shr eax,1
  277.     neg eax
  278.     add eax,num_iters
  279.   else
  280.     mov    eax,num_iters
  281.     sub    eax,_loop_count
  282.  
  283.   endif
  284.     imul    eax,eax,dword ptr _size
  285.     add    eax,offset _start1
  286.     jmp    eax
  287.  
  288.     align    4
  289. _start1:
  290.  
  291. ; usage:
  292. ;    eax    work
  293. ;    ebx    lighting value
  294. ;    ecx    _lighting_tables
  295. ;    edx    du, dv 6:10:6:10
  296. ;    ebp    u, v coordinates 6:10:6:10
  297. ;    esi    pointer to source bitmap
  298. ;    edi    write address
  299.  
  300. ; do all but the last pixel in the unwound loop, last pixel done separately because less work is needed
  301.   rept num_iters
  302.  if 1
  303.  
  304. ;**; inner loop if lighting value is constant
  305. ;**; can be optimized if source bitmap pixels are stored as words, then the mov ah,bh is not necessary
  306. ;**    mov    eax,ebp    ; get u, v
  307. ;**    shr    eax,26    ; shift out all but int(v)
  308. ;**    shld    ax,bp,6    ; shift in u, shifting up v
  309. ;**
  310. ;**    add    ebp,edx    ; u += du, v += dv
  311. ;**
  312. ;**    mov    al,[esi+eax]    ; get pixel from source bitmap
  313. ;**    mov    ah,bh    ; get lighting table
  314. ;**    mov    al,[ecx+eax]    ; xlat pixel through lighting tables
  315. ;**    mov    [edi],al    ; write pixel...
  316. ;**    inc    edi    ; ...and advance
  317.  
  318.  
  319.   if ALLOW_DITHERING
  320.  
  321. ; dithering
  322. ; loop contains two iterations which must be the same length
  323.     mov    eax,ebp    ; get u, v
  324.     shr    eax,26    ; shift out all but int(v)
  325.     shld    ax,bp,6    ; shift in u, shifting up v
  326.  
  327.     add    ebp,edx    ; u += du, v += dv
  328.  
  329.     mov    al,[esi+eax]    ; get pixel from source bitmap
  330.     mov    ah,bh    ; get lighting table
  331.     add    ebx,_fx_dl_dx1    ; update lighting value
  332.     mov    al,[ecx+eax]    ; xlat pixel through lighting tables
  333.     mov    [edi],al    ; write pixel...
  334.     inc    edi    ; ...and advance
  335.  
  336. ; second iteration
  337.     mov    eax,ebp    ; get u, v
  338.     shr    eax,26    ; shift out all but int(v)
  339.     shld    ax,bp,6    ; shift in u, shifting up v
  340.  
  341.     add    ebp,edx    ; u += du, v += dv
  342.  
  343.     mov    al,[esi+eax]    ; get pixel from source bitmap
  344.     mov    ah,bh    ; get lighting table
  345.     add    ebx,_fx_dl_dx2    ; update lighting value
  346.     mov    al,[ecx+eax]    ; xlat pixel through lighting tables
  347.     mov    [edi],al    ; write pixel...
  348.     inc    edi    ; ...and advance
  349.   else
  350.     mov    eax,ebp    ; get u, v
  351.     shr    eax,26    ; shift out all but int(v)
  352.     shld    ax,bp,6    ; shift in u, shifting up v
  353.  
  354.     add    ebp,edx    ; u += du, v += dv
  355.  
  356.     mov    al,[esi+eax]    ; get pixel from source bitmap
  357.     mov    ah,bh    ; get lighting table
  358.     add    ebx,_fx_dl_dx    ; update lighting value
  359.     mov    al,[ecx+eax]    ; xlat pixel through lighting tables
  360.     mov    [edi],al    ; write pixel...
  361.     inc    edi    ; ...and advance
  362.   endif
  363.  
  364.  
  365.   else
  366.  
  367. ;obsolete: ; version which assumes segment overrides are in place (which they are obviously not)
  368. ;obsolete:     mov    eax,ebp    ; get u, v
  369. ;obsolete:     shr    eax,26    ; shift out all but int(v)
  370. ;obsolete:     shld    ax,bp,6    ; shift in u, shifting up v
  371. ;obsolete: 
  372. ;obsolete:     add    ebp,edx    ; u += du, v += dv
  373. ;obsolete: 
  374. ;obsolete:     mov    al,[eax]    ; get pixel from source bitmap
  375. ;obsolete:     mov    ah,bh    ; get lighting table
  376. ;obsolete:     add    ebx,esi    ; update lighting value
  377. ;obsolete:     mov    al,[eax]    ; xlat pixel through lighting tables
  378. ;obsolete:     mov    [edi],al    ; write pixel...
  379. ;obsolete:     inc    edi    ; ...and advance
  380.  endif
  381.   endm
  382.  
  383. _end1:
  384.  
  385. ; now do the leftover pixel
  386.     mov    eax,ebp
  387.     shr    eax,26    ; shift in v coordinate
  388.     shld    ax,bp,6    ; shift in u coordinate while shifting up v coordinate
  389.     mov    al,[esi+eax]    ; get pixel from source bitmap
  390.     mov    ah,bh    ; get lighting table
  391.  or ah,ah
  392.  jns ok1
  393.  sub ah,ah
  394. ok1:
  395.     mov    al,_lighting_tables[eax]    ; xlat pixel through lighting tables
  396.     mov    [edi],al    ; write pixel...
  397.  
  398. _none_to_do:    popa
  399.     pop    fs
  400.     pop    es
  401.     ret
  402.  
  403.   endif
  404. ; -- Code to get rgb 5 bits integer, 5 bits fraction value into 5 bits integer (for each gun)
  405. ; suitable for inverse color lookup
  406. ;**__test:
  407. ;** int 3
  408. ;**;                  rrrrrfffffrrrrrfffffxxbbbbbfffff
  409. ;**    mov    eax,11111001001010101110101101110111b
  410. ;**    and    eax,11111000001111100000001111100000b
  411. ;**    shld    ebx,eax,15
  412. ;**    or    bx,ax
  413.  
  414.  
  415. ;; esi, ecx should be free
  416. do_transparency_ll:
  417.     mov    esi,_fx_dl_dx
  418.  
  419.     mov    ecx,_loop_count
  420.     inc    ecx
  421.     shr    ecx,1
  422.     je    one_more_pix2
  423.     pushf
  424.  
  425.     align    4
  426.  
  427. loop1a:
  428.     mov    eax,ebp    ; get u, v
  429.     shr    eax,26    ; shift out all but int(v)
  430.     shld    ax,bp,6    ; shift in u, shifting up v
  431.  
  432.     add    ebp,edx    ; u += du, v += dv
  433.  
  434.     mov    al,es:[eax]    ; get pixel from source bitmap
  435.     cmp    al,255
  436.     je    skip1a
  437.     mov    ah,bh    ; get lighting table
  438.     add    ebx,esi    ; _fx_dl_dx    ; update lighting value
  439.     mov    al,fs:[eax]    ; xlat pixel through lighting tables
  440.     mov    [edi],al    ; write pixel...
  441. skip1a:    inc    edi    ; ...and advance
  442.  
  443. ; --- ---
  444.  
  445.     mov    eax,ebp    ; get u, v
  446.     shr    eax,26    ; shift out all but int(v)
  447.     shld    ax,bp,6    ; shift in u, shifting up v
  448.  
  449.     add    ebp,edx    ; u += du, v += dv
  450.  
  451.     mov    al,es:[eax]    ; get pixel from source bitmap
  452.     cmp    al,255
  453.     je    skip2a
  454.     mov    ah,bh    ; get lighting table
  455.     add    ebx,esi    ; _fx_dl_dx    ; update lighting value
  456.     mov    al,fs:[eax]    ; xlat pixel through lighting tables
  457.     mov    [edi],al    ; write pixel...
  458. skip2a:    inc    edi    ; ...and advance
  459.  
  460.     dec    ecx    ; _loop_count
  461.     jne    loop1a
  462.  
  463.     popf
  464.     jnc    all_done_1
  465.  
  466. one_more_pix2:    mov    eax,ebp    ; get u, v
  467.     shr    eax,26    ; shift out all but int(v)
  468.     shld    ax,bp,6    ; shift in u, shifting up v
  469.  
  470.     mov    al,es:[eax]    ; get pixel from source bitmap
  471.     cmp    al,255
  472.     je    skip3a
  473.     mov    ah,bh    ; get lighting table
  474.     mov    al,fs:[eax]    ; xlat pixel through lighting tables
  475.     mov    [edi],al    ; write pixel...
  476.  
  477. skip3a:
  478. all_done_1:    popa
  479.     pop    fs
  480.     pop    es
  481.     ret
  482.  
  483. _TEXT    ends
  484.  
  485.     end
  486. 
  487.