home *** CD-ROM | disk | FTP | other *** search
/ Amiga ACS 1998 #6 / amigaacscoverdisc1998-061998.iso / games / descent / source / texmap / tmap_lin.asm < prev    next >
Assembly Source File  |  1998-06-08  |  8KB  |  289 lines
  1. ;THE COMPUTER CODE CONTAINED HEREIN IS THE SOLE PROPERTY OF PARALLAX
  2. ;SOFTWARE CORPORATION ("PARALLAX").  PARALLAX, IN DISTRIBUTING THE CODE TO
  3. ;END-USERS, AND SUBJECT TO ALL OF THE TERMS AND CONDITIONS HEREIN, GRANTS A
  4. ;ROYALTY-FREE, PERPETUAL LICENSE TO SUCH END-USERS FOR USE BY SUCH END-USERS
  5. ;IN USING, DISPLAYING,  AND CREATING DERIVATIVE WORKS THEREOF, SO LONG AS
  6. ;SUCH USE, DISPLAY OR CREATION IS FOR NON-COMMERCIAL, ROYALTY OR REVENUE
  7. ;FREE PURPOSES.  IN NO EVENT SHALL THE END-USER USE THE COMPUTER CODE
  8. ;CONTAINED HEREIN FOR REVENUE-BEARING PURPOSES.  THE END-USER UNDERSTANDS
  9. ;AND AGREES TO THE TERMS HEREIN AND ACCEPTS THE SAME BY USE OF THIS FILE.  
  10. ;COPYRIGHT 1993-1998 PARALLAX SOFTWARE CORPORATION.  ALL RIGHTS RESERVED.
  11. ;
  12. ; $Source: f:/miner/source/texmap/rcs/tmap_lin.asm $
  13. ; $Revision: 1.3 $
  14. ; $Author: john $
  15. ; $Date: 1995/02/20 18:22:57 $
  16. ;
  17. ; Linearly interpolating texture mapper inner loop
  18. ;
  19. ; $Log: tmap_lin.asm $
  20. ; Revision 1.3  1995/02/20  18:22:57  john
  21. ; Put all the externs in the assembly modules into tmap_inc.asm.
  22. ; Also, moved all the C versions of the inner loops into a new module, 
  23. ; scanline.c.
  24. ; 
  25. ; Revision 1.2  1995/02/20  17:09:10  john
  26. ; Added code so that you can build the tmapper with no assembly!
  27. ; 
  28. ; Revision 1.1  1994/11/30  12:24:04  mike
  29. ; Initial revision
  30. ; 
  31. ; Revision 1.6  1994/11/12  16:39:40  mike
  32. ; jae to ja.
  33. ; 
  34. ; Revision 1.5  1994/02/10  21:24:43  matt
  35. ; Got rid of debug_on set
  36. ; 
  37. ; Revision 1.4  1994/01/31  15:39:53  mike
  38. ; Write additional inner loop for transparency.
  39. ; 
  40. ; Revision 1.3  1994/01/26  11:50:04  john
  41. ; Added transparency to linear unlighted texture mapper.
  42. ; 
  43. ; Revision 1.2  1993/11/22  10:24:36  mike
  44. ; *** empty log message ***
  45. ; 
  46. ; Revision 1.1  1993/09/08  17:29:50  mike
  47. ; Initial revision
  48. ; 
  49. ;
  50. ;
  51.  
  52.     .386
  53.  
  54.     option    oldstructs
  55.  
  56.     .nolist
  57.     include    psmacros.inc
  58.     .list
  59.  
  60.  
  61.     public    asm_tmap_scanline_lin_
  62.  
  63.     include    tmap_inc.asm
  64.  
  65. _DATA    SEGMENT DWORD PUBLIC USE32 'DATA'
  66.  
  67. _loop_count     dd    ?
  68.  
  69. _DATA    ENDS
  70.  
  71. DGROUP    GROUP    _DATA
  72.  
  73. _TEXT   SEGMENT DWORD PUBLIC USE32 'CODE'
  74.  
  75.     ASSUME    DS:_DATA
  76.     ASSUME    CS:_TEXT
  77.  
  78.     extn    mprintf_
  79.  
  80. ; --------------------------------------------------------------------------------------------------
  81. ; Enter:
  82. ;    _xleft    fixed point left x coordinate
  83. ;    _xright    fixed point right x coordinate
  84. ;    _y    fixed point y coordinate
  85. ;    _pixptr    address of source pixel map
  86. ;    _u    fixed point initial u coordinate
  87. ;    _v    fixed point initial v coordinate
  88. ;    _du_dx    fixed point du/dx
  89. ;    _dv_dx    fixed point dv/dx
  90.  
  91. ;   for (x = (int) xleft; x <= (int) xright; x++) {
  92. ;      _setcolor(read_pixel_from_tmap(srcb,((int) (u/z)) & 63,((int) (v/z)) & 63));
  93. ;      _setpixel(x,y);
  94. ;
  95. ;      u += du_dx;
  96. ;      v += dv_dx;
  97. ;      z += dz_dx;
  98. ;   }
  99.  
  100.     align    4
  101. asm_tmap_scanline_lin_:
  102.     pusha
  103.  
  104. ; Setup for loop:    _loop_count  iterations = (int) xright - (int) xleft
  105. ;    esi    source pixel pointer = pixptr
  106. ;    edi    initial row pointer = y*320+x
  107.  
  108. ; set esi = pointer to start of texture map data
  109.     mov    esi,_pixptr
  110.  
  111. ; set edi = address of first pixel to modify
  112.     mov    edi,_fx_y
  113.     cmp    edi,_window_bottom
  114.     ja    _none_to_do
  115.  
  116.     imul    edi,_bytes_per_row
  117.     mov    eax,_fx_xleft
  118.     test    eax, eax
  119.     jns    eax_ok
  120.     sub    eax,eax
  121. eax_ok:
  122.     add    edi,eax
  123.     add    edi,write_buffer
  124.  
  125. ; set _loop_count = # of iterations
  126.     mov    eax,_fx_xright
  127.     cmp    eax,_window_right
  128.     jb    eax_ok1
  129.     mov    eax,_window_right
  130. eax_ok1:    cmp    eax,_window_left
  131.     ja    eax_ok2
  132.     mov    eax,_window_left
  133. eax_ok2:
  134.  
  135.     mov    ebx,_fx_xleft
  136.     sub    eax,ebx
  137.     js    _none_to_do
  138.     cmp    eax,_window_width
  139.     jbe    _ok_to_do
  140.     mov    eax,_window_width
  141. _ok_to_do:
  142.     mov    _loop_count,eax
  143.  
  144. ;    edi    destination pixel pointer
  145.  
  146.  
  147.     mov    ebx,_fx_u
  148.     mov    ecx,_fx_du_dx
  149.     mov    edx,_fx_dv_dx
  150.     mov    ebp,_fx_v
  151.  
  152.     shl    ebx,10
  153.     shl    ebp,10
  154.     shl    edx,10
  155.     shl    ecx,10
  156.  
  157. ; eax    work
  158. ; ebx    u
  159. ; ecx    du_dx
  160. ; edx    dv_dx
  161. ; ebp    v
  162. ; esi    read address
  163. ; edi    write address
  164.  
  165.     test    _transparency_on,-1
  166.     jne    transparent_texture
  167.  
  168. _size = (_end1 - _start1)/num_iters
  169.     mov    eax,num_iters-1
  170.     sub    eax,_loop_count
  171.     jns    j_eax_ok1
  172.     inc    eax    ; sort of a hack, but we can get -1 here and want to be graceful
  173.     jns    j_eax_ok1    ; if we jump, we had -1, which is kind of ok, if not, we int 3
  174.     int    3    ; oops, going to jump behind _start1, very bad...
  175.     sub    eax,eax    ; ok to continue
  176. j_eax_ok1:    imul    eax,eax,dword ptr _size
  177.     add    eax,offset _start1
  178.     jmp    eax
  179.  
  180.     align    4
  181. _start1:
  182.  
  183. ; "OPTIMIZATIONS" maybe not worth making
  184. ;    Getting rid of the esi from the mov al,[esi+eax] instruction.
  185. ;       This would require moving into eax at the top of the loop, rather than doing the sub eax,eax.
  186. ;       You would have to align your bitmaps so that the two shlds would create the proper base address.
  187. ;       In other words, your bitmap data would have to begin at 4096x (for 64x64 bitmaps).
  188. ;       I did timings without converting the sub to a mov eax,esi and setting esi to the proper value.
  189. ;       There was a speedup of about 1% to 1.5% without converting the sub to a mov.
  190. ;    Getting rid of the edi by doing a mov nnnn[edi],al instead of mov [edi],al.
  191. ;       The problem with this is you would have a dword offset for nnnn.  My timings indicate it is slower.  (I think.)
  192. ;    Combining u,v and du,dv into single longwords.
  193. ;       The problem with this is you then must do a 16 bit operation to extract them, and you don't have enough
  194. ;       instructions to separate a destination operand from being used by the next instruction.  It shaves out one
  195. ;       register instruction (an add reg,reg), but adds a 16 bit operation, and the setup is more complicated.
  196. ; usage:
  197. ;    eax    work
  198. ;    ebx    u coordinate
  199. ;    ecx    delta u
  200. ;    edx    delta v
  201. ;    ebp    v coordinate
  202. ;    esi    pointer to source bitmap
  203. ;    edi    write address
  204.  rept num_iters
  205.     mov    eax,ebp    ; clear for 
  206.     add    ebp,edx    ; update v coordinate
  207.     shr    eax,26    ; shift in v coordinate
  208.     shld    eax,ebx,6    ; shift in u coordinate while shifting up v coordinate
  209.     add    ebx,ecx    ; update u coordinate
  210.     mov    al,[esi+eax]    ; get pixel from source bitmap
  211.     mov    [edi],al
  212.     inc    edi        ; XPARENT ADDED BY JOHN
  213.  
  214. ; inner loop if bitmaps are 256x256
  215. ; your register usage is bogus, and you must clear ecx
  216. ; fix your setup
  217. ; this is only about 10% faster in the inner loop
  218. ; this method would adapt to writing two pixels at a time better than
  219. ; the 64x64 method because you wouldn't run out of registers
  220. ; Note that this method assumes that both dv_dx and du_dx are in edx.
  221. ; edx = vi|vf|ui|uf
  222. ; where each field is 8 bits, vi = integer v coordinate, vf = fractional v coordinate, etc.
  223. ;** add ebx,edx
  224. ;** mov cl,bh
  225. ;** shld cx,bx,8
  226. ;** mov al,[esi+ecx]
  227. ;** mov [edi],al
  228. ;** inc edi
  229.  endm
  230.  
  231. _end1:
  232.  
  233. _none_to_do:    popa
  234.  
  235.     ret
  236.  
  237. ; ----------------------------------------------------------------------------------------
  238. ; if texture map has transparency, use this code.
  239. transparent_texture:
  240.     test    _loop_count,-1
  241.     je    _t_none_to_do
  242. loop_transparent:
  243.     mov    eax,ebp    ; clear for 
  244.     add    ebp,edx    ; update v coordinate
  245.     shr    eax,26    ; shift in v coordinate
  246.     shld    eax,ebx,6    ; shift in u coordinate while shifting up v coordinate
  247.     add    ebx,ecx    ; update u coordinate
  248.     mov    al,[esi+eax]    ; get pixel from source bitmap
  249.     cmp    al,255
  250.     je    transp
  251.     mov    [edi],al
  252. transp:    inc    edi        ; XPARENT ADDED BY JOHN
  253.  
  254.     dec    _loop_count
  255.     jne    loop_transparent
  256.  
  257. _t_none_to_do:    popa
  258.     ret
  259.  
  260. _TEXT    ends
  261.  
  262.     end
  263.  
  264.  
  265.  
  266. ; This is the inner loop to write two pixels at a time
  267. ; This is about 2.5% faster overall (on Mike's 66 MHz 80486 DX2, VLB)
  268. ; You must write code to even align edi and do half as many iterations, and write
  269. ; the beginning and ending extra pixels, if necessary.
  270. ;    sub    eax,eax    ; clear for 
  271. ;    shld    eax,ebp,6    ; shift in v coordinate
  272. ;    add    ebp,_fx_dv_dx    ; update v coordinate
  273. ;    shld    eax,ebx,6    ; shift in u coordinate while shifting up v coordinate
  274. ;    add    ebx,ecx    ; update u coordinate
  275. ;    mov    dl,[esi+eax]    ; get pixel from source bitmap
  276. ;
  277. ;    sub    eax,eax    ; clear for 
  278. ;    shld    eax,ebp,6    ; shift in v coordinate
  279. ;    add    ebp,_fx_dv_dx    ; update v coordinate
  280. ;    shld    eax,ebx,6    ; shift in u coordinate while shifting up v coordinate
  281. ;    add    ebx,ecx    ; update u coordinate
  282. ;    mov    dh,[esi+eax]    ; get pixel from source bitmap
  283. ;
  284. ;    mov    [edi],dx
  285. ;    add    edi,2
  286.  
  287.  
  288. 
  289.